image of READY prompt

Wang2200.org

Listing of file='36debin' on disk='vmedia/mvp-diag-2.6.2.wvd.zip'

# Sector 3436, program filename = '36debin'
0030 SELECT PRINT 005(80)
   : PRINT HEX(0306);
   : A1=#PART
   : A$="T#  DIAG"
   : CONVERT A1TO STR(A$,3,2),(##)
   : DEFFN@PARTA$
0040 DIM A$,A1,A1$1,B$1,C,C$1,C$(81)1,C1,D,I,J,L,M$20,P
0060 PRINT HEX(03020402000E);AT(1,34);"BURN-IN TESTS"
   : $PSTAT="BI-MENU"
0070 PRINT AT(5,0);"Which test would you like (1-5)";HEX(0F);AT(10,25);" 1) FU
     LL TEST (All Characters)";AT(12,25);" 2) SHORT TEST (All Screen Bits)";AT
     (14,25);" 3) FULL TEST W/Slow display";AT(16,25);" 4) SHORT TEST W/Slow d
     isplay";AT(18,25);" 5) MAIN MENU"
0075 PRINT AT(22,24);"DURING TEST KEY 'RETURN' TO CANCEL"
0080 KEYIN C$
   : C=NUM(C$)
   : IF C<>1THEN 80
   : CONVERT C$TO C
   : ON CGOSUB 210,290,220,310,740
   : GOTO 60
0100 P=P+1
   : RETURN
0210 D=4
   : GOTO 230
0220 D=1
   : GOTO 230
0230 PRINT HEX(0306)
   : $PSTAT="BI-CRT-F"
   : B$=HEX(10)
   : M$="-HEX(  )-"
   : L=9
   : C$=HEX(FF)
   : A$=HEX(020400000E)
   : GOSUB '112
   : IF D=5THEN 260
0240 PRINT HEX(0202020F0306)
   : B$=HEX(80)
   : M$="-HEX(80)-"
   : C$=HEX(94)
   : GOSUB '112
   : IF D=5THEN 260
   : B$=HEX(C0)
   : M$="-HEX(C0)-"
   : C$=HEX(FF)
   : GOSUB '112
   : IF D=5THEN 260
0250 GOSUB 390
   : IF D=5THEN 260
   : GOSUB 100
   : GOTO 230
0260 PRINT HEX(0202000F020400000E0306)
   : RETURN
0290 D=4
   : GOTO 320
0310 D=1
   : GOTO 320
0320 PRINT HEX(0306)
   : $PSTAT="BI-CRT-S"
   : B$=HEX(11)
   : M$="-HEX(  )-"
   : L=9
   : C$=HEX(FF)
   : A$=HEX(020400000E)
   : GOSUB '111
   : IF D=5THEN 260
0330 PRINT HEX(0202020F0306)
   : B$=HEX(88)
   : M$="-HEX(80)-"
   : C$=HEX(FF)
   : GOSUB '111
   : IF D=5THEN 260
0340 GOSUB 390
   : IF D=5THEN 260
   : GOSUB 100
   : GOTO 320
0350 DEFFN'111
   : C$()=ALL(B$)
   : GOSUB '108
   : PRINT AT(12,40);HEXOF(B$)
   : IF D=5THEN RETURN
   : IF B$=C$THEN RETURN
   : B$=ADDCHEX(11)
   : GOSUB '109
   : IF D=5THEN RETURN
   : GOTO 350
0360 DEFFN'112
   : C$()=ALL(B$)
   : GOSUB '108
   : PRINT AT(12,40);HEXOF(B$)
   : IF D=5THEN RETURN
   : IF B$=C$THEN RETURN
   : B$=ADDCHEX(01)
   : GOSUB '109
   : IF D=5THEN RETURN
   : GOTO 360
0390 PRINT HEX(0202020F0306)
0400 A$=HEX(020400000E)
   : M$="* NORMAL *"
   : L=10
   : GOSUB '105
   : GOSUB '109
   : IF D=5THEN RETURN
0410 A$=HEX(020402000E)
   : M$="* BRIGHT *"
   : L=10
   : GOSUB '105
   : GOSUB '109
   : IF D=5THEN RETURN
0420 A$=HEX(020404000E)
   : M$="* BLINK *"
   : L=9
   : GOSUB '105
   : GOSUB '109
   : IF D=5THEN RETURN
