Listing of file='HAMURABI' on disk='vmedia/more_games.wvd.zip'
# Sector 621, program filename = 'HAMURABI'
0010 REM *HAMURABI*
: LOAD DC T#6,"GAMES"
0020 REM ** HAMURABI - GOVERN THE KINGDOM OF SUMERIA ** (ADAPTED FOR THE WANG
2200 BY JOEL EHRLICH
: PRINT HEX(03);"HAMURABI - ";
: PRINT "WHERE YOU GOVERN THE ANCIENT KINGDOM OF SUMERIA."
0030 REM %VARIABLES LIST
0040 REM A1=Population, A2=Last Year's Immigrants, A3=Last Year's Deaths, B1=B
ushels in Warehouses, B2=Bushels Destroyed by Rats Last Year, B3=Last Yea
r's Harvest (Per Acre)
0050 REM B4=Total Harvest Last Year, C1=City Owned Acreage, C2=Value Per Acre,
I&J=Working Storage (Temporary)
0060 PRINT "THE OBJECT IS TO FIGURE OUT HOW THE GAME WORKS!!"
0070 PRINT "(IF YOU WANT TO QUIT, SELL ALL YOUR LAND.)"
: FOR X=1TO 2E3
: NEXT X
: A1=100
: A2=5
: A3=0
: B1=2800
: B2=200
: B3=3
: B4=3000
: C1=1000
: J=1
0080 REM %REPORT TO HAMURABI
0090 PRINT HEX(03);"HAMURABI, I BEG TO REPORT THAT LAST YEAR";
: PRINT A3;"PEOPLE STARVED AND";A2;"PEOPLE CAME TO THE CITY.";
: IF J>0THEN 110
0100 A1=A1-INT(A1/2)
: PRINT "THE PLAGUE KILLED HALF THE PEOPLE.";
0110 PRINT "THE POPULATION IS NOW";A1
: PRINT "WE HARVESTED";B4;"BUSHELS AT";B3;"BUSHELS PER ACRE.";
: PRINT "RATS DESTROYED";B2;"BUSHELS LEAVING";B1;
: PRINT "BUSHELS IN THE STOREHOUSES.";
0120 PRINT "THE CITY OWNS";C1;"ACRES OF LAND."
: C2=17+INT(6*RND(1))
: PRINT "LAND IS WORTH";C2;"BUSHELS PER ACRE.";
: PRINT " HAMURABI . . ."
: %PURCHASE LAND?
0130 INPUT "BUY HOW MANY ACRES OF LAND SHALL WE BUY",I
: I=INT(ABS(I))
: IF I=0THEN 150
: J=I*C2
: IF J<=B1THEN 140
: GOSUB 250
: GOTO 130
0140 B1=B1-J
: C1=C1+I
: %SELL LAND?
0150 INPUT "HOW MANY ACRES OF LAND SHALL WE SELL",I
: I=INT(ABS(I))
: IF I=0THEN 170
: IF I<C1THEN 160
: IF I=C1THEN 260
: GOSUB 250
: GOTO 150
0160 C1=C1-I
: B1=B1+C2*I
: %DISTRIBUTE FOOD?
0170 INPUT "HOW MANY BUSHELS SHALL WE DISTRIBUTE AS FOOD",I
: I=INT(ABS(I))
: IF I<=B1THEN 180
: GOSUB 250
: GOTO 170
0180 B1=B1-I
: A3=A1-INT(I/20)
: A2=0
0190 IF A3>=0THEN 200
: A2=-A3/2
: A3=0
: %PLANT?
0200 INPUT "HOW MANY ACRES OF LAND SHALL WE PLANT",I
: I=INT(ABS(I))
: IF I>C1THEN 210
: J=INT(I/2)
: IF J<=B1THEN 220
0210 GOSUB 250
: GOTO 200
: %HARVEST-RATS_POPULATION
0220 IF I>10*A1THEN 210
: B1=B1-J
: B3=INT(5*RND(1))+1
: B4=B3*I
: B2=INT((B1+B4)*.07*RND(1))
: B1=B1-B2+B4
: J=INT(10*RND(1))
0230 A2=INT(A2+(5-B3)*B1/600+1)
: IF A2<=50THEN 240
: A2=50
0240 A1=A1+A2-A3
: GOTO 90
: %ERROR ROUTINE
0250 PRINT HEX(0307);"HAMURABI, THINK AGAIN - YOU ONLY HAVE";
: PRINT A1;"PEOPLE,";C1;"ACRES, AND";
: PRINT B1;"BUSHELS IN STOREHOUSES."
: RETURN
0260 END