image of READY prompt

Wang2200.org

Listing of file='CASINO' on disk='vmedia/more_games.wvd.zip'

# Sector 248, program filename = 'CASINO'
0010 REM *CASINO*
   : LOAD DC T#6,"GAMES"
0020 REM "DECAY1"
   : PRINT HEX(03);TAB(20);"---THE NEW CLEA CASINO---"
   : GOSUB '248(4,0,0)
   : PRINT "     MR. A. TOM MICK, GENERAL MANAGER OF THE NEW CLEA CASINO,"
0030 DIM Q6$64
   : W0$="N"
0040 PRINT "HAS, AT TIME  T=0,  DISCOVERED  100,000 RADIOACTIVE PLAYING"
0050 PRINT "CHIPS AT HIS TABLE. THEIR HALF-LIFE IS 10 MINUTES. EACH CHIP"
   : PRINT "TRANSMUTES SPONTANEOUSLY AND COMPLETELY IN A RANDOM FASHION."
   : PRINT
   : PRINT "     AT VARIOUS TIMES T, AFTER T=0, YOU MUST DETERMINE WITHIN"
0060 PRINT "A CERTAIN PERCENTAGE, HOW MANY CHIPS ARE LEFT."
   : PRINT
   : PRINT "     TO FURTHER THE INTEREST OF THE GAME, YOU WILL START WITH"
   : PRINT "$1,000 AND THE HOUSE WITH AN UNSPECIFIED AMOUNT.  HALF THE"
0070 PRINT "MONEY YOU HAVE WILL RIDE ON EACH GUESS YOU TAKE.  LET'S SEE"
   : PRINT "IF YOU CAN BREAK THE HOUSE BEFORE THE CHIPS RUN OUT.";
   : GOSUB '243("KEY RETURN (EXEC) TO CONTINUE",1)
   : GOSUB '248(4,0,12)
   : PRINT
   : PRINT "THE HOUSE OFFERS THE FOLLOWING ODDS:"
0080 PRINT "     2) 2 TO 1 ODDS FOR GUESSING WITHIN 20 PERCENT"
   : PRINT "     4) 4 TO 1 ODDS FOR GUESSING WITHIN 10 PERCENT"
   : PRINT "     8) 8 TO 1 ODDS FOR GUESSING WITHIN  5 PERCENT."
0090 GOSUB '245("GIVE ME YOUR LUCKY NUMBER",2,0)
   : FOR I=1TO Q9
   : T3=RND(RND(Q9))
   : NEXT I
0100 IF W0$="N"THEN 110
   : GOSUB '200
   : GOTO 120
0110 GOSUB '248(5,0,6)
0120 PRINT
   : PRINT
   : PRINT "   $$ MONEY $$         TIME   GUESS         NO. OF CHIPS LEFT"
   : PRINT "   YOURS    HOUSE     (MIN)    NO.   ODDS    GUESSED   ACTUAL"
0130 % #######   #######    ###.#    ##
0140 %#      #######  #######
0150 G,D,A,B,T=0
   : Y=1000
0160 C=0
   : IF ABS(G-D)<500THEN 170
   : G=5
   : D=2
0170 B=B+1
   : FOR I=1TO 3+A+ABS(G-D)
   : T3=INT(100*RND(-Y))/10
   : NEXT I
   : T=T+T3
   : D=INT(100000*EXP(-.0693*T))
   : IF D=0THEN 290
   : IF W0$="N"THEN 180
   : GOSUB '200
   : GOTO 190
0180 GOSUB '248(14-(1-(B/5-INT(B/5)))*5,0,2)
0190 PRINTUSING 130,Y,1.001E+6-Y,T,B
0200 GOSUB '245("WHAT ODDS DO YOU WANT (2=20%:4=10%:8=5%)",1,0)
   : A=Q9
   : IF A=2THEN 210
   : IF A=4THEN 210
   : IF A=8THEN 210
   : GOSUB '248(3,0,0)
   : PRINT "SORRY PAL, WE DONT OFFER THOSE ODDS."
   : IF C=1THEN 280
   : C=1
   : GOTO 200
0210 GOSUB '245("HOW MANY CHIPS ARE LEFT",6,0)
   : G=Q9
0220 IF W0$="N"THEN 230
   : GOSUB '200
   : PRINT TAB(38);
   : GOTO 240
0230 GOSUB '248(14-(1-(B/5-INT(B/5)))*5,39,2)
0240 PRINTUSING 140,A,G,D
   : GOSUB '248(3,0,4)
   : T=10*B
   : IF ABS(D-G)<=D/A*.4THEN 250
   : Y=INT(Y-Y/2)
   : IF Y<=50THEN 280
   : PRINT "TOO BAD, YOU LOST. TRY AGAIN."
   : GOTO 160
0250 Y=INT(Y+A*Y/2)
   : IF 1E+6-Y<1THEN 310
   : IF Y>200000THEN 270
0260 PRINT "YOU WON. TRY AGAIN."
   : GOTO 160
0270 PRINT "YOU CAN BREAK THE HOUSE IF YOU TRY A LONG SHOT."
   : GOTO 160