0440 PRINT HEX(0202000F)
0450 A$=HEX(020400020E)
   : M$="*REVERSE*VIDEO*"
   : L=15
   : GOSUB '106
   : GOSUB '109
   : IF D=5THEN RETURN
0460 A$=HEX(020400040E)
   : M$="*UNDERSCORE*"
   : L=12
   : GOSUB '106
   : GOSUB '109
   : IF D=5THEN RETURN
0470 A$=HEX(0204000B0E)
   : M$="*REVERSE/UNDERSCORE*"
   : L=20
   : GOSUB '106
   : GOSUB '109
   : IF D=5THEN RETURN
0480 A$=HEX(020402020E)
   : M$="*BRIGHT/REVERSE*"
   : L=16
   : GOSUB '106
   : GOSUB '109
   : IF D=5THEN RETURN
0490 A$=HEX(020404020E)
   : M$="*BLINK/REVERSE*"
   : L=15
   : GOSUB '106
   : GOSUB '109
   : IF D=5THEN RETURN
0500 A$=HEX(020404040E)
   : M$="*BLINK/UNDERSCORE*"
   : L=18
   : GOSUB '106
   : GOSUB '109
   : IF D=5THEN RETURN
0510 A$=HEX(0204020B0E)
   : M$="*BRIGHT/R.V./U.S.*"
   : L=18
   : GOSUB '106
   : GOSUB '109
   : IF D=5THEN RETURN
0520 A$=HEX(0204040B0E)
   : M$="*BLINK/R.V./U.S.*"
   : L=17
   : GOSUB '106
   : GOSUB '109
   : IF D=5THEN RETURN
0530 PRINT HEX(03)
   : A$=HEX(020400000E06)
   : C$()=ALL(" ")
   : FOR I=2TO 79STEP 2
   : C$(I)="!"
   : NEXT I
   : M$="   B O X   E V E N  "
   : L=0
   : GOSUB '108
   : L=20
   : GOSUB '103
   : FOR I=0TO 77STEP 4
   : PRINT AT(0,I);BOX(24,2);
   : NEXT I
   : FOR I=0TO 23STEP 2
   : PRINT AT(I,0);BOX(1,78);
   : NEXT I
   : PRINT AT(23,0);BOX(1,78)
   : GOSUB '109
   : IF D=5THEN RETURN
0540 SELECT PRINT 205(81)
   : PRINT HEX(03)
   : A$=HEX(020400000E06)
   : C$()=ALL(" ")
   : FOR I=3TO 79STEP 2
   : C$(I)="!"
   : NEXT I
   : M$="   B O X   O D D  "
   : L=0
   : GOSUB '108
   : L=18
   : GOSUB '103
   : FOR I=1TO 78STEP 4
   : PRINT AT(0,I);BOX(24,2);
   : NEXT I
   : FOR I=0TO 23STEP 2
   : PRINT AT(I,1);BOX(1,78);
   : NEXT I
   : PRINT AT(23,1);BOX(1,78)
   : GOSUB '109
   : SELECT PRINT 005(80)
0560 PRINT HEX(03)
   : RETURN
0580 DEFFN'104
   : PRINT AT(12,40-L/2);STR(M$,1,L)
   : PRINT AT(11,40-L/2,L);AT(11,36);"PASS ";P
   : RETURN
0581 DEFFN'103
   : PRINT AT(12,40-L/2);STR(M$,1,L)
   : RETURN
0600 DEFFN'105
   : INIT(FF)C$()
   : GOSUB '108
   : RETURN
0620 DEFFN'106
   : INIT(21)C$()
   : GOSUB '108
   : RETURN
0640 DEFFN'108
   : C$(81)=HEX(00)
   : FOR I=0TO 22
   : PRINT A$;AT(I,0);
   : $GIO/005(A0004001)C$()
   : NEXT I
   : C$(81)=HEX(01)
   : PRINT AT(23,0);
   : $GIO/005(A0004001)C$()
   : IF L>0THEN GOSUB '104
   : RETURN
0660 DEFFN'109
   : KEYIN A1$,670,660
   : GOTO 680
0670 IF A1$=HEX(0D)THEN 730
0680 IF D=4THEN RETURN
   : IF D>0THEN 720
0690 KEYIN A1$,700,690
   : GOTO 690
0700 RETURN
0720 FOR I=1TO 8000
   : NEXT I
   : RETURN
0730 PRINT HEX(020400000E0202000F)
   : D=5
   : RETURN
0740 LOAD T"TERMINAL"