Listing of file='RUMMY' on disk='vmedia/gamesall.wvd.zip'
# Sector 442, program filename = 'RUMMY'
0010 REM "RUMMY"
: PRINT HEX(03)
0020 PRINT "SO YOU WANT TO PLAY A GAME OF FOUR CARD RUMMY WITH ME!!!"
0030 PRINT "TO WIN YOU HAVE TO HAVE FOUR OF A KIND. THE TOP ROW OF CARDS"
0040 PRINT "ARE MINE, THE MIDDLE CARD IS THE DISCARD, AND THE BOTTOM ROW"
0050 PRINT "OF CARDS ARE YOURS. LET'S PLAY!!"
0060 GOSUB '22(3)
: DIM D$(4,13)1,H$(2,4)3,A$1,C$3,C1$3,X$3,Y$3
: GOSUB '00
0070 FOR I=1TO 4
: FOR H=1TO 2
: GOSUB '01(S,C)
: GOSUB '02(S,C)
: H$(H,I)=C$
: NEXT H
: NEXT I
: FOR H=1TO 2
: GOSUB '05(H)
: IF A$="Y"THEN 70
: NEXT H
: GOSUB '01(S,C)
: GOSUB '02(S,C)
: GOSUB '03(C$)
0080 GOSUB '11(2)
0090 PRINT "THE FIRST CARD UP IS ";C$;". DO YOU WANT IT";
: INPUT A$
0100 IF A$="Y"THEN 200
: IF A$="N"THEN 110
: GOSUB '10
: GOTO 90
0110 GOSUB '04(C$,2)
: GOSUB '11(2)
: IF A$="Y"THEN 220
: PRINT ,"I DON'T WANT IT EITHER"
: GOSUB '22(.75)
: PRINT HEX(0C)
0120 GOSUB '01(S,C)
: GOSUB '02(S,C)
0130 PRINT "THE NEXT CARD UP IS ";C$;". DO YOU WANT IT";
: INPUT A$
0140 IF A$="Y"THEN 230
: IF A$="N"THEN 150
: GOSUB '10
: GOTO 130
0150 C1$=C$
: GOSUB '03(C1$)
0160 PRINT ,"HMMMMMM. LET'S SEE NOW......"
: GOSUB '22(.75)
0170 GOSUB '04(C1$,2)
: GOSUB '11(2)
: IF A$="Y"THEN 220
: GOSUB '01(S,C)
: GOSUB '02(S,C)
: GOSUB '04(C$,2)
: GOSUB '11(2)
: IF A$="Y"THEN 220
: C1$=C$
: GOSUB '03(C1$)
0180 INPUT "DO YOU WANT MY DISCARD",A$
: PRINT HEX(0C)
: IF A$="N"THEN 120
: IF A$="Y"THEN 190
: GOSUB '10
: GOTO 180
0190 C$=C1$
0200 INPUT "WHICH CARD DO YOU WISH TO DISCARD",C1$
: GOSUB '08(C1$)
: IF A$="Y"THEN 210
: GOTO 200
0210 C1$=X$
: GOSUB '09(C$,C1$,1)
: GOTO 250
0220 GOSUB '05(2)
: IF A$="Y"THEN 260
: GOSUB '03(C1$)
: GOTO 180
0230 INPUT "WHAT CARD DO YOU WANT TO GIVE AWAY",C1$
: GOSUB '08(C1$)
: IF A$="Y"THEN 240
: GOTO 230
0240 C1$=X$
: GOSUB '09(C$,C1$,1)
0250 GOSUB '03(C1$)
: PRINT ,"VERY INTERESTING !!!!"
: GOSUB '22(.75)
: GOSUB '05(1)
: IF A$="Y"THEN 270
: GOTO 170
0260 GOSUB '03(C1$)
: GOSUB '20
: PRINT ,"AH HA! FOUR OF A KIND! I WIN!!!"
: GOTO 280
0270 GOSUB '20
: PRINT ,"YOU LUCKY !!#*@*#??, YOU WIN!!"
0280 PRINT
: INPUT "DO YOU WANT TO PLAY ANOTHER GAME OF RUMMY",A$
0290 IF A$<>"Y"THEN 300
: GOSUB '00
: GOTO 70
0300 END
0310 DEFFN'00
: FOR C=1TO 13
: FOR S=1TO 4
: D$(S,C)="C"
: NEXT S
: NEXT C
: RETURN
0320 DEFFN'01(S,C)
: C=INT(13*RND(1)+1)
: S=INT(4*RND(2)+1)
0330 IF D$(S,C)="E"THEN 320
0340 D$(S,C)="E"
: RETURN
0350 DEFFN'02(S,C)
0360 DATA " A"," 2"," 3"," 4"," 5"," 6"," 7"," 8"," 9","10"," J"," Q"," K","D"
,"C","H","S"
0370 RESTORE C
: READ STR(C$,1,2)
: RESTORE S+13
: READ STR(C$,3,1)
: RETURN
0380 DEFFN'04(X$,H)
: I=1
0390 IF STR(X$,1,2)=STR(H$(H,I),1,2)THEN 410
: IF I=4THEN 400
: I=I+1
: GOTO 390
0400 A$="N"
: GOTO 460
0410 A$="Y"
: IF STR(X$,1,2)=STR(H$(H,1),1,2)THEN 440
: I=1
0420 IF STR(X$,1,2)<>STR(H$(H,I),1,2)THEN 450
: I=I+1
: GOTO 420
0430 IF STR(X$,1,2)=STR(H$(H,1),1,2)THEN 400
0440 IF STR(H$(H,2),1,2)=STR(H$(H,3),1,2)THEN 400
: GOTO 420
0450 Y$=H$(H,I)
: H$(H,I)=X$
: C1$=Y$
0460 RETURN
0470 DEFFN'06(X$)
: IF STR(X$,1,2)="10"THEN 480
: STR(X$,3,1)=STR(X$,2,1)
: STR(X$,2,1)=STR(X$,1,1)
: STR(X$,1,1)=" "
0480 RETURN
0490 DEFFN'09(X$,Y$,H)
: I=1
0500 IF Y$=H$(H,I)THEN 520
0510 I=I+1
: GOTO 500
0520 C1$=Y$
: H$(H,I)=X$
0530 RETURN
0540 DEFFN'05(H)
: I=1
: N=2
0550 IF STR(H$(H,I),1,2)<>STR(H$(H,N),1,2)THEN 570
: IF N=4THEN 560
: N=N+1
: GOTO 550
0560 A$="Y"
: GOTO 580
0570 A$="N"
0580 RETURN
0590 DEFFN'03(X$)
: PRINT HEX(030A)
: PRINTUSING 610
0600 % ###
0610 % XX XX XX XX
0620 PRINT HEX(0A0A0A0A)
: PRINT TAB(25);X$
: PRINT HEX(0A0A0A0A)
: FOR I=1TO 4
: PRINTUSING 600,H$(1,I);
: NEXT I
: PRINT
: PRINT
: RETURN
0630 DEFFN'20
: PRINT HEX(010A)
: FOR I=1TO 4
: PRINTUSING 600,H$(2,I);
: NEXT I
: PRINT
: PRINT
: RETURN
0640 DEFFN'22(P)
: FOR I=1TO 50*P
: X=2^8
: NEXT I
: RETURN
0650 DEFFN'08(X$)
: GOSUB '06(X$)
: I=1
0660 IF I=5THEN 690
: IF X$=H$(1,I)THEN 680
0670 I=I+1
: GOTO 660
0680 A$="Y"
: GOTO 700
0690 A$="N"
0700 IF A$="Y"THEN 710
: GOSUB '10
0710 RETURN
0720 DEFFN'10
: PRINT "DOES NOT COMPUTE!!!!!!!!!!!!"
: RETURN
0730 DEFFN'12(H,I,J)
: X$=H$(H,I)
: H$(H,I)=H$(H,J)
: H$(H,J)=X$
: RETURN
0740 DEFFN'11(H)
: N=0
: IF STR(H$(H,3),1,2)=STR(H$(H,4),1,2)THEN 780
: N=0
: FOR A=1TO 3
: FOR B=A+1TO 4
: IF STR(H$(H,A),1,2)<>STR(H$(H,B),1,2)THEN 750
: N=B
: I=A
: A=3
: B=4
0750 NEXT B
: NEXT A
: IF N=0THEN 790
0760 IF N>2THEN 770
: GOSUB '12(H,I,3)
: GOSUB '12(H,I,4)
: GOTO 780
0770 GOSUB '12(H,I,7-N)
: GOTO 790
0780 IF STR(H$(H,1),1,2)<>STR(H$(H,3),1,2)THEN 790
: GOSUB '12(H,1,2)
0790 RETURN