0280 PRINT "IT SEEMS YOU JUST CANT GET THE HANG OF IT. SAVE YOUR BREAD."
   : GOTO 340
0290 PRINT "OOOOPS... SORRY PAL, THE LAST CHIP JUST DISINTEGRATED."
0300 PRINT "THE HOUSE IS CLOSED."
   : GOTO 340
0310 PRINT "YOU BROKE THE HOUSE. YOU NEEDED ONLY ";
   : IF B>5THEN 320
   : PRINT "THE MINIMUM NUMBER OF GUESSES."
   : GOTO 330
0320 PRINT B;"GUESSES."
0330 PRINT "CONGRATULATIONS."
   : PRINT "YOU MUST KNOW A LOT ABOUT RADIOACTIVITY AND THINGS."
0340 GOSUB '243("KEY RETURN (EXEC) TO CONTINUE",0)
   : GOSUB '248(4,0,12)
   : PRINT "    THANKS FOR PLAYING......DONT SPEND IT ALL IN ONE PLACE"
   : PRINT
   : PRINT "     * * * * * * * * * * * * * * * * * * * * * * * * * * *"
   : PRINT "     *";TAB(36);"CHECK NO.";B+D;TAB(57);"*"
0350 PRINT "     *";TAB(36);"DATE: ----------19--";TAB(57);"*"
   : PRINT "     *";TAB(57);"*"
   : PRINT "     *  PAY TO THE ORDER OF     C A S H     $";Y;TAB(57);"*"
   : PRINT "     *";TAB(29);"-------------------------";TAB(57);"*"
   : PRINT "     *  THE NEW CLEA CASINO";TAB(40);"A  TOM MICK      *"
0360 PRINT "     *";TAB(40);"GENERAL MANAGER  *"
   : PRINT "     * * * * * * * * * * * * * * * * * * * * * * * * * * *"
0370 GOSUB '243("WOULD YOU LIKE TO PLAY THE GAME AGAIN (Y/N)",1)
   : PRINT HEX(03);TAB(20);"---THE NEW CLEA CASINO---"
   : IF Q6$="Y"THEN 90
   : IF Q6$<>"N"THEN 370
0380 STOP
0390 Q6=3
   : GOTO 570
0400 DEFFN'242(W0,Q6$)
   : IF W0<=0THEN 600
   : IF W0=1THEN 410
   : STR(Q6$,2)=STR(Q6$,1,W0-1)
0410 PRINT Q6$;
   : RETURN
0420 DEFFN'243(Q6$,Q0)
   : GOSUB 520
0430 SELECT CO 205
   : Q6$=" "
   : INPUT Q6$
   : IF Q0=0THEN 550
   : IF LEN(Q6$)<=Q0THEN 550
   : GOSUB 510
0440 DEFFN'244(Q0)
   : GOSUB 540
   : GOSUB 530
   : GOTO 430
0450 DEFFN'245(Q6$,Q2,Q3)
   : Q0=ABS(Q2)+Q3+1
0460 GOSUB 520
0470 GOSUB '242(ABS(Q2)+2,HEX(09))
   : PRINT "/"
   : GOSUB 540
   : SELECT CO 205
   : Q9,W0=-1E-99
   : INPUT Q9
   : IF W0=Q9THEN 480
   : IF Q9>=0THEN 500
   : IF Q2<=0THEN 500
0480 GOSUB 510
0490 DEFFN'246(Q2,Q3)
   : Q0=ABS(Q2)+Q3+1
   : GOSUB 540
   : GOSUB 530
   : GOTO 470
0500 IF ABS(Q9)>=10^ABS(Q2)THEN 480
   : W0=ABS(Q9*10^Q3)
   : IF INT(W0)<>W0THEN 480
   : GOTO 390
0510 GOSUB 390
   : PRINT "RE-ENTER"
   : RETURN
0520 GOSUB 600
   : PRINT HEX(010A);STR(Q6$,1);
0530 GOSUB 600
   : GOSUB '242(Q0+2,"-")
   : PRINT TAB(64)
0540 PRINT HEX(010A0A)
   : RETURN
0550 PRINT HEX(0A);TAB(64)
   : GOTO 600
0560 Q6=0
0570 Q7=0
   : Q8=1
0580 DEFFN'248(Q6,Q7,Q8)
   : GOSUB 600
   : IF Q8<1THEN 590
   : GOSUB 590
   : SELECT PRINT 205
   : Q6$=" "
   : PRINT STR(Q6$,Q7+1)
   : IF Q8<2THEN 590
   : FOR W0=2TO Q8
   : PRINT HEX(0A);STR(Q6$,1)
   : NEXT W0
0590 PRINT HEX(01)
   : GOSUB '242(Q7,HEX(09))
   : GOSUB '242(Q6,HEX(0A))
0600 SELECT PRINT 005(64),CO 005
   : RETURN
0610 DEFFN'31
   : W0$="N"
   : RETURN
0620 DEFFN'15
   : W0$="Y"
   : RETURN
0630 DEFFN'200
0640 SELECT PRINT 015(80)
   : IF W9$="T"THEN 650
   : SELECT PRINT 211(80)
   : IF W9$="P"THEN 650
   : SELECT PRINT 215(80)
0650 RETURN