image of READY prompt

Wang2200.org

Listing of file='13A' on disk='vmedia/glbr_22.wvd.zip'

# Sector 758, program filename = '13A'
0001 DIM X(4,2),N(2),S(2),U(2),M(2)
0005 PRINT "HYPOTHESIS TO BE TESTED?"
0010 INPUT H
0015 IF H=4 THEN 400
0020 FOR I=1 TO 1.7+H/5
0022 S(I),U(I)=0
0025 PRINT
0030 PRINT "NO. OF ELEMENTS IN SAMPLE";I
0035 INPUT N(I)
0040 PRINT "ENTER SAMPLE";I
0045 FOR J=1 TO N(I) STEP 4
0050 INPUT X(1,I),X(2,I),X(3,I),X(4,I)
0055 FOR K=1 TO 4
0060 S(I)=S(I)+X(K,I)
0065 U(I)=U(I)+X(K,I)^2
0070 NEXT K
0075 NEXT J
0080 M(I)=S(I)/N(I)
0085 S(I)=(U(I)-S(I)^2/N(I))/(N(I)-1)
0090 NEXT I
0095 PRINT
0100 IF H=2 THEN 200
0110 IF H=3 THEN 300
0120 PRINT "ENTER GIVEN VALUE OF MEAN"
0130 INPUT K
0140 T=(M(1)-K)*SQR(N(1)/S(1))
0150 D=N(1)-1
0160 GOTO 600
0200 T=(M(1)-M(2))/SQR(1/N(1)+1/N(2))
0210 D=N(1)+N(2)-2
0220 T=T/SQR(((N(1)-1)*S(1)+(N(2)-1)*S(2))/D)
0230 GOTO 600
0300 T=(M(1)-M(2))/SQR(S(1)/N(1)+S(2)/N(2))
0310 D=(S(1)/N(1)+S(2)/N(2))^2
0320 D=D/((S(1)/N(1))^2/(N(1)+1)+(S(2)/N(2))^2/(N(2)+1))-2
0330 D=INT(D+.5)
0340 GOTO 600
0400 PRINT
0410 PRINT "NO. OF PAIRS OF ELEMENTS?"
0420 INPUT N(1)
0430 PRINT "ENTER SAMPLES (1 PAIR/LINE)"
0435 S(1),S(2)=0
0440 FOR I=1 TO N(1)
0450 INPUT X(1,1),X(1,2)
0460 D=X(1,1)-X(1,2)
0470 S(1)=S(1)+D
0480 S(2)=S(2)+D^2
0490 NEXT I
0500 T=S(1)/N(1)*SQR(N(1)-1)
0510 T=T/SQR(S(2)/N(1)-(S(1)/N(1))^2)
0520 D=N(1)-1
0600 PRINT
0610 PRINT "T VALUE=";ABS(T)
0620 PRINT "DEG. FREEDOM=";D
0630 END