image of READY prompt

Wang2200.org

Listing of file='HANGMAN' on disk='vmedia/more_games.wvd.zip'

# Sector 634, program filename = 'HANGMAN'
0010 REM *HANGMAN*
   : LOAD DC T#6,"GAMES"
0020 DIM A$(15)18,B$(13)18,C$(7)18,D$(2)18,W$18,K$1,W1$18,X$1
   : N9=0
0030 REM %INITIALIZE STORAGE VARIABLES
0040 INIT(20)A$(),B$(),C$(),D$(),W$,W1$,K$
0050 REM %GALLOWS & FIGURE
0060 A$(1)=HEX(2020202D2D2D2D2D2D2D2D2D2D2D2D2D2D49)
   : A$(2),A$(3),A$(6)=HEX(2020202E2020202020202020202020202049)
   : A$(4),A$(5)=HEX(20202E202E20202020202020202020202049)
0070 A$(7),A$(8),A$(9),A$(10),A$(11),A$(12),A$(13),A$(14)=HEX(2020202020202020
     20202020202020202049)
   : A$(15)=HEX(202020202020202020492049204920492049)
0080 B$(1),B$(4)=HEX(20202020204F202020202020202020202049)
   : B$(2),B$(3)=HEX(2020204F2020204F20202020202020202049)
   : B$(5),B$(6),B$(7),B$(8)=HEX(202020202058202020202020202020202049)
0090 B$(9)=HEX(202020202320202020202020202020202049)
   : B$(10)=HEX(202020232020202020202020202020202049)
   : B$(11),B$(12)=HEX(202023202020202020202020202020202049)
0100 B$(13)=HEX(232323202020202020202020202020202049)
   : C$(1)=HEX(202320202058202020202020202020202049)
   : C$(2)=HEX(202323232358202020202020202020202049)
   : C$(3),C$(4)=B$(5)
0110 C$(5)=HEX(202020202320232020202323232020202049)
   : C$(6)=HEX(202020232020202320232020202020202049)
   : C$(7)=HEX(202023202020202023202020202020202049)
0120 D$(1)=HEX(202323232358232323232020202020202049)
   : D$(2)=HEX(202020202058202020232020202020202049)
0130 REM %WORD LIST
0140 DATA "MAIZE","OFFICE","SHOOT","WHITE","CENTIGRADE","DINOSAUR","ECOLOGY","
     FUROR","UNDERMINE","CHURCH","POPULATION","NOTORIOUS","SAPPHIRE","SOMNOLEN
     T","TALLOW","CALLOW","FAMINE","UNREST"
0150 DATA "LATEEN","TOOTH","UPSET","HORSEPOWER","EXTRA","COMPUTER","ABORT","SC
     HOLASTIC","HONOR","FIRST","CALCULATION","HACK","ESSAY","RURAL","SECONDARY
     ","BROCHURE","CHAIN","BEACON","BARBEQUE"
0160 DATA "REINDEER","SUNSTROKE","TRIFLE","MARIJUANA","UNDERGROUND","SKELETON"
     ,"VERMIN","MOMENT","RHINOCEROS","SUCCESS","TRAIN","PESSIMIST","ISOLATE","
     FAMOUS","GURU","OBJECTIVE","SLAUGHTER"
0170 DATA "SUMMARY","KNAVE","OBSCENE","UNKNOWN","IDIOT","SENSE","ISSUE","LEVER
     ","HORSESHOE","PUTRID","ELUDE","RENAISSANCE","SMITE","SANDWICH","VIGOR","
     SENTIMENTAL","RALLY","KEEL","MOTTO"
0180 DATA "MIMEOGRAPH","MILLION","PUPIL","REPEAT","QUOTE","SOUSAPHONE","TEMPO"
     ,"JUDICIOUS","SNORT","GRUESOME","SENATOR","JUSTICE","DREAM","IRONY","RAVI
     OLI","NURSE","THING","TABERNACLE"
0190 DATA "TEMPERMENT","GRILL","HOBBY","PEPPER","PERSONNEL","PERSONIFY","HOSPI
     TAL","COMPLETED","SUBJECTIVITY"
0200 REM %LIST & ENTER OPTION
0210 PRINT HEX(03);"HANGMAN ---";
   : FOR X=1TO 250
   : NEXT X
   : PRINT "A WORD GAME."
   : FOR X=1TO 1000
   : NEXT X
0220 PRINT "THERE ARE TWO WAYS TO PLAY: 1- YOU AGAINST THE 2200 (IT PICKS THE
     WORD, YOU TRY TO GUESS IT); 2- YOU AGAINST SOMEONE ELSE (YOU TAKE TURNS T
     YPING IN AND GUESSING THE WORD)."
   : PRINT
