image of READY prompt

Wang2200.org

Listing of file='PAPER' on disk='vmedia/games_vol_3.wvd.zip'

# Sector 208, program filename = 'PAPER'
0010 COM D$23,Z9
0030 PRINT HEX(03);"                NEWSPAPER SALES PROBLEM"
0040 PRINT "THE PROBLEM IS TO MAKE A PROFIT BY SELLING NEWSPAPERS."
0050 PRINT "THE INFORMATION REQUIRED TO ORDER PAPERS IS:"
0060 PRINT ,"BUYING PRICE PER PAPER            4 CENTS"
0070 PRINT ,"SELLING PRICE PER PAPER           5 CENTS"
0080 PRINT ,"UNSOLD PAPERS MAY BE RETURNED FOR 0 CENTS"
0090 PRINT ,"EXCESS DEMAND MUST BE MET AT"
   : PRINT ,"AN ADDITIONAL COST TO YOU OF      1.5 CENTS"
0100 PRINT "YOU WILL BE ASKED THE NUMBER OF PAPERS YOU WISH TO BUY"
   : PRINT  "FROM THE AGENT TODAY."
0110 PRINT "I WILL ALSO MAKE A DECISION AND COMPETE WITH YOU."
0120 PRINT HEX(0A)
0130 PRINT  "PRESS 'RETURN' FOR MORE INSTRUCTIONS."
0140 INPUT A9
0150 PRINT HEX(03)
0160 PRINT "TODAYS ACTUAL DEMAND IS UNKNOWN UNTIL BOTH OF OUR ORDERS ARE"
   : PRINT  "PLACED."
0170 X=5
0180 PRINT "THE ACTUAL DEMAND FOR THE LAST 10 DAYS IS;"
0190 FOR I=1TO 10
   : GOSUB 540
   : PRINT ,,D1
   : NEXT I
0200 PRINT "TYPE IN YOUR ORDER AND PRESS 'RETURN' (TYPE 0 TO STOP THE GAME)"
0210 INPUT D2
0220 IF D2=0 THEN 450
0230 D3=INT(.5+M-.6045*V)
0240 GOSUB 540
0250 IF D1>D2 THEN 280
0260 P1=(.01*D1)-(.04*(D2-D1))
0270 GOTO 290
0280 P1=(.01*D2)-(.015*(D1-D2))
0290 IF D1>D3 THEN 320
0300 P2=(.01*D1)-(.04*(D3-D1))
0310 GOTO 330
0320 P2=(.01*D3)-(.015*(D1-D3))
0330 P3=P3+P1
0340 P4=P4+P2
0350 PRINT HEX(0A)
   : PRINT HEX(0A)
   : PRINT HEX(0A)
0360 PRINTUSING 780,D2,D3
0370 PRINT HEX(0A)
0380 PRINTUSING 790,D1
0390 PRINT HEX(0A)
   : PRINT HEX(0A)
   : PRINT HEX(0A)
0400 PRINTUSING 800,P1,P3
0410 PRINT
0420 PRINTUSING 810,P2,P4
0430 PRINT HEX(0A)
0440 GOTO 200
0450 FOR I=1TO 5
   : PRINT HEX(0A)
   : NEXT I
0460 PRINTUSING 470,P3
0470 %          YOUR TOTAL PROFIT/LOSS IS -$####.##
0480 PRINT HEX(0A)
0490 PRINTUSING 500,P4
0500 %          MY TOTAL PROFIT/LOSS IS   -$####.##
0510 FOR I=1TO 2
   : PRINT HEX(0A)
   : NEXT I
0520 PRINT "          GAME OVER.THANK YOU FOR PLAYING."
0530 LINPUT "'RETURN' TO CONCLUDE",A8$
   : LOAD T"GAMES"
0540 S1=RND(X)
0550 IF S1<.002THEN 540
0560 IF S1>.5 THEN 690
0570 S2=S1
0580 C0=2.515517
   : C1=.802853
   : C2=0.010328
   : R1=1.432788
   : R2=.189269
   : R3=.001308
0590 T=SQR(LOG(1/(S2)^2))
0600 X1=T-(C0+C1*T+C2*T^2)/(1+R1*T+R2*T^2+R3*T^3)
0610 IF F1=1THEN 720
0620 D1=INT(500+(100*X1))
0630 Z1=Z1+D1
0640 Z2=Z2+(D1^2)
0650 Z3=Z3+1
0660 M=Z1/Z3
0670 V=SQR((Z2-(M^2)*Z3)/Z3)
0680 RETURN
0690 S2=1-S1
0700 F1=1
0710 GOTO 590
0720 X1=-X1
0730 F1=0
0740 GOTO 620
0750 DEFFN'126
   : LOAD T"GAMES"
0760 STOP
0770 END
0775 DEFFN'4
   : SCRATCH T/D11,"PAPER"
   : SAVE T/D11,()"PAPER"
   : STOP "SAVED"
0780 %YOU ORDERED #### PAPERS.       I ORDERED #### PAPERS.
0790 %             TODAYS DEMAND IS #### PAPERS.
0800 %YOUR PROFIT TODAY: -$####.##  YOUR TOTAL PROFIT/LOSS ;-$####.##
0810 %  MY PROFIT TODAY: -$####.##   MY TOTAL PROFIT/LOSS  ;-$####.##