Listing of file='KENO' on disk='vmedia/gamesall.wvd.zip'
# Sector 353, program filename = 'KENO'
0010 REM * $25,000.00 KENO * (Version 1.0) - Adapted from an HP-2000 Program c
reated by Carl Davidson -
: DIM D(15),F(20),N(15,15),R(9),K$1
: PRINT HEX(03);"KENO"
: GOSUB 530
: LET T,G,Q=0
0020 PRINT HEX(03070A0A0A0A0A);TAB(18);"***** $25,000.00 KENO *****"
: PRINT HEX(0A0A);TAB(23);"A GAME OF CHANCE"
: FOR Y=1TO 350
: NEXT Y
0030 REM %OPTIONS
0040 PRINT HEX(03)
: INPUT "DO YOU WISH TO REVIEW THE INSTRUCTIONS",K$
: IF K$="N"THEN 50
: IF K$<>"Y"THEN 40
: GOSUB 630
0050 PRINT HEX(03)
: INPUT "DO YOU WANT TO SEE THE TABLE OF TICKET PRICES/PAYOFFS ",K$
: IF K$="N"THEN 60
: IF K$<>"Y"THEN 50
: GOSUB 890
0060 PRINT HEX(03)
: INPUT "WHAT WAS THE NUMBER OF LAST GAME PLAYED ",A
: IF A<0THEN 60
: IF INT(A)<>ATHEN 60
: PRINT HEX(03);"GETTING READY..."
: FOR X=1TO 30*A
: LET B=RND(1)
: NEXT X
: LET G=A
0070 PRINT HEX(03)
: INPUT "DO YOU WANT ME TO SUPPRESS NUMBER PRINTOUT ",K$
: IF K$<>"N"THEN 80
: GOTO 90
0080 IF K$<>"Y"THEN 70
0090 IF K$="N"THEN 100
: B=1
: GOTO 120
0100 B=0
0110 REM %SPOTS?
0120 PRINT HEX(03)
: INPUT "HOW MANY SPOTS ",A
: IF A<>0THEN 130
: END
0130 IF A>=1THEN 140
: GOTO 160
0140 IF A<=15THEN 150
: GOTO 160
0150 IF INT(A)=ATHEN 180
: GOTO 160
0160 PRINT HEX(0307);"NUMBER MUST BE AN INTEGER FROM 1 TO 15."
: FOR N=1TO 750
: NEXT N
: GOTO 120
0170 REM %MARK SPOTS
0180 IF A>1THEN 190
: PRINT HEX(03);"WHAT IS YOUR NUMBER ";
: GOTO 200
0190 PRINT HEX(03);"WHAT ARE YOUR NUMBERS ";
0200 FOR X=1TO A
: INPUT D(X)
: NEXT X
: FOR X=1TO A
: IF D(X)>=1THEN 210
: GOTO 230
0210 IF D(X)<=80THEN 220
: GOTO 230
0220 IF INT(D(X))=D(X)THEN 240
0230 PRINT HEX(0307);"EACH NUMBER MUST BE AN INTEGER FROM 1 TO 80."
: FOR N=1TO 750
: NEXT N
: X=A+1
: NEXT X
: GOTO 130
0240 NEXT X
: IF A=1THEN 270
: FOR X=1TO A-1
: FOR Y=X+1TO A
: IF D(X)<>D(Y)THEN 250
: PRINT HEX(0307);"EACH NUMBER MUST BE UNIQUE."
: Y=A+1
: NEXT Y
: X=A
: NEXT X
: FOR N=1TO 750
: NEXT N
: GOTO 130
0250 NEXT Y
: NEXT X
0260 REM %BET
0270 PRINT HEX(03)
: INPUT "WHAT IS YOUR BET ",E
: IF E>=0THEN 290
0280 PRINT HEX(0307);"BET IS NOT A MULTIPLE OF BASIC TICKET RATE."
: FOR N=1TO 750
: NEXT N
: GOTO 270
0290 IF E<=25000THEN 300
: PRINT HEX(0307);"BET LIMIT: $25,000.00"
: FOR N=1TO 750
: NEXT N
: GOTO 270
0300 LET P=0
: LET E=INT(100*E+.5)
: IF A=9THEN 320
0310 IF INT(E/60)*60<>ETHEN 280
: GOTO 330
0320 IF INT(E/40)*40<>ETHEN 310
: LET P=1
0330 FOR X=1TO 20
: LET F(X)=INT(80*RND(1)+1)
: NEXT X
0340 FOR X=1TO 19
: FOR Y=X+1TO 20
: IF F(X)<>F(Y)THEN 350
: LET F(Y)=INT(80*RND(1)+1)
: Y=X+2
: NEXT Y
: X=20
: NEXT X
: GOTO 340
0350 NEXT Y
: NEXT X
: LET G=G+1
: IF B=0THEN 370
: PRINT "GAME NO. ";G
: GOTO 380
0360 REM %DISPLAY RESULTS
0370 PRINT "*************************** GAME NO. ";G;
: PRINT "***************************"
0380 LET L=0
: FOR X=1TO 20
: FOR Y=1TO A
: IF F(X)<>D(Y)THEN 400
: LET L=L+1
: IF B=1THEN 390
: PRINT " *";F(X),
0390 Y=A+1
: NEXT Y
: GOTO 410
0400 NEXT Y
: IF B=1THEN 410
: PRINT " ";F(X),
0410 NEXT X
: IF B=1THEN 440
0420 PRINT "************************************";
: PRINT "************************************"
0430 REM %CALCULATE PAYOFF
0440 IF L<>0THEN 450
: LET Q=0
: GOTO 460
0450 LET Q=(E/60)*INT(100*N(A,L)+.5)
: IF P<>1THEN 460
: LET Q=(E/40)*INT(100*R(L)+.5)
0460 IF Q<>0THEN 470
: PRINT "NO PAYOFF"
: GOTO 500
0470 IF Q<=2.5E6THEN 480
: LET Q=2.5E6
0480 IF L=1THEN 490
: PRINT L;"SPOTS OUT OF";A;"PAYS $";Q/100
: GOTO 500
0490 PRINT L;"SPOT OUT OF";A;"PAYS $";Q/100
0500 LET T=T+(Q-E)
: IF T<0THEN 510
: PRINTUSING 1180,T/100
: FOR N=1TO 1E3
: NEXT N
: GOTO 120
0510 PRINTUSING 1190,ABS(T/100)
: FOR N=1TO 1E3
: NEXT N
: GOTO 120
0520 REM %INITIALIZE MATRICES
0530 MAT N=ZER
: LET N(6,3)=.35
: LET N(5,3),N(12,5)=.5
0540 LET N(3,2),N(4,2),N(7,4)=.6
: LET N(13,6),N(15,6)=1
: LET N(10,5)=1.2
: LET N(1,1)=1.8
: LET N(6,4),N(9,5),N(14,6)=2
: LET N(4,3)=2.5
: LET N(12,6)=3
: LET N(5,4),N(8,5),N(14,7),N(15,7)=5
: LET N(11,6)=6
: LET N(2,2)=7.5
0550 LET N(13,7)=10
: LET N(7,5),N(10,6)=12
: LET N(15,8)=14
: LET N(12,7)=18
0560 LET N(14,8)=20
: LET N(3,3)=26
: LET N(9,6)=30
: LET N(8,6),N(11,7),N(13,8),N(15,9)=50
: LET N(6,5)=60
: LET N(4,4)=70
: LET N(10,7)=90
: LET N(12,8)=130
: LET N(15,10)=150
: LET N(14,9)=160
: LET N(9,7)=175
: LET N(7,6)=245
0570 LET N(11,8)=250
: LET N(12,9)=375
: LET N(13,9)=450
: LET N(14,10)=500
: LET N(5,5)=535
0580 LET N(10,8)=660
: LET N(12,10)=900
: LET N(8,7)=1100
: LET N(11,9)=1200
: LET N(6,6)=1250
: LET N(14,11),N(15,11)=1500
: LET N(10,9),N(13,10)=2400
: LET N(9,8)=3000
: LET N(13,11)=4500
0590 LET N(12,11),N(14,12),N(15,12)=5000
: LET N(7,7)=5500
: LET N(11,10)=7500
: LET N(13,12)=10000
0600 LET N(10,10)=12000
: LET N(8,8),N(9,9),N(11,11)=12500
: LET N(14,13),N(15,13)=15000
: LET N(15,14)=20000
: LET N(12,12),N(13,13),N(14,14),N(15,15)=25000
: MAT R=ZER
: LET R(4)=.2
: LET R(5)=2
: LET R(6)=18
: LET R(7)=112
0610 LET R(8)=1100
: LET R(9)=7500
: RETURN
0620 REM %INSTRUCTIONS
0630 PRINT HEX(03);TAB(20);"KENO INSTRUCTIONS"
0640 PRINT TAB(20);"-----------------"
: PRINT "DURING EACH GAME OF KENO, TWENTY NUMBERS FROM 1 TO 80";
: PRINT "ARE SELECTED AT RANDOM BY THE COMPUTER."
0650 PRINT "PRIOR TO EACH GAME, THE PLAYER MAY CHOOSE FROM ONE TO";
0660 PRINT "FIFTEEN NUMBERS, OR 'SPOTS' HE THINKS WILL BE";
: PRINT "SELECTED DURING THE GAME. THE PLAYER ENTERS OR";
: PRINT "'MARKS' THE DESIRED SPOTS AND PLACES A BET."
0670 PRINT "AT THE END OF EACH GAME, THE SPOTS MARKED BY THE PLAYER";
0680 PRINT "ARE COMPARED WITH THE TWENTY NUMBERS SELECTED BY THE";
: PRINT "COMPUTER AND THE PAYOFF IS CALCULATED ACCORDINGLY."
: PRINT "PRESS 'EXECUTE' TO CONTINUE."
0690 KEYIN K$,700,690
: GOTO 690
0700 PRINT HEX(03);"HOW TO PLAY"
: PRINT "-----------"
0710 PRINT "THE FOLLOWING ARE THE MESSAGES TYPED BY THE COMPUTER";
: PRINT "WITH EXPLANATIONS OF THE RESPONSES EXPECTED:";
0720 PRINT "MESSAGE: HOW MANY SPOTS?","RESPONSE: ENTER A NUMBER FROM 1 TO 15 (
ENTER 0 TO END GAME).";
0730 PRINT "MESSAGE: WHAT IS(ARE) YOUR NUMBER(S)?","RESPONSE: ENTER EACH NUMBE
R (BETWEEN 1 & 80) AND PRESS 'EXECUTE'";
0740 PRINT "MESSAGE: WHAT IS YOUR BET?","RESPONSE: A BET MAY BE ANY MULTIPLE O
F THE BASIC RATE FOR ALL TICKETS (.60).";
0750 PRINT "BETS FOR 9-SPOT MAY BE MULTIPLES OF .60 OR .40. A BET OF 0 MAY AL
SO BE ENTERED IF YOU WISH ONLY TO OBSERVE A GAME WITHOUT BETTING."
: PRINT "PRESS 'EXECUTE' TO CONTINUE."
0760 KEYIN K$,770,760
: GOTO 760
0770 PRINT HEX(03);"PROGRAM OPTIONS"
0780 PRINT "---------------"
: PRINT "THE FOLLOWING ARE THE OPTIONS FOR PLAYING KENO - THEY ARE OF
FERED AT THE BEGINNING OF THE GAME:";
0790 PRINT "MESSAGE: DO YOU WANT TO SEE THE TABLE OF TICKET PRICES/PAYOFFS?","
RESPONSE: RESPOND WITH YES OR NO.";
0800 PRINT "MESSAGE: WHAT IS THE NUMBER OF THE LAST GAME PLAYED?";
: PRINT "RESPONSE: EACH GAME IS NUMBERED. IF THIS IS A REPEAT, ENTER THENUM
BER OF THE LAST GAME. FOR A NEW START, ENTER 0";
0810 PRINT "PRESS 'EXECUTE' TO CONTINUE."
0820 KEYIN K$,830,820
: GOTO 820
0830 PRINT HEX(03);"MESSAGE: DO YOU WANT ME TO SUPRESS NUMBER PRINTOUT?";
0840 PRINT "RESPONSE: THE TWENTY NUMBERS SELECTED BY THE COMPUTER FOR EACH GA
ME ARE NORMALLY PRINTED, THE PRINTING IS SUPPRESSED IF YOU ANSWER WITH
'NO'."
0850 PRINT "PRESS 'EXECUTE' TO CONTINUE."
0860 KEYIN K$,870,860
: GOTO 860
0870 RETURN
0880 REM %PAYOFF TABLE
0890 PRINT HEX(03);TAB(23);"KENO TICKET PRICES/PAYOFFS"
: PRINT TAB(23);"--------------------------"
: LET X=0
: GOSUB 1130
: PRINT "1";TAB(10);"1.80";TAB(16);"2";TAB(26);"7.50";TAB(32);"2";TAB(43);
: PRINT ".60";TAB(48);"2";TAB(59);".60"
0900 PRINT TAB(32);"3";TAB(41);"26.00";TAB(48);"3";TAB(58);"2.50"
: PRINT TAB(48);"4";TAB(57);"70.00"
: PRINT "PRESS 'EXECUTE' TO CONTINUE."
0910 KEYIN K$,920,910
: GOTO 910
0920 PRINT HEX(03)
: GOSUB 1130
: PRINT "3";TAB(11);".50";TAB(16);"3";TAB(27);".35";TAB(32);"4";TAB(43);".6
0";
: PRINT TAB(48);"5";TAB(58);"5.00"
0930 PRINT "4";TAB(10);"5.00";TAB(16);"4";TAB(26);"2.00";TAB(32);"5";TAB(41);
: PRINT "12.00";TAB(48);"6";TAB(57);"50.00"
: PRINT "5";TAB(8);"535.00";TAB(16);"5";TAB(25);"60.00";TAB(32);
0940 PRINT "6";TAB(40);"245.00";TAB(48);"7";TAB(54);"1,100.00"
: PRINT TAB(16);"6";TAB(22);"1,250.00";TAB(32);"7";TAB(38);"5,500.00";
0950 PRINT TAB(48);"8";TAB(53);"12,500.00"
: PRINT "PRESS 'EXECUTE' TO CONTINUE."
0960 KEYIN K$,970,960
: GOTO 960
0970 PRINT HEX(03)
: GOSUB 1130
: PRINT "4";TAB(10);".20";TAB(16);"5";TAB(26);"2.00";TAB(32);"5";TAB(42);
: PRINT "1.20";TAB(48);"6";TAB(58);"6.00"
: PRINT "5";TAB(9);"2.00";TAB(16);"6";TAB(25);"30.00";TAB(32);
0980 PRINT "6";TAB(41);"12.00";TAB(48);"7";TAB(57);"50.00"
: PRINT "6";TAB(8);"18.00";TAB(16);"7";TAB(24);"175.00";TAB(32);"7";
: PRINT TAB(41);"90.00";TAB(48);"8";TAB(56);"250.00"
0990 PRINT "7";TAB(7);"112.00";TAB(16);"8";TAB(22);"3,000.00";TAB(32);"8";
: PRINT TAB(40);"660.00";TAB(48);"9";TAB(54);"1,200.00"
1000 PRINT "8";TAB(5);"1,100.00";TAB(16);"9";TAB(21);"12,500.00";TAB(32);
: PRINT "9";TAB(38);"2,400.00";TAB(48);"10";TAB(54);"7,500.00"
: PRINT "9";TAB(5);"7,500.00";TAB(32);"10";TAB(37);"12,000.00";
1010 PRINT TAB(48);"11";TAB(53);"12,500.00"
: PRINT "PRESS 'EXECUTE' TO CONTINUE."
1020 KEYIN K$,1030,1020
: GOTO 1020
1030 PRINT HEX(03)
: GOSUB 1130
: PRINT "5";TAB(10);".50";TAB(16);"6";TAB(26);"1.00";TAB(32);"6";TAB(43);
: PRINT "2.00";TAB(48);"6";TAB(58);"1.00"
: PRINT "6";TAB(9);"3.00";TAB(16);"7";TAB(25);"10.00";TAB(32);"7";
: PRINT TAB(43);"5.00";TAB(48);"7";TAB(58);"5.00"
1040 PRINT "7";TAB(8);"18.00";TAB(16);"8";TAB(25);"50.00";TAB(32);"8";
1050 PRINT TAB(42);"20.00";TAB(48);"8";TAB(57);"14.00"
: PRINT "8";TAB(7);"130.00";TAB(16);"9";TAB(24);"450.00";TAB(32);"9";
: PRINT TAB(41);"160.00";TAB(48);"9";TAB(57);"50.00"
1060 PRINT "9";TAB(7);"375.00";TAB(16);"10";TAB(22);"2,400.00";TAB(32);
: PRINT "10";TAB(41);"500.00";TAB(48);"10";TAB(56);"150.00"
1070 PRINT "10";TAB(7);"900.00";TAB(16);"11";TAB(22);"4,500.00";TAB(32);
: PRINT "11";TAB(39);"1,500.00";TAB(48);"11";TAB(54);"1,500.00"
: PRINT "11";TAB(5);"5,000.00";TAB(16);"12";TAB(21);"10,000.00";
1080 PRINT TAB(32);"12";TAB(39);"5,000.00";TAB(48);"12";TAB(54);"5,000.00"
1090 PRINT "12";TAB(4);"25,000.00";TAB(16);"13";TAB(21);"25,000.00";
: PRINT TAB(32);"13";TAB(38);"15,000.00";TAB(48);"13";TAB(53);"15,000.00"
: PRINT TAB(32);"14";TAB(38);"25,000.00";TAB(48);"14";TAB(53);"20,000.00"
1100 PRINT TAB(48);"15";TAB(53);"25,000.00"
: PRINT "PRESS 'EXECUTE' TO CONTINUE."
1110 KEYIN K$,1120,1110
: GOTO 1110
1120 RETURN
1130 LET X=X+4
: IF X=12THEN 1150
: PRINT "MARK";X-3;"SPOTS";TAB(16);"MARK";X-2;"SPOTS";TAB(32);"MARK";
: PRINT X-1;"SPOTS";TAB(48);"MARK";X;"SPOTS"
: PRINT "SPOTS .60 PAYS";TAB(16);"SPOTS .60 PAYS";TAB(32);
1140 PRINT "SPOTS .60 PAYS";TAB(48);"SPOTS .60 PAYS"
: RETURN
1150 PRINT "MARK";X-3;"SPOTS";TAB(16);"MARK";X-3;"SPOTS";TAB(32);"MARK";
: PRINT X-2;"SPOTS";TAB(48);"MARK";X-1;"SPOTS"
: PRINT "SPOTS .40 PAYS";TAB(16);"SPOTS .60 PAYS";TAB(32);
1160 PRINT "SPOTS .60 PAYS";TAB(48);"SPOTS .60 PAYS"
: LET X=X-1
: RETURN
1170 REM %IMAGES
1180 %TOTAL WINNINGS $ ###,###,###.##
1190 %TOTAL LOSSES $ ###,###,###.##
1200 REM $