image of READY prompt

Wang2200.org

Listing of file='@DOSTYPE' on disk='vmedia/mvp-boot-3.5.wvd.zip'

# Sector 203, program filename = '@DOSTYPE'
0010 REM %^  @DOSTYPE Written by  Kirit Baxi E.A.M.E. R&D
0020 REM % Ver 1.0 20 JUN 1991
0030 REM *******************************************************
0040 REM *                                                     *
0050 REM *                   Type Command                      *
0060 REM *                                                     *
0070 REM *******************************************************
0080 REM % CLEAR SCREEN AND SET CURSOR FLASH ON
0100 DIM A$(32),A1$(16),B$(16)32,D$(16),B$3,C$2,D$4,F$11,H$8,K$1
   : A1$()=T$()
   : PRINT HEX(0202020E)
0110 REM % READJUST TRANSLATE TABLE FOR LOWER CASE
0120 A1$(7)=HEX(896162636465666768696A6B6C6D6E6F)
0130 A1$(8)=HEX(707172737475767778797A988699209B)
0140 REM % CHECK FOR NO FILE EXT NAME!
0150 C$=ALL(00)
   : MAT SEARCHI$,="."TO C$
   : IF LEN(I$)<=8AND VAL(C$,2)=0THEN STR(I$,9,4)=".   "
0160 PRINT HEX(02050F);
0170 REM % TEST FOR DRIVE READY
   : DATA LOAD BA T#N,(0)D$()
   : ERRORE=ERR
   : IF E=98THEN DO
   : PRINT HEX(070E);"Please insert Diskette in Drive"
   : END DO
   : IF E=98THEN 370
0180 REM % TEST FOR BLANK FILENAME
0190 IF LEN(I$)=1THEN PRINT HEX(0E);"   ^ Unknown Command"
   : IF LEN(I$)=1THEN 370
   : I=0
0200 REM % CALCULATE BYTES FOR THE FILE TO TYPE
0210 C$=ALL(00)
   : F$=ALL(20)
   : MAT SEARCHI$,="."TO C$
   : C=VAL(C$,2)
   : STR(F$,1,8)=STR(I$,1,C-1)
   : STR(F$,9,3)=STR(I$,C+1,3)
   : REM $TRAN(F$,HEX(20 00))R $TRAN(I$,HEX(20 00))R
0220 GOSUB 8900
0230 REM % Open the file f$
0240 DATA LOAD ACOPEN T#N,I$
   : ERRORGOTO 380
0250 REM % Read file and display the data
0260 REM % Select CRT for No Auto LF
   : SELECT PRINT 205
0270 LIMITS T#N,A,B,C
   : IF B=CTHEN 370
   : A$()=ALL(20)
   : DATA LOAD AC#N,A$()
0280 $TRAN(A$(),A1$())
0290 REM PRINT HEX(0A)
0300 FOR X=1TO 512
   : IF A9=0THEN 360
0310 IF STR(A$(),X,1)>HEX(07)THEN PRINT STR(A$(),X,1);
   : IF STR(A$(),X,1)=HEX(0D)THEN DO
   : I=I+1
   : IF I=22THEN PRINT HEX(0D0A0E);"-- More --  ";
   : IF I=22THEN KEYIN K$
   : P9=POS(HEX(7E7FF0)=K$)
   : IF P9>0THEN 370
   : IF I=22THEN PRINT HEX(0F0D0A);
   : IF I=22THEN I=0
   : END DO
0320 I1=I1+1
   : IF I1=(A9-1)THEN 370
   : NEXT X
0330 REM PRINT HEX(0D 0A)
   : GOTO 270
0340 STOP
0350 GOTO 270
0360 REM % EXIT EOF OR 0 BYTES
   : SELECT PRINT 005
   : PRINT
   : PRINT HEX(0E);"End of File..."
   : PRINT HEX(0E);"Strike any key to continue...";HEX(02050F);
   : KEYIN K$
0370 REM % RET > CMD PROC
   : PRINT
   : I4$="R"
   : SELECT PRINT 005
   : PRINT HEX(0F0A)
   : LOAD T"@DOS"
0380 REM % EXIT IF FILE NOT FOUND
   : PRINT HEX(0E);"Bad command or File not found"
   : I4$="R"
   : PRINT HEX(0F0A)
   : LOAD T"@DOS"
8890 REM % CALCULATE OFFSET VALUES
8900 DATA LOAD BMT#N,(1440,L)A$()
   : ERRORE=ERR
   : IF E=98THEN Y=10
   : V=13
   : GOTO 8920
8910 DATA LOAD BMT#N,(4800,L)A$()
   : ERRORE=ERR
   : IF E=98THEN Y=30
   : V=27
   : GOTO 8920
8920 A1,B,C,D,D2=0
   : IF Y=0THEN DO
   : Y=10
   : V=13
   : END DO
8930 REM % GET THE DIRECTORY INFORMATION AND CALCUTATE AND DISPLAY THE DATA
8940 FOR Z=YTO Y+VSTEP 2
8950 DATA LOAD BMT#N,(Z,L)B$()
   : ERRORE=ERR
   : IF E=98THEN 9010
8960 FOR X=1TO 16
   : IF STR(B$(X),1,11)=STR(F$,1,11)THEN 8970
   : ELSE GOTO 8980
8970 REM % CALCULATE BYTES USED
   : D$=ALL(00)
   : STR(D$,3,1)=STR(B$(X),30,1)
   : STR(D$,4,1)=STR(B$(X),29,1)
   : STR(D$,1,1)=STR(B$(X),32,1)
   : STR(D$,2,1)=STR(B$(X),31,1)
   : A9=VAL(D$,4)
   : GOTO 9000
8980 NEXT X
8990 NEXT Z
9000 RETURN
9010 RETURN CLEAR
   : GOTO 380