image of READY prompt

Wang2200.org

Listing of file='CRYPTO' on disk='vmedia/more_games.wvd.zip'

# Sector 492, program filename = 'CRYPTO'
0010 REM T.OLSEN  WANG LABS 2200 R&D
0015 LOAD DC T#6,"GAMES"
0020 F9$="CRYPTOGRAM GAME"
0030 DIM Y$64,A$64,B$64,C$64,D$26,E$26,F$26,Z$1,Z1$1
0040 A9$="SOURCE TEXT"
   : B9$="ENCRYPTED TEXT"
   : C9$="YOUR SOLUTION"
0050 PRINT HEX(03)
0060 %TRIES MADE=####  CORRECT=##  CLUES=##
0070 D$="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
0080 GOSUB 90
   : STOP "KEY IN APPROPRIATE FUNCTION"
0090 PRINT HEX(010A0A0A0A0A0A0A0A)
0100 PRINT F9$;" FUNCTION KEYS ARE INPUT COMMANDS"
0110 PRINT "LETTERS CORRECT=";STR(F$,1,26)
0120 PRINT "KEY 0  TRY A NEW VALUE"
0130 PRINT "KEY 1  GET A CLUE"
0140 PRINT "KEY 2-14 AND 17-31 CANNED PHRASES"
0150 PRINT "KEY 15 ENTER A NEW PHRASE"
0160 PRINT "KEY 16 IF YOU CAN TYPE IN THE WHOLE PHRASE"
0170 RETURN
0180 DEFFN'15
   : PRINT HEX(03),F9$
0190 PRINT "TYPE A PHRASE ON ONE LINE WHICH WILL BE ENCRYPTED"
0200 A$=" "
   : INPUT A$
0210 A1=LEN(A$)
   : B$,C$=" "
0220 PRINT HEX(03);"RANDOMIZING"
0230 FOR C=1 TO A1
   : T=RND(1)
   : NEXT C
0240 C,T,T1=0
   : F$=" "
0250 PRINT "BUSY ENCRYPTING"
0260 GOSUB 640
   : REM ENCRYPT ALPHABET
0270 GOSUB 700
   : REM ENCRYPT PHRASE
0280 PRINT HEX(03);
   : GOSUB 90
0290 DEFFN'0
   : GOSUB 90
   : PRINT HEX(01);"ENCRYPTED PHRASE="
   : PRINT B$
   : PRINT C$
0300 Z$=" "
   : INPUT "CHARACTER=",Z$
0310 IF Z$=" "THEN 290
0320 X=1
0330 IF Z$=STR(D$,X,1)THEN 350
0340 X=X+1
   : IF X<27THEN 330
   : GOTO 290
0350 Z1$=" "
   : PRINT HEX(010A0A0A0A);
   : INPUT "CODED AS=",Z1$
0360 IF Z1$=" "THEN 350
0370 T=T+1
   : PRINT "TRY NUMBER ";T
0380 IF Z1$=STR(E$,X,1)THEN 410
0390 PRINT "YOU MISSED, TRY AGAIN"
0400 GOTO 490
0410 PRINT "CORRECT                       "
0420 T1=T1+1
0430 FOR W=1 TO A1
0440  IF Z1$<>STR(B$,W,1)THEN 460
0450  STR(C$,W,1)=Z$
0460 NEXT W
0470 W=0
0480 W=W+1
   : IF STR(D$,W,1)<>Z$THEN 480
   : STR(F$,W,1)=Z$
0490 IF A$<>C$THEN 290
0500 PRINT HEX(01);"COMPLETED PHRASE="
   : PRINT C$
0510 PRINT "YOU FINISHED";TAB(63)
0520 PRINT TAB(63)
   : PRINT TAB(63)
   : PRINT TAB(63)
   : PRINT HEX(0C0C0C)
0530 PRINTUSING 60,T,T1,C
0540 STOP
0550 DEFFN'1
   : C=C+1
0560 Y=INT(A1*RND(1))+1
0570 IF STR(C$,Y,1)<>" "THEN 560
0580 IF STR(A$,Y,1)=" "THEN 560
0590 Z$=STR(A$,Y,1)
   : Z1$=STR(B$,Y,1)
0600 PRINT HEX(010A0A0A);"CHARACTER=";TAB(63)
0610 PRINT "CLUE NO.=";C;TAB(63)
0620 PRINT "CHAR ";Z$;"=";Z1$;TAB(63)
0630 PRINT TAB(63)
   : GOTO 430
0640 E$=" "
   : REM ENCRYPT ALPHABET
0650 FOR X=1 TO 26
0660 Y=INT(26*RND(1))+1
0670 IF STR(E$,Y,1)<>" " THEN 660
0680 STR(E$,Y,1)=STR(D$,X,1)
0690 NEXT X
   : RETURN
0700 B$=" "
   : REM ENCRYPT PHRASE
