Listing of file='ROCKET2' on disk='vmedia/games.wvd.zip'
# Sector 524, program filename = 'ROCKET2'
0005 PRINT HEX(030A0A)
0080 PRINT "LUNAR LANDING SIMULATION"
0090 PRINT "------------------------"
: PRINT
0100 INPUT "DO YOU WANT INSTRUCTIONS (YES OR NO)",A$
0111 PRINT HEX(0A0A0A0A0A0A0A0A0A0A0A0A0A0A0A0A)
0120 IF A$="NO" THEN 390
0130 PRINT
: SELECT P9
0140 PRINT "YOU ARE LANDING ON THE MOON AND HAVE TAKEN OVER MANUAL"
0150 PRINT "CONTROL 500 FEET ABOVE A GOOD LANDING SPOT. YOU HAVE A"
0160 PRINT "DOWNWARD VELOCITY OF 50 FT/SEC. 120 UNITS OF FUEL REMAIN."
0225 PRINT
0230 PRINT " HERE ARE THE RULES THAT GOVERN YOUR SPACE VEHICLE"
0240 PRINT "(1) AFTER EACH SECOND, THE HEIGHT, VELOCITY, AND REMAINING"
0250 PRINT "FUEL WILL BE REPORTED"
0260 PRINT "(2) AFTER THE RELPORT, A '?' WILL BE TYPED. ENTER THE"
0270 PRINT "NUMBER OF UNITS OF FUEL YOU WISH TO BURN DURING THE"
0280 PRINT "NEXT SECOND. EACH UNIT OF FUEL WILL SLOW YOUR DESCEN T"
0290 PRINT "BY 1 FT/SEC"
0310 PRINT "(3) THE MAXIMUM THRUST OF YOUR ENGINE IS 30 FT/SEC OR"
0320 PRINT "30UNITS OF FUEL PER SEC"
0330 PRINT "(4) WHEN YOU CONTACT THE LUNAR SURFACE, YOUR DESCENT ENGINE"
0340 PRINT "WILL AUTOMATICALLY CUT OFF AND YOU WILL BE GIVEN A"
0350 PRINT "REPORT OF YOUR LANDING SPEED AND REMAINING FUEL"
0360 PRINT "(5)IF YOU RUN OUT OF FUEL, THE '?' WILL NO LONGER APPEAR"
0370 PRINT "BUT YOUR SEC BY SEC REPORT WILL CONTINUE UNTIL"
0380 PRINT "YOU CONTACT THE LULNAR SURFACE"
0385 PRINT HEX(03)
0390 PRINT "BEGINNING LANDING PROCEDURE......"
: PRINT
: PRINT
0410 PRINT "GOOD LUCK !!!!!"
0415 SELECT P
0420 PRINT
: PRINT
: PRINT
0421 PRINT HEX(03)
0440 PRINT "SEC";TAB(4);"FEET";TAB(12);"SPEED";TAB(20);"FUEL"; TAB(29); "PLOT
OF DISTANCE"
0450 PRINT
0455 T=0
: H=500
: V=50
: F=120
0490 PRINT T;TAB(4);H;TAB(12);V;TAB(20);F;TAB(30);"I";TAB(H/12+29);"*"
0500 INPUT B
0510 IF B<0 THEN 650
0520 IF B>30 THEN 521
: GOTO 530
0521 B=30
0530 IF B>F THEN 531
: GOTO 540
0531 B=F
0540 V1=V-B+5
0560 F=F-B
0570 H=H-.5*(V+V1)
0580 IF H<=0THEN 670
0590 T=T+1
0600 V=V1
0610 IF F>0 THEN 490
0615 IF B=0 THEN 640
0620 PRINT "OUT OF FUEL"
0640 PRINT T;TAB(4);H;TAB(12);Y;TAB(20);F;TAB(30);"I";TAB(H/12+29);"*"
0650 B=0
0660 GOTO 540
0670 PRINT "*** CONTACT***"
0680 H=H+.5*(V+V1)
0690 IF B=5 THEN 720
0700 D=(-V+SQR(V*V+H*(10-2*B)))/(5-B)
0710 GOTO 730
0720 D=H/V
0730 V1=V+(5-B)*D
0760 PRINT "TOUCHDOWN AT";T+D; "SECONDS"
0770 PRINT "LANDING VELOCITY =";V1;"FEET/SEC"
0780 PRINT F;" UNITS OF FUEL REMAINING"
0790 IF V1<>0 THEN 810
0800 PRINT "CONGRATULATIONS !! A PERFECT LANDING"
0805 PRINT "YOUR LICENCE WILL BE RENEWED........... LATER"
0810 IF ABS(V1)<2 THEN 840
0820 PRINT "***** SORRY YOU BLEW IT *****"
0830 PRINT " APPROPRIATE CONDOLENCES WILL BE SENT TO YOUR NEXT OF KIN."
0840 STOP
0850 DEFFN'31
: LOAD DC F"GAMES"