image of READY prompt

Wang2200.org

Listing of file='HORSE' on disk='vmedia/more_games.wvd.zip'

# Sector 676, program filename = 'HORSE'
0010 REM *HORSE*
   : LOAD DC T#6,"GAMES"
0020 PRINT HEX(03)
0030 DIM W(5),D(5)
   : Z=5
0040 R=300
   : Q=0
0050 FOR I=1TO Z
   : W(I)=1
   : NEXT I
0060 FOR I=1TO 10+Z
   : PRINT
   : NEXT I
   : GOSUB 630
0070 PRINT "LADIES AND GENTLEMEN -- PLACE YOUR BETS"
0080 INPUT "YOUR BET IS:",Z1
0090 INPUT "YOUR HORSE IS #:",Z2
0100 FOR I=1TO 10+Z
   : PRINT
   : NEXT I
   : GOSUB 630
0110 PRINT HEX(0C);
0120 FOR I=1 TO Z
   : D(I)=0
   : NEXT I
   : N=0
   : J=Z
0130 FOR I=1 TO J
0140 PRINT HEX(0C);
0150 NEXT I
0160 PRINT HEX(0C0C06);
0170 PRINT "AND THEY'RE OFF.....";
0180 PRINT "TIME =";N
   : GOSUB 630
0190 A=RND(1)
   : I=1/Z
0200 FOR J=1 TO Z
0210 IF A>I THEN 220
   : K=J
   : J=Z
0220 I=I+1/Z
   : NEXT J
0230 J=K
0240 D(J)=D(J)+1
0250 N=N+1
0260 IF J=1 THEN 280
0270 FOR I=1 TO J-1
   : PRINT
   : NEXT I
0280 PRINT TAB((D(J))-3);"/)*)'"
0290 IF D(J)=60 THEN 310
0300 GOTO 130
0310 W(J)=W(J)+1
0320 PRINT HEX(0A0A0A0A0A0A0A);
0330 PRINT "THE WINNER IS HORSE #";J;
0340 L=60
0350 FOR I=1 TO Z
0360 D(I)=60-D(I)
0370 IF D(I)<>0 THEN 380
   : D(I)=60
0380 IF L<D(I)THEN 390
   : L=D(I)/5
0390 NEXT I
0400 PRINT " BY ";L;" LENGTHS"
0410 PRINT "TIME FOR RACE = ";N
0420 IF N<R THEN 430
   : GOTO 440
0430 R=N
   : Q=J
   : PRINT "IT'S A NEW TRACK RECORD....."
0440 PRINT "WANG 2200 RACING RESULTS"
   : PRINT
0450 PRINT "HORSE #","WINS","ODDS"
   : PRINT
0460 T=0
0470 FOR I=1TO Z
   : T=T+W(I)
   : NEXT I
0480 FOR I=1 TO Z
0490 PRINT I,W(I),INT(100*T/W(I))/100;"TO 1"
   : NEXT I
0500 PRINT
   : PRINT "TRACK RECORD = ";R;" HELD BY HORSE #";Q
0510 IF J=Z2 THEN 530
0520 IF J<>Z2 THEN 570
0530 Z3=Z3+Z1*INT(100*T/W(I))/100
0540 PRINT "CONGRATULATIONS, YOU WON:";Z1*INT(100*T/W(I))/100;"DOLLARS THAT RA
     CE!"
0550 PRINT "YOUR TOTAL WINNINGS ARE:";Z3;"DOLLARS"
0560 GOTO 600
0570 Z3=Z3-Z1
0580 PRINT "YOU HAD A BUM FOR A HANDICAPPER"
0590 PRINT "YOUR TOTAL WINNINGS ARE NOW:";Z3;"DOLLARS"
0600 FOR I=1TO 230
0610 X=2^8
   : NEXT I
0620 GOTO 70
0630 PRINT "-------------1/4------------1/2------------3/4--------------1"
   : RETURN