image of READY prompt

Wang2200.org

Listing of file='SLOTMACH' on disk='vmedia/gamesall.wvd.zip'

# Sector 295, program filename = 'SLOTMACH'
0001 %YOUR CURRENT BALANCE IS $#,###,###
0010 DIM S$(6)8
   : S$(1)="   LEMON"
   : S$(2)="  CHERRY"
   : S$(3)="  ORANGE"
   : S$(4)="    PLUM"
   : S$(5)="    BELL"
   : S$(6)=" LIBERTY"
0020 DIM W$40
   : FOR I=1TO 40
   : STR(W$,I,1)=HEX(09)
   : NEXT I
0025 DIM W1$9
   : W1$=HEX(0A0808080808080808)
0030 DIM T(3),P(3,6),R(9)
0035 FOR I=1TO 9
   : R(I)=INT(1+5*RND(1))
   : NEXT I
0040 FOR I=1TO 3
   : FOR J=1TO 6
   : READ P(I,J)
   : NEXT J
   : NEXT I
   : E4=0
0080 %######## ######## ######## ##
0120 PRINT HEX(03),,"****ONE-ARMED BANDIT****"
   : PRINT
0300 PRINT "EACH PLAY YOU CAN ENTER ANY AMOUNT OF SILVER DOLLARS"
0310 PRINT "INTO THE MACHINE UP TO THE BALANCE YOU HAVE BY TYPING"
0320 PRINT "IN THE QUANTITY OF DOLLARS."
0325 PRINT
0340 PRINT "YOU 'PULL DOWN THE HANDLE' BY DEPRESSING THE CR/LF KEY."
0350 PRINT
0360 PRINT "WHEN YOUR BALANCE REACHES ZERO,THE GAME IS OVER..."
0375 FOR Z=1TO 1000
   : NEXT Z
0380 DEFFN'0
   : S=INT(30+15*RND(1))
   : PRINT HEX(03)
   : GOSUB '15
0400 PRINT HEX(010A0A0A0A)
0410 PRINT
   : PRINT TAB(63);HEX(0C)
   : PRINTUSING 1,S;
   : Z=0
0415 INPUT "DOLLARS BET=",Z
0420 Z=INT(Z)
   : IF Z<1THEN 440
   : IF Z<S+1THEN 470
0440 PRINT "***ILLEGAL PLAY-----TRY AGAIN***"
   : GOTO 400
0470 PRINT TAB(63)
   : REM CLEAROUT WIN/LOSE
0480 FOR W=1 TO INT(1+30*RND(1))
   : REM WHEELS 1,2,3
0485 GOSUB 1431
   : GOSUB 1434
   : GOSUB 1437
   : NEXT W
0490 FOR W=1TO INT(1+20*RND(1))
   : REM WHEELS 2 AND 3
0495 GOSUB 1434
   : GOSUB 1437
   : NEXT W
0500 FOR W=1 TO INT(1+15*RND(1))
   : REM WHEEL 3
0505 GOSUB 1437
   : NEXT W
0600 PRINT
   : PRINT
0830 D=100*R(1)+10*R(2)+1*R(3)
0840 W=2
   : IF D=221THEN 1300
   : IF D=223THEN 1300
   : IF D=224THEN 1300
0860 W=4
   : IF D=225THEN 1300
   : W=6
   : IF D=226THEN 1300
0880 W=10
   : IF D=333THEN 1300
   : W=12
   : IF D=444THEN 1300
0900 W=14
   : IF D=555THEN 1300
   : W=16
   : IF D=336THEN 1300
0920 W=18
   : IF D=446THEN 1300
0940 W=20
   : IF D=556THEN 1300
   : IF D=666THEN 1190
0960 PRINT "....YOU LOSE...$";Z
   : S=S-Z
   : IF S<1THEN 1410
   : GOTO 400
1190 W=INT(200+400*RND(1))
   : PRINT "...JACKPOT OF $";W
1210 S=S+W-Z
   : GOTO 400
1300 W=W*Z
   : PRINT "...YOU WIN $";W
   : GOTO 1210
1410 PRINT "YOU HAVE RUN OUT OF MONEY..."
1420 PRINT "...THE GAME IS OVER...BETTER LUCK NEXT TIME SUCKER"
1430 PRINT TAB(63)
   : PRINT TAB(63)
   : PRINT TAB(63)
   : END
1431 R(1)=R(4)
   : R(4)=R(7)
   : REM WHEEL 1
1432 GOSUB '36(1)
   : R(7)=T(1)
1433 GOSUB '35(R(1),R(4),R(7),15)
   : RETURN
1434 R(2)=R(5)
   : R(5)=R(8)
   : REM WHEEL 2
1435 GOSUB '36(2)
   : R(8)=T(2)
1436 GOSUB '35(R(2),R(5),R(8),26)
   : RETURN
1437 R(3)=R(6)
   : R(6)=R(9)
   : REM WHEEL 3
1438 GOSUB '36(3)
   : R(9)=T(3)
1439 GOSUB '35(R(3),R(6),R(9),37)
   : RETURN
1440 DATA .10,.40,.65,.83,.94,1
   : REM WHEEL 1 DATA
1450 DATA .10,.45,.65,.80,.90,1
   : REM WHEEL 2 DATA
1460 DATA .30,.40,.70,.82,.96,1
   : REM WHEEL 3 DATA
1600 DEFFN'15
   : SELECT PRINT 005(64)
   : PRINT HEX(03),,"*WANG 2200 SLOT MACHINE*"
1602 PRINT HEX(0A);TAB(10);"--->";TAB(47);"<---"
1605 PRINT HEX(0A0A0A0A0A)
1610 GOSUB '34(2,2,1,2)
   : GOSUB '33(2,2,3,2)
   : GOSUB '34(2,2,4,2)
1620 GOSUB '33(2,2,5,4)
   : GOSUB '34(2,2,6,6)
   : GOSUB '33(3,3,3,10)
1630 GOSUB '34(4,4,4,12)
   : GOSUB '33(5,5,5,14)
   : GOSUB '34(3,3,6,16)
1640 GOSUB '33(4,4,6,18)
   : GOSUB '33(5,5,6,20)
1650 PRINTUSING 80,S$(6),S$(6),S$(6);
   : PRINT "   JACKPOT"
   : RETURN
1990 DEFFN'33(A,B,C,D)
   : PRINTUSING 80,S$(A),S$(B),S$(C),D
   : RETURN
2000 DEFFN'34(A,B,C,D)
   : PRINTUSING 80,S$(A),S$(B),S$(C),D;
   : RETURN
2025 DEFFN'35(A,B,C,D)
   : PRINT HEX(010A0A);STR(W$,1,D);S$(A);HEX(0A)
   : RETURN
2040 DEFFN'36(I)
   : R=RND(1)
   : FOR J=1TO 6
   : T(I)=J
2050 IF R<P(I,J)THEN 2060
   : NEXT J
   : RETURN
2060 J=6
   : NEXT J
   : RETURN