0230 PRINT "WHICH WOULD YOU LIKE TO PLAY (1 OR 2)?"
0240 KEYIN K$,250,40
   : U=RND(1)
   : GOTO 240
0250 PRINT HEX(03);"PRESS 'EXECUTE' TO START GAME."
   : INPUT X$
0260 IF K$>"2"THEN 230
   : IF K$<"1"THEN 230
   : CONVERT K$TO O
   : ON OGOTO 280,530
0270 REM %SELECT WORD
0280 A=INT(RND(1)*10)
   : IF A<1THEN 280
   : IF A>10THEN 280
   : FOR X=1TO INT(U*10)
   : Q=RND(1)
   : NEXT X
0290 B=INT(RND(1)*10)
   : IF B<1THEN 290
   : IF B>10THEN 290
   : C=(A*B)+INT(Q*10)
   : IF C<1THEN 280
   : IF C>100THEN 280
0300 FOR W=1TO C
   : READ W$
   : N9=N9+1
   : IF N9>99THEN 310
   : NEXT W
   : W=LEN(W$)
   : FOR X=1TO W
   : STR(W1$,X,1)=HEX(2D)
   : NEXT X
   : B=0
   : GOTO 330
0310 N9=0
   : RESTORE
   : NEXT W
0320 REM %DISPLAY & ENTRY
0330 PRINT HEX(030A)
   : FOR X=1TO 15
   : PRINT TAB(44);A$(X)
   : NEXT X
   : K$=HEX(20)
   : PRINT HEX(01);W1$;HEX(0D0A0A);
   : INPUT "WHICH LETTER WOULD YOU LIKE TO TRY",K$
0340 IF K$=HEX(20)THEN 330
   : GOSUB 360
   : GOTO 420
0350 REM %TEST FOR LETTER
0360 FOR X=1TO W
   : IF K$=STR(W$,X,1)THEN 380
   : NEXT X
0370 PRINT "SORRY---THAT'S NOT USED IN YOUR WORD!"
   : B=B+1
   : FOR X=1TO 1500
   : NEXT X
   : RETURN
0380 FOR Y=1TO W
   : IF K$=STR(W$,Y,1)THEN 390
   : NEXT Y
   : GOTO 400
0390 STR(W1$,Y,1)=STR(W$,Y,1)
   : NEXT Y
0400 PRINT HEX(03);"GOOD GUESS!"
   : PRINT W1$
   : FOR Z=1TO 1500
   : NEXT Z
   : RETURN
0410 REM %TEST FOR FINISHED
0420 P=POS(W1$=2D)
   : IF P=0THEN 570
0430 REM %BRANCH FOR FIGURE ELEMENT
0440 IF B=0THEN 330
   : ON BGOTO 450,460,470,480,490,500
   : GOTO 500
0450 FOR X=1TO 4
   : A$(X+1)=B$(X)
   : NEXT X
   : A$(X+2)=A$(X+3)
   : GOTO 330
0460 FOR X=1TO 8
   : A$(X+1)=B$(X)
   : NEXT X
   : GOTO 330
0470 FOR X=1TO 13
   : A$(X+1)=B$(X)
   : NEXT X
   : GOTO 330
0480 FOR X=1TO 2
   : A$(X+5)=C$(X)
   : NEXT X
   : GOTO 330
0490 FOR X=1TO 7
   : A$(X+5)=C$(X)
   : NEXT X
   : GOTO 330
0500 FOR X=1TO 2
   : A$(X+6)=D$(X)
   : NEXT X
   : PRINT HEX(03);"YOU LOSE!"
   : FOR X=1TO 5000
   : NEXT X
   : PRINT HEX(03);W$;TAB(44);A$(1)
0510 FOR X=2TO 15
   : PRINT TAB(44);A$(X)
   : NEXT X
   : PRINT HEX(010A0A0A0A);TAB(15);"BETTER LUCK NEXT TIME!"
   : PRINT
   : PRINT TAB(20);W$;HEX(01)
   : FOR X=1TO 9500
   : NEXT X
   : GOTO 40
0520 REM %ENTER WORD
0530 PRINT HEX(03);"ENTER A WORD OF UP TO 18 LETTERS FOR YOUR OPPONENT TO TRY
     TO    GUESS."
0540 INPUT "WHAT WORD WOULD YOU LIKE",W$
0550 B=0
   : W=LEN(W$)
   : FOR X=1TO W
   : STR(W1$,X,1)=HEX(2D)
   : NEXT X
   : GOTO 330
0560 REM %WIN DISPLAY
0570 PRINT HEX(030A0A0A);TAB(25);"YOU WIN!"
   : PRINT
   : PRINT W$
   : FOR X=1TO 5000
   : NEXT X
   : GOTO 40