0710 FOR W=1 TO A1
0720 Z$=STR(A$,W,1)
0730  FOR X=1 TO 26
0740   IF Z$=STR(D$,X,1) THEN 760
0750  NEXT X
   : STR(B$,W,1)=Z$
   : STR(C$,W,1)=Z$
   : GOTO 780
0760  REM CHARACTER TO BE ENCRYPTED IS ALPHABETIC
0770 STR(B$,W,1)=STR(E$,X,1)
   : X=26
   : NEXT X
0780 NEXT W
   : RETURN
0790 DEFFN'16
   : PRINT "TYPE THE ENTIRE PHRASE EMBEDDED IN DOUBLE QUOTES."
0800 INPUT Y$
   : T=T+1
   : IF A$<>Y$THEN 390
0810 T1=T1+1
   : GOTO 510
0820 DEFFN'2
0830 A$="THE QUICK BROWN FOX JUMPED OVER THE LAZY DOG'S BACK."
0840 GOTO 210
0850 DEFFN'3
0860 A$="THE WANG 2200-A IS ABLE TO PLAY CRYPTO GAMES."
0870 GOTO 210
0880 DEFFN'4
0890 A$="WE CAN ALSO DO PAYROLLS, INVENTORY, TEACHING AIDS, PLUS"
0900 GOTO 210
0910 DEFFN'5
0920 A$="USE AN ACE AXE TO RUN KIDS OFF OF YOUR BIKE PATH."
0930 GOTO 210
0940 DEFFN'6
0950 A$="NOBODY SHOOTS AT SANTA CLAUS. ALFRED E. SMITH"
0960 GOTO 210
0970 DEFFN'7
0980 A$="NO MATTER HOW THIN YOU SLICE IT, IT'S STILL BOLONEY."
0990 GOTO 210
1000 DEFFN'8
1010 A$="THOUGH IT BE HONEST, IT IS NEVER GOOD TO BRING BAD NEWS."
1020 GOTO 210
1030 DEFFN'9
1040 A$="GOOD WINE IS A GOOD FAMILIAR CREATURE IF IT BE WELL USED."
1050 GOTO 210
1060 DEFFN'10
1070 A$="FAULTILY FAULTLESS, ICILY REGULAR, SPLENDIDLY NULL. MAUD."
1080 GOTO 210
1090 DEFFN'11
1100 A$="POETS ARE THE HIEROPHANTS OF AN UNAPPREHENDED INSPIRATION."
1110 GOTO 210
1120 DEFFN'12
1130 A$="IS THERE SUCH A WORD AS ANTIDISESTABLISHMENTARIANISM?"
1140 GOTO 210
1150 DEFFN'13
1160 A$="THE LETTERS OF THE ALPHABET ARE 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"
1170 GOTO 210
1180 DEFFN'14
1190 STOP "NO PHRASE STORED FOR THIS FUNCTION KEY."
1200 GOTO 210
1210 DEFFN'17
1220 A$="LOUD LAMB BAAS SEND ECHO OVER THIS FIVE ACRE FARM UNIT."
1230 GOTO 210
1240 DEFFN'18
1250 A$="ABLE WAS I ERE I SAW ELBA.  NAPOLEON BONAPARTE"
1260 GOTO 210
1270 DEFFN'19
1280 A$="SATOR, AREPO, TENET, OPERA, ROTAS.  MAGIC SQUARE"
1290 GOTO 210
1300 DEFFN'20
1310 A$="ALASKAN USED IVORY OF WALRUS TUSK FOR NEW CARVED CURIOSITY."
1320 GOTO 210
1330 DEFFN'21
1340 A$="REALIZE THE IDEAL; IDEALIZE THE REAL."
1350 GOTO 210
1360 DEFFN'22
1370 A$="CORPULENT DERELICT COURTED OPULENT RELICT."
1380 GOTO 210
1390 DEFFN'23
1400 A$="RUMBA, SAMBA BOTH RIGHT MAD, BUT I DIG MOST THAT MAMBO."
1410 GOTO 210
1420 DEFFN'24
1430 A$="HIS FROZEN ASSETS CONSISTED OF FREEZER KEPT STACKS OF STEAKS."
1440 GOTO 210
1450 DEFFN'25
1460 A$="WE SHIRK IRKSOME HOMEWORK."
1470 GOTO 210
1480 DEFFN'26
1490 A$="CRISP CRYPTS STYMIE ME."
1500 GOTO 210
1510 DEFFN'27
1520 A$="BAGGY CLOTHES DECREED BY THE HAUTE COUTURE ARE GHASTLY."
1530 GOTO 210
1540 DEFFN'28
1550 A$="MEDIUM ABJURED OUIJA BOARD"
1560 GOTO 210
1570 DEFFN'29
1580 A$="OUR HEP JAVA FINCHES JUMP FIVE INCHES FROM PERCH."
1590 GOTO 210
1600 DEFFN'30
1610 A$="HORSESHOER QUIT QUOITS."
1620 GOTO 210
1630 DEFFN'31
1640 A$="QUAKING SKIN DIVER AVOIDS TAKING GROTESQUE SQUID."
1650 GOTO 210