image of READY prompt

Wang2200.org

Listing of file='GOLF' on disk='vmedia/gamesall.wvd.zip'

# Sector 400, program filename = 'GOLF'
0010 REM "GOLF "  WANG 2200-A  4K INTERACTIVE GOLF GAME
0020 DATA "1110","1101","1011","0111"
0030 DATA "1100","1010","1001","0110","0101","0011"
0040 DATA "0001","0010","0100","1000"
0050 %KEY ## for a ##########  Range  ### to ### yards  (##)
0060 REM A()=HOLE YARDAGE  P()=HOLE PAR
0070 REM  P$()=PLAYER NAMES
0080 REM Y=YARDAGE HIT  H=YARDS TO GO   S=SCORE
0090 REM C$()=CLUB NAME  R()=MIN YARDS/CLUB  V()=YARDAGE VAR./CLUB
0100 DIM A(18),P(18),N(4),C$(12)10,R(12),V(12),P$(4),B$(2)6
0105 B$(2)="DUFFED"
0110 SELECT PRINT 005(64)
   : PRINT HEX(03)
0120 GOSUB 990
0125 PRINT "TO START RANDOM NUMBER GENERATOR, ENTER A"
0130 INPUT "NUMBER BETWEEN 100 AND 500",A
   : A=INT(A)
   : IF A<100THEN 130
   : IF A>500THEN 130
   : FOR Z=1TO A
   : A1=RND(1)
   : NEXT Z
   : GOTO 180
0140 DEFFN'15
   : PRINT "YOUR CHOICE OF CLUBS-"
0150 FOR X=1 TO 12
   : PRINTUSING 50,X,C$(X),R(X),R(X)+V(X),X
   : NEXT X
   : RETURN
0160 X=0
   : INPUT "club",X
   : X=INT(X)
   : IF X<1 THEN 160
   : IF X>12 THEN 160
   : IF X=10THEN 160
0170 RETURN
0180 INPUT "HOW MANY PLAYERS (MAX.=4)",U
0190 U=INT(U)
   : IF U<1THEN 180
   : IF U>4THEN 180
   : FOR X=1 TO U
0200 INPUT "Player's name",P$(X)
   : IF P$(X)=" "THEN 200
   : NEXT X
0210 PRINT
0220 DATA 340,4,500,5,218,3,525,5,401,4,184,3,370,4,227,3,516,5
0230 DATA 190,3,344,4,236,3,550,5,427,4,196,3,604,5,355,4,544,5
0240 RESTORE 15
   : FOR R=1TO 18
   : REM SET COURSE PARAMETERS
0250 READ A(R)
   : READ P(R)
0260 NEXT R
0270 E,N(1),N(2),N(3),N(4)=0
0280 FOR J=1TO 18
0290 FOR Q=1TO U
0300 H=A(J)
   : S=0
0310 PRINT HEX(03);"Hole number";J;"is";H;"yards PAR";P(J)
0320 PRINT P$(Q);"'s turn"
0330 GOSUB 160
0340 S=S+1
0350 Y=INT(V(X)*RND(1)+R(X)+.5)
   : B=1
0360 IF S=1THEN 380
   : IF X=11THEN 370
   : IF X=10 THEN 380
   : IF RND(1)>.05THEN 380
0370 Y=INT(1+30*RND(1)+.5)
   : B=2
0380 PRINT HEX(0C090909090909090909);"Hit is";Y;"yards   ";B$(B)
0390 C=H-Y
0400 IF ABS(C)<=21THEN 650
0410 L=INT(RND(1)*100)
   : C=ABS(H-Y)
0420 IF C<=30THEN 440
   : IF (H-Y)>0THEN 440
0430 PRINT " over the green"
   : GOTO 470
0440 IF X=10 THEN 630
   : IF L/9=INT(L/9)THEN 470
0450 IF L/13=INT(L/13) THEN 580
0460 IF L/19=INT(L/19)THEN 620
   : GOTO 630
0470 B=1
0480 A=4
0490 L8=INT(RND(1)*10)
   : IF L8<1THEN 490
   : IF L8>6THEN 490
0500 PRINT "    YOU LIE";S;" *** IN TRAP ***"
0510 S=S+1
0520 IF B<2 THEN 540
   : PRINT "KEY RETURN (EXEC) TO BLAST OUT"
   : INPUT "DON'T FORGET TO RAKE YOUR FOOTPRINTS",A
0530 GOTO 570
0540 RESTORE A+L8
   : READ P1$
0550 INPUT "   WEDGE STROKE (1 - 4)",A1
   : A1=INT(A1)
   : IF A1<1 THEN 550
   : IF A1>4 THEN 550
0560 IF STR(P1$,A1,1)="1" THEN 570
   : B=2
   : GOTO 500
0570 X=10
   : H=C
   : PRINT "CLUB 10"
   :   GOTO 350
