image of READY prompt

Wang2200.org

Listing of file='2229STRT' on disk='vmedia/mvp-diag-2.6.2.wvd.zip'

# Sector 1398, program filename = '2229STRT'
0010 REM % "2229STRT" -  2229 Utilities package - first file
0020 REM ST 01/21/1983
0030 SELECT PRINT 005(80),CO 005(80),LIST 005(80)
   : RETURN CLEAR ALL
0040 COM D5$3,O$3,F$8
0050 REM TITLES AND DISPLAYS
   : DIM T$30,O1$30
0060 REM uCODE FILE AND GIO REGISTERS
   : DIM X$2,X1$3,X$(4)60,R$16,S$30
0070 T$="2229 UTILITIES"
   : PRINT HEX(03);AT(0,40-(LEN(T$)/2));HEX(020402040E);T$;HEX(0F)
0080 A=0
   : IF D5$=" "THEN D5$="D10"
   : PRINT AT(3,0);
   : LINPUT "2229 Utilities address  ",-D5$
   : SELECT #1<D5$>
   : ERRORA=1
   : GOTO 100
0090 PRINT HEX(06)
   : VERIFY T#1,(0,0)A
   : ERRORA=1
0100 IF A=0THEN 110
   : PRINT AT(3,30,30);"Error ";ERR;HEX(07);
   : GOTO 80
0110 PRINT AT(3,30,50);
   : LIMITS T#1,"2229STRT",A,A,A,A
   : IF A=1THEN 120
   : PRINT AT(3,30);"File 2229STRT not resident";HEX(07);
   : GOTO 80
0120 PRINT AT(4,0);
   : IF O$=" "THEN O$="018"
   : A=0
   : LINPUT "Tape controller address ",-O$
   : SELECT #4<O$>
   : ERRORPRINT AT(4,30);"Error ";ERR;HEX(07)
   : GOTO 120
0130 $GIO#4(4501)
   : REM RESET CONTROLLER
0140 $IF ON #4,160
   : ERRORPRINT AT(4,30);"Error ";ERR;HEX(07)
   : GOTO 120
0150 PRINT HEX(06);AT(4,35);"Power up diagnostics in progress"
   : $BREAK
   : $GIO(75FF 75FF)
   : P=P+1
   : IF P<20THEN 140
   : PRINT HEX(06),AT(4,0,);"Controller is not ready - check address and try a
     gain"
   : STOP
   : GOTO 10
0160 GOSUB '102
   : REM CONTROLLER STATUS
0170 REM % DOWNLOAD ROUTINE FOR 2229 TAPE CONTROLLER
   : INIT(01)X1$
   : PRINT HEX(06);AT(1,0,)
   : F$="@2229"
   : LIMITS T#1,F$,A,A,A,A
   : IF A=2THEN 180
   : STOP "Microcode file @2229 not on utilities platter"
   : GOTO 10
0180 D=0
   : PRINT AT(4,0,);"Loading: ";
   : DATA LOAD DC OPEN T#1,F$
   : ERRORGOTO 240
0190 DATA LOAD DC #1,X$,X1$,X$()
   : ERRORGOTO 240
0200 IF END  THEN 220
   : IF STR(X$,1,1)=HEX(01)THEN 210
   : IF D=1THEN 190
   : IF STR(X$,1,1)<>HEX(00)THEN 190
   : PRINT X$(1)
   : D=1
   : GOTO 190
0210 STR(R$,1,2)=X1$
   : STR(R$,3,1)=STR(X1$,3)
   : $GIO#4(4440 4210 4220 4230 1800 1300 A000,R$)STR(X$(),1,VAL(STR(X1$,3)))
   : GOTO 190
0220 $GIO#4 (4441,R$)
   : PRINT AT(5,0,79);"Controller microcode loaded"
   : $GIO(75FF 75FF 75FF 75FF)
0230 LOAD T#1,F9$BEG 20
   : REM PASS CONTROL TO BACKUP/RECOVERY FILE
0240 PRINT "Disk error ";ERR
   : STOP
0250 DEFFN'126
   : LOAD T"@MENU"
0260 DEFFN'102
   : REM CONTROLLER STATUS
   : R$=ALL(01)
0270 $GIO#4(4402 8701 1800 C340,R$)STR(S$,1,VAL(STR(R$,1,1)))
   : ERRORPRINT AT(3,0,150);"Error ";ERR;" taking controller status";HEX(07)
   : PRINT "Press any key to continue"
   : KEYIN K$
   : GOTO 10
0280 IF STR(S$,10,1)=HEX(00)THEN RETURN
0290 PRINT "Power up diagnostic failure code  ";HEXOF(STR(S$,10,1))
   : PRINT "Error information: ";HEXOF(STR(S$,11,6))
   : PRINT
   : PRINT "Press any key to try again"
   : KEYIN K$
   : GOTO 10