image of READY prompt

Wang2200.org

Listing of file='STARTTBO' on disk='vmedia/games_vol_4.wvd.zip'

# Sector 10, program filename = 'STARTTBO'
0010 REM STARTTBO 04/05/88
0012 COM D1$(12)4
   : D1$()="D10 D11"
0015 % Image statement for COM overlay
0016 COM Z$64
0020 DIM D8$20,N$64,A$64,B$1,C$1,A,B,C,W$64,E$80,F$8
0030 DIM D,D1,I,A1$(24)24,A1$
0035 RESTORE
   : READ E$
0040 A$="TBO Menu"
   : N$=$PSTAT(#PART)
   : IF STR(N$,1,8)<>A$THEN $PSTAT=E$
0042 SELECT CI 001,INPUT 001,LIST 005(80),CO 005(80),PRINT 005(80),TAPE 005
0043 D$=$PSTAT(1)
0044 PRINT HEX(0306020402000E);E$;TAB(25);STR(D$,1,8);TAB(50);"What do you wis
     h to do?"
0046 PRINT HEX(020400000F)
0210 INIT(0A)D8$
   : STR(D8$,1,1)=HEX(01)
0220 A=1
   : RESTORE 3
   : READ E$
0260 PRINT "TO OPERATE -- Press S.F. KEY or DIGIT corresponding to name,"
0270 PRINT "or position # via Alpha, RETURN, SPACE or BACKSPACE and key RUN"
0275 D$=SELECT #0
0280 PRINT " This is Terminal =";#TERM;" in Partition =";#PART;"  Memory =";SP
     ACEK;"K  using ";D$;
0290 D=5
   : D1=2
0300 GOSUB 660
   : REM /SET DISPLAY
0310 ON I GOTO 340
0320 %   ' ## to ######################################################
0330 GOSUB 390
   : REM /K.B./CRT INTERACTION
0340 E$=A1$(A)
   : W$=" "
0342 RESTORE LINE9000,A+1
   : READ E$
   : IF LEN(E$)>65THEN SELECT #0<STR(E$,LEN(E$)-2,3)>
0345 B$=STR(E$,9,1)
0350 IF B$="]" THEN 362
0352 IF B$<>"@"THEN 354
   : $PSTAT=STR(E$,1,8)
   : COM CLEAR
   : LOAD DC T#0,"@MENU"
   : ERRORGOTO 10
0354 IF B$<>"c"THEN COM CLEAR
0356 $PSTAT=" "
0360 LOAD T#0,STR(E$,1,8)
   : ERRORGOTO 10
0361 REM %.] denotes a loader module over stmts 9000-nnnn
0362 F$=E$
   : MAT SEARCH Z$,=F$ TO N$
   : B=1
   : A=VAL(N$,2)
0364 IF A=0 THEN 366
   : B=A
   : GOTO 368
0366 IF Z$<>" "THEN B=INT((LEN(Z$)+7)/8)*8+1
0368 STR(Z$,B)=F$
   : GOTO 372
0370 DEFFN'0
   : A=INT((LEN(Z$)+7)/8)*8-7
   : IF A<1THEN 375
   : STR(Z$,A)=" "
0371 E$=STR(Z$,INT((LEN(Z$)+7)/8)*8-7)
0372 LOAD DC T#0,STR(E$,1,8) 9000,9999 BEG  10
   : ERRORGOTO 375
0375 COM CLEAR
   : LOAD DC T#0,"START"
0380 REM %^.K.B./CRT INTERACTION
0390 DIM A$(1)13,M$(1)2
0400 A$(1)=HEX(080D2082313233343536373839)
0410 REM ......CRBSRN.1.2.3.4.5.6.7.8.9
0420 A=1
   : GOTO 560
0430 KEYIN C$,,600
0440 REM LOWER PAD
0450 MAT SEARCHA$(),=C$TO M$()
   : C=VAL(STR(M$(1),2))
0460 IF C=0THEN 642
0470 PRINT STR(D8$,1,A+D-1);BOX(-1,-64);TAB(D1+1)
0480 ON CGOTO 550,530,530,630
0490 REM .....BS..CR..SP..RUN
0500 REM DIGIT
0510 AND (C$,0F)
   : GOTO 600
0520 REM CR CARRIAGE RETURN or SPACE
0530 A=A+1
   : IF A<=ITHEN 560
   : A=1
   : GOTO 560
0540 REM BS BACKSPACE
0550 A=A-1
   : IF A>0THEN 560
   : A=I
0560 PRINT STR(D8$,1,A+D-1);BOX(1,64);TAB(D1);"#";HEX(08);
0570 SELECT PRINT 005
0580 GOTO 430
0590 REM S.F.
0600 $TRAN(C$,HEX(00F0005000420052))R
   : REM .EDIT & PREV SCRN
   : IF C$=HEX(00)THEN 370
0610 C=VAL(C$)
   : IF C>ITHEN 560
0620 PRINT STR(D8$,1,A+D-1);BOX(-1,-64);TAB(D1+1)
   : A=C
0630 PRINT STR(D8$,1,A+D-1);BOX(1,7);TAB(D1);"*";
0640 RETURN
0641 REM .Position cursor by alpha character
0642 C=A
0643 A=A+1
   : IF A>I THEN A=1
   : IF A=C THEN 430
   : IF STR(A1$(A),10,1)<>C$THEN 643
0644 PRINT STR(D8$,1,C+D-1);BOX(-1,-64);TAB(D1+1)
   : GOTO 560
0650 REM % **   SET DISPLAY  ***
0660 I=0
   : RESTORE 2
   : PRINT
   : B=0
0670 READ E$
   : IF E$=" "THEN RETURN
   : B=B+1
0680 A1$(I+1)=E$
0690 A$=STR(E$,10)
   : I=I+1
   : PRINTUSING 320,I,A$
   : GOTO 670
9000 REM   ....!...V1....!....2....!....3....!....4....!....5....!....6....^
9010 DATA "STARTTBO menu"
9157 DATA "GAMES   ]Games from the TBO big disk"
9160 DATA " "