0580 PRINT "    YOU LIE";S;".  ^^^  TREES BLOCK THE GREEN  ^^^ !"
0585 PRINT " CADDY SUGGESTS AN 8 OR 9 IRON !"
0590 PRINT "    DISTANCE TO PIN IS(";C;") YARDS"
   : H=C
0591 L=INT(RND(1)*10)
   : IF L<1THEN 591
   : IF L>4THEN 591
0600 GOSUB 160
   : IF X=8 THEN 340
   : IF X=9THEN 340
   : IF L=3 THEN 340
0610 PRINT "  ^^^^^^ IN THE WOODS ^^^^^^"
   : S=S+1
   : PRINT "You lose ONE stroke"
   : PRINT "CARRY YOUR OWN CLUBS YOU F*$##%$#@!%&*&!!!!"
   : GOTO 630
0620 PRINT " IN WATER"
   : S=S+1
   : PRINT "you lose one stroke"
0630 PRINT "    YOU LIE";S;".  DISTANCE TO PIN IS (";C;") YARDS"
0640 H=C
   : IF C>21 THEN 330
0650 FOR I=1TO 500
   : NEXT I
   : C=ABS(C)
   : IF C=0THEN 800
   : PRINT HEX(030A),"ON THE GREEN ... THE PIN IS OUT -- GRAB YOUR PUTTER"
0670 PRINT "YOU LIE";S;"    ";C*3;" FEET FROM CUP"
0680 A=0
0690 L=INT(RND(1)*10)
   : IF L<1 THEN 690
   : IF L>4 THEN 690
0700 IF C<8 THEN 730
   : A=10
0710 IF C>14THEN 730
   : A=4
0720 L=INT(RND(1)*10)
   : IF L<1 THEN 720
   : IF L>6THEN 720
0730 RESTORE A+L
0740 READ P1$
0750 A1=5
   : INPUT "PUTTING STROKE (1 - 4)",A1
   : A1=INT(A1)
   : IF A1<1THEN 750
   : IF A1>4THEN 750
   : S=S+1
0760 IF STR(P1$,A1,1)="0"THEN 770
   : IF C<8 THEN 764
   : PRINT "   DRIBBLE....";
0761 IF C<15 THEN 764
   : PRINT "SQUIBBLE....";
0764 PRINT "TRICKLE....PLUNK!"
   : GOTO 820
0770 C=C-7
0780 IF C>0 THEN 670
0790 INPUT "BALL ON LIP OF CUP, KEY RETURN TO TAP IN",P1$
   : S=S+1
   : PRINT "..PLOP.."
   :   GOTO 820
0800 IF S<>1THEN 810
   : PRINT "$$$  HOLE IN ONE  --- DRINKS ARE ON YOU AT THE CLUBHOUSE  $$$"
   : GOTO 820
0810 PRINT " OFF THE PIN AND IN THE CUP, YOU SUNK THE SHOT, YOU HOT SHIT!!"
0820 N(Q)=N(Q)+S
0830 PRINT
   : PRINT "******************************************"
0840 PRINT S;" Strokes for hole number";J;" PAr";P(J)
0850 PRINT "******************************************"
0860 PRINT
0870 FOR I=1TO 500
   : NEXT I
   : NEXT Q
   : PRINT
0880 E=P(J)+E
0890 PRINT HEX(030A0A);"********** SCORE FOR";J;"HOLES; PAR";E;"**********"
   : PRINT
   : PRINT
0900 FOR W=1TO U
0905 IF N(W)<>ETHEN 910
   : PRINTUSING 907,P$(W),N(W)
0907 %################    SHOT   ###      EVEN
0908 GOTO 930
0910 PRINTUSING 920,P$(W),N(W),N(W)-E
0920 %################    SHOT   ###      +##
0930 NEXT W
0940 FOR L=1TO 550
   : NEXT L
0950 NEXT J
0955 PRINT "********** END OF GAME **********"
0960 INPUT "KEY RETURN(EXEC) TO PLAY ANOTHER GAME",P1$
0970 GOTO 10
0990 C$(1)="1 iron"
   : R(1)=170
   : V(1)=30
1000 C$(2)="2 iron"
   : R(2)=140
   : V(2)=30
1010 C$(3)="3 iron"
   : R(3)=130
   : V(3)=20
1020 C$(4)="4 iron"
   : R(4)=120
   : V(4)=20
1030 C$(5)="5 iron"
   : R(5)=100
   : V(5)=30
1040 C$(6)="6 iron"
   : R(6)=80
   : V(6)=30
1050 C$(7)="7 iron"
   : R(7)=60
   : V(7)=30
1060 C$(8)="8 iron"
   : R(8)=40
   : V(8)=30
1070 C$(9)="9 iron"
   : R(9)=20
   : V(9)=20
1080 C$(10)="SAND WEDGE"
   : R(10)=1
   : V(10)=24
1090 C$(11)="1 wood"
   : R(11)=180
   : V(11)=90
1100 C$(12)="2 wood"
   : R(12)=170
   : V(12)=70
1130 RETURN