image of READY prompt

Wang2200.org

Listing of file='HLDA010A' on disk='vmedia/letter_editor.wvd.zip'

# Sector 49, program filename = 'HLDA010A'
0010 REM ***** HLDA010A - REVISED 1540 08/18/76 ***** COPYRIGHT WANG LABS, 197
     6
0020 DIM A9$30
   : DIM Q$64,Q1$64,Q2$64,N$(16),B$(80)1
   : GOSUB 1040
   : GOSUB '15
   : STOP
0060 DEFFN'0
0070 DEFFN'16
   : GOSUB '35("MOVE TEXT")
   : LOAD DC T#1,"HLDA010J"
0100 DEFFN'1
0110 DEFFN'17
   : GOSUB '35("TEXT EDITOR")
   : LOAD DC T#1,"HLDA010E"
0280 DEFFN'2
0290 DEFFN'18
   : GOSUB '35("GLOBAL REPLACE")
   : LOAD DC T#1,"HLDA010H"
0320 DEFFN'3
0330 DEFFN'19
   : GOSUB '35("DOCUMENT/LETTER ASSEMBLY")
   : LOAD DC T#1,"HLDA010F"
0470 DEFFN'4
0475 DEFFN'20
   : GOSUB '35("DISK TABLE OF CONTENTS")
   : LOAD DC T#1,"HLDA010C"
0500 DEFFN'5
0510 DEFFN'21
   : GOSUB '35("DELETE A DOCUMENT FROM DISK")
0530 DEFFN'20
   : LOAD DC T#1,"HLDA010D"
0550 DEFFN'6
0560 DEFFN'22
   : GOSUB '35("COPY TEXT")
   : LOAD DC T#1,"HLDA010I"
0590 DEFFN'7
0600 DEFFN'23
   : GOSUB '35("PRINT ADDRESSES")
   : LOAD DC T#1,"HLDA010L"
0630 DEFFN'8
0640 DEFFN'24
   : GOSUB '35("PRINT A DOCUMENT")
   : LOAD DC T#1,"HLDA010K"
0670 DEFFN'9
0680 DEFFN'25
   : GOSUB '35("INITIALIZE VOLUME")
   : LOAD DC T#1,"HLDA010B"
0730 DEFFN'15
   : SELECT TAPE 10A
   : SELECT PRINT 005(64)
   : PRINT HEX(03);TAB(20);"* * * 2 2 0 0 * * *"
   : PRINT TAB(13);"***** TEXT EDITING UTILITIES *****"
   : PRINT " PRESS APPROPRIATE FUNCTION KEY TO PERFORM DESIRED FUNCTION"
   : PRINT "-----------------------------------------------------------"
0810 PRINT ,"PROGRAMS IN THIS SYSTEM"
   : PRINT "FN KEY   PROGRAM NAME          FN KEY   PROGRAM NAME"
   : PRINT "-----------------------------------------------------------"
   : PRINT "  '0  MOVE TEXT                  '6  COPY TEXT"
0850 PRINT "  '1  TEXT EDITOR                '7  PRINT ADDRESSES"
   : PRINT "  '2  GLOBAL REPLACE             '8  PRINT A DOCUMENT"
   : PRINT "  '3  DOCUMENT/LETTER ASSEMBLY   '9  INITIALIZE VOLUME"
   : PRINT "  '4  DISK TABLE OF CONTENTS    '15  MENU"
0890 PRINT "  '5  DELETE A DOCUMENT         '31  LOG ON/OFF"
   : RETURN
0910 DEFFN'35(A9$)
   : SELECT PRINT 005(64)
   : PRINT HEX(03)
   : PRINT HEX(0A0A0A0A0A)
   : PRINT "     * * * * * * * * * * * * * * * * * * * * * * * * * *"
   : PRINT "     *";TAB(55);"*"
   : PRINT "     *";TAB(22);"SYSTEM NOW LOADING";TAB(55);"*"
   : PRINT "     *";TAB(12+(38-LEN(A9$))/2);A9$;TAB(55);"*"
   : PRINT "     *";TAB(55);"*"
1000 PRINT "     * * * * * * * * * * * * * * * * * * * * * * * * * *"
   : RETURN
1040 LIMITS T#1,"ACTIVE",U1,U2,U2
   : DATA LOAD BA T#6,(U1,A)N$()
   : INIT(20)N$(VAL(Z$))
   : DATA SAVE BA T#1,(U1,A)N$()
   : RETURN
1110 DEFFN'31
   : PRINT HEX(03);TAB(23);"L O G   O N / O F F"
   : GOSUB '32("DO YOU WANT TO LOG 'ON' OR 'OFF'?",3)
1130 IF Q$="ON"THEN 1300
   : IF Q$="on"THEN 1300
   : IF Q$="OFF"THEN 1170
   : IF Q$="off"THEN 1170
   : GOSUB '34("INVALID REPLY.  ENTER 'ON' OR 'OFF'.")
   : GOTO 1130
1170 LIMITS T#1,"ACTIVE",U1,U2,U2
   : DATA LOAD BA T#6,(U1,A)N$()
   : INIT(00)N$(VAL(Z$))
   : DATA SAVE BA T#1,(U1,A)N$()
   : PRINT " TERMINAL";VAL(Z$);"IS LOGGED OFF.";HEX(0C)
   : INIT(00)Z$
   : RETURN
1300 GOSUB 1170
   : LOAD DC T#1,"START"
8050 DEFFN'32(Q1$,N)
   : GOSUB 8460
8070 PRINT HEX(010A);Q1$
   : INIT(2D)Q$
   : $GIO/005(40204020A000402F400D,I0$)Q$<1,N>
   : Q$=" "
   : D=1
   : PRINT "? ";
8150 KEYIN D$,8160,8150
   : GOTO 8150
8160 IF D$=HEX(0D)THEN 8330
   : IF D$=HEX(08)THEN 8280
   : IF D$=HEX(A1)THEN 8250
   : IF D>NTHEN 8150
   : IF D$=HEX(84)THEN 8350
   : STR(Q$,D,1)=D$
8220 PRINT D$;
   : D=D+1
   : GOTO 8150
8250 PRINT HEX(0D0909);
   : D=1
   : GOTO 8150
8280 IF D=1THEN 8150
   : D=D-1
   : STR(Q$,D,1)=" "
   : PRINT HEX(082008);
   : GOTO 8150
8330 PRINT HEX(0D0A)
   : RETURN
8350 OR (STR(Q$,D,1),80)
   : D$=STR(Q$,D,1)
   : GOTO 8220
8400 DEFFN'34(Q2$)
   : GOSUB 8460
   : PRINT HEX(010A0A0A);Q2$
   : GOTO 8070
8460 PRINT HEX(010A);
   : GOSUB 8490
   : GOSUB 8490
8490 $GIO/005(400DA000400A,I$)B$()<1,W>
   : RETURN