image of READY prompt

Wang2200.org

Listing of file='GPE-1' on disk='vmedia/mvp-diag-2.6.2.wvd.zip'

# Sector 3495, program filename = 'GPE-1'
0220 DIM T1$1,T3$30,Q$1,K$1,K1$1,Q1$1,D1$43,D2$7,T3$30
0230 GOSUB '33
0240 PRINT HEX(03060A0A0A);"1-215   2-204   3-216   4-217";HEX(0A0A)
0250 INPUT "SELECT THE PRINTER ADDRESS BY KEYING THE NUMBER 1,2,3 OR 4",A
0260 A1=0
   : IF A=2 THEN A1=1
   : GOSUB '32
   : PRINT HEX(020D0C030F),"GPE-1  REV 6170"
   : PRINT HEX(0A0A0A)
0270 IF A=0THEN GOTO 240
0280 GOSUB '33
0290 K$="X"
0300 PRINT HEX(03060A0A0A)
0310 PRINT " 1 PRINTER RDY      11 SEND 1 CHARACTER      21 PLATEN HEIGHT"
0320 PRINT " 2 DATA BUFFER      12 SELECT/DESEL & ALARM  22 HAMMER ADJUST"
0330 PRINT " 3 PIN FIRING       13 OPERATOR CLEAR        23 RIBBON HEIGHT"
0340 PRINT " 4 CHARACTER SET    14 PAPER OUT             24 CARD GUIDE"
0350 PRINT " 5 SPIRAL PRINT     15 HEAD POSITIONING      25 WORST CASE"
0360 PRINT " 6 CARRIAGE RET-1   16 HORIZONTAL TAB-2      26 LINES PER INCH"
0370 PRINT " 7 LINE FEED        17 V.F.U. CODES          27 CARRIAGE ENCODER A
     LI"
0380 PRINT " 8 VERTICAL TAB     18 CLEAR BUFFER          28 PLOTTER TEST"
0390 PRINT " 9 HORIZONTAL TAB-1 19 CARRIAGE RET-2"
0400 PRINT "10 END OF DOCUMENT  20 TWIN SHEET FEEDER"
0410 PRINT HEX(0A),"A SERIES OF TESTS HAS BEEN CHOSEN FOR"
0420 PRINT "A CONFIDENCE CHECK OF THE PRINTER."
0430 INPUT "DO YOU WANT TO RUN THAT SERIES OF TESTS ?  KEY  Y  OR  N",Q$
   : IF Q$="Y"THEN GOTO 510
0440 PRINT HEX(0A0A0A),"THIS PRINTER RUNS TESTS",T2$
0450 IF Q$<>"N"THEN GOTO 300
0460 INPUT "SELECT THE TEST THAT YOU WANT TO LOOP ON",T
0470 IF T>30THEN GOTO 300
   : IF T=0THEN GOTO 300
0480 PRINT HEX(0A0A),"KEY 'I' TO INTERUPT"
0490 FOR I1=1TO 6000
   : NEXT I1
0500 GOTO 1130
0510 PRINT HEX(0A),"TESTS 12,13, AND 14 ARE MANUAL INTERVENTION TESTS"
0520 INPUT "DO YOU WANT TO INCLUDE THEM ?    KEY  Y or N",Q1$
0530 J=LEN(T$)
0540 FOR T=1TO J
   : T1$=STR(T$,T,1)
0550 ON VAL(T1$)GOTO 620,630,640,650,660,670,680,690,700,710,720,730,740,750,7
     60,770,780,790,800,810,820,830,840,850,860,870,880,890,900,910
0560 NEXT T
0570 PRINT HEX(0C)
   : GOSUB '33
0580 PRINT HEX(0703060A0A0A),"ALL TESTS HAVE BEEN RUN"
0590 PRINT HEX(0A0A0A),"KEY  LOAD, RUN, RETURN  TO GET BACK TO MAIN MENU"
0600 COM CLEAR
   : STOP #
0620 GOSUB '101
   : IF Q$="N"THEN GOTO 280
   : GOTO 560
0630 GOSUB '102
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0640 GOSUB '103
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0650 GOSUB '104
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0660 GOSUB '105
   : IF Q$="N"THEN GOTO 280
   : GOTO 560
0670 GOSUB '106
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0680 GOSUB '107
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0690 GOSUB '108
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0700 GOSUB '109
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0710 GOSUB '110
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0720 GOSUB '111
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0730 GOSUB '112
   : IF Q$="N"THEN GOTO 280
   : GOTO 560
0740 GOSUB '113
   : IF Q$="N"THEN GOTO 280
   : GOTO 560
0750 GOSUB '114
   : IF Q$="N"THEN GOTO 280
   : GOTO 560
0760 GOSUB '115
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0770 GOSUB '116
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0780 GOSUB '117
   : IF Q$="N"THEN GOTO 280
   : GOTO 560
0790 GOSUB '118
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0800 GOSUB '119
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0810 GOSUB '120
   : IF Q$="N"THEN GOTO 280
   : GOTO 560
0820 GOSUB '121
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0830 GOSUB '122
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0840 GOSUB '123
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0850 GOSUB '124
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0860 GOSUB '125
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0870 GOSUB '126
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0880 GOSUB '127
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0890 GOSUB '128
   : IF Q$="N"THEN GOTO 280
   : GOTO 560
0900 GOSUB '129
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0910 GOSUB '130
   : IF Q$="N"THEN GOTO 1130
   : GOTO 560
0920 DEFFN'32
0950 IF A=0THEN GOTO 1010
   : IF A>4THEN GOTO 1010
0960 ON AGOTO 970,980,990,1000
0970 SELECT PRINT 215(N)
   : SELECT #1/215
   : RETURN
0980 SELECT PRINT 204(N)
   : SELECT #1/204
   : RETURN
0990 SELECT PRINT 216(N)
   : SELECT #1/216
   : RETURN
1000 SELECT PRINT 217(N)
   : SELECT #1/217
   : RETURN
1010 PRINT HEX(03060A0A0A07);"YOU DID NOT SELECT A PRINTER THAT IS ON THE LIST
     "
1020 A=0
1030 FOR I1=1TO 10500
   : NEXT I1
1040 RETURN
1050 DEFFN'33
1060 SELECT PRINT 005(80)
1070 RETURN
1090 PRINT HEX(03060A)
1100 INPUT "DO YOU WANT TO RUN ALL THE TESTS FOR THIS PRINTER? KEY Y OR N",Q$
1110 IF Q$="Y"THEN RETURN
1120 IF Q$<>"N"THEN GOTO 1100
1130 KEYIN K$,1150,1150
1150 IF K$="I"THEN GOTO 280
1160 T3$=HEX(0102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E)
1170 T1$=STR(T3$,T,1)
1180 ON VAL(T1$)GOTO 620,630,640,650,660,670,680,690,700,710,720,730,740,750,7
     60,770,780,790,800,810,820,830,840,850,860,870,880,890,900,910
1190 GOTO 280
1200 DEFFN'101
1230 DIM R$10,V$1
1240 $IF ON #1,1250
   : GOTO 1350
1250 IF A1<>1 THEN $GIO#1(410D,R$)
   : ELSE $GIO#1(400D,R$)
1260 $IF ON #1,1270
   : GOTO 1350
1270 STR(R$,3,2)=HEX(0400)
1280 $GIO#1(12324020400D400E1200,R$)
1290 V$=STR(R$,8,1)AND HEX(10)
1300 IF V$=HEX(10)THEN GOTO 1350
1310 $GIO#1(1232407F1200,R$)
1320 V$=STR(R$,8,1)AND HEX(10)
1330 IF V$=HEX(10)THEN GOTO 1350
1340 RETURN
1350 PRINT HEX(03060A0A0A),"               PRINTER IS NOT READY"
1360 PRINT HEX(0A0A),"               KEY  RETURN  WHEN PRINTER IS READY"
1370 KEYIN K1$,1370,1370
1380 IF K1$<>HEX(0D)THEN GOTO 1370
1390 $GIO#1(4120,R$)
   : GOTO 1240
1400 DEFFN'102
1410 GOSUB '33
1420 PRINT HEX(03060A0A0A0A),"        DATA BUFFER TEST"
1430 PRINT HEX(0A0A),"      THE SEVEN CHARACTERS USED ARE ' * U 0 Q 2 4 H '"
1440 PRINT HEX(0A0A),"      THE PRINTER SHOULD PRINT ONE LINE OF EACH CHARACTE
     R"
1460 D2$="*U0Q24H"
1470 GOSUB '32
1500 PRINT HEX(0E),"DATA BUFFER TEST"
1510 PRINT HEX(0A0A),"THE CHARACTERS PRINTED SHOULD BE  *(2A) U(55) 0(30) Q(51
     ) 2(32) 4(34) H(48) "
   : PRINT HEX(0A0A)
1520 I3=1
1530 FOR I4=1TO N
1540 PRINT STR(D2$,I3,1);
1550 NEXT I4
1560 PRINT HEX(0D)
1580 I3=I3+1
   : IF I3<8THEN GOTO 1530
1590 RETURN
1600 DEFFN'103
1610 DIM Z5$2
1620 GOSUB '33
1650 PRINT HEX(03060A0A0A),"        PIN FIRING TEST"
1660 PRINT HEX(0A0A),"        SHOULD PRINT TEN ROWS OF ' W/ '"
1670 PRINT HEX(0A0A),"        THE ' W ' AND ' / ' CHARACTERS"
1680 PRINT HEX(0A0A),"        SHOULD NOT BE MISSING ANY DOTS."
1690 GOSUB '32
1700 PRINT HEX(0A0D0E),"PIN FIRING TEST"
1710 PRINT HEX(0A0A0F)
1730 I4=0
1740 I3=1
1750 Z5$="W/"
1760 PRINT Z5$;
1770 I3=I3+1
   : IF I3<=N/2THEN GOTO 1760
1780 I4=I4+1
   : IF I4<10THEN GOTO 1740
1790 RETURN
1800 DEFFN'104
1810 GOSUB '33
1820 PRINT HEX(03060A0A0A),"        CHARACTER SET"
1830 GOSUB '32
   : PRINT HEX(0B0D0E),"CHARACTER SET"
1840 DIM S$1
   : S$=F1$
1850 PRINT HEX(0D)
1860 FOR I3=1TO 32
   : PRINT S$;
   : ADD(S$,01)
1870 IF S$>L1$THEN GOTO 1890
   : NEXT I3
1880 GOTO 1850
1890 PRINT HEX(0D0A)
   : RETURN
1900 DEFFN'105
1910 GOSUB '33
1920 PRINT HEX(03060A0A0A0A),"             SPIRAL PRINT TEST"
1930 GOSUB '32
1940 PRINT HEX(0D0C0E),"SPIRAL  PRINT  TEST"
1960 N1=N
1980 Y=L*5-3
1990 IF E=0THEN Y=L*10-3
2010 GOSUB '37
2020 IF K1$="I"THEN RETURN
2030 IF E=0THEN RETURN
2040 PRINT HEX(0D0E0A0A),"EXPANDED SPIRAL PRINT TEST"
2060 N1=E
2080 GOSUB '37
2090 RETURN
2100 DEFFN'106
2110 GOSUB '33
2120 PRINT HEX(03060A0A0A),"        CARRIAGE RETURN TEST"
2130 IF N<81THEN GOSUB '119
2140 IF N<81THEN RETURN
2150 GOSUB '32
   : I3=0
2160 PRINT HEX(0D0C0E),"CARRIAGE RETURN TEST"
2170 PRINT HEX(0A0A0A0A0F)
2180 D1$=" LAST COLUMN OF THIS LINE SHOULD BE HERE  X"
2190 D2$="NEXT TO"
2200 PRINT "SOFTWARE CARRIAGE RETURN TEST"
2210 PRINT HEX(0A)
2220 FOR I4=1TO N-51
2230 PRINT ".";
2240 NEXT I4
2250 PRINT D2$;D1$;
2260 PRINT HEX(0D0A0A0A)
2270 PRINT "HARDWARE CARRIAGE RETURN TEST"
2280 PRINT HEX(0A)
2290 FOR I4=1TO N-43
2300 PRINT ".";
2310 NEXT I4
2320 PRINT D1$;
2330 PRINT HEX(0A0A0A),"SOFTWARE AND HARDWARE CARRIAGE RETURN TEST"
2340 PRINT HEX(0A)
2350 FOR I4=1TO N-43
2360 PRINT ".";
2370 NEXT I4
2380 PRINT D1$
2390 PRINT HEX(0A0A0A)
2400 PRINT "LINE OVER RUN TEST"
2410 PRINT HEX(0A)
2420 FOR I4=1TO N-43
2430 PRINT ".";
2440 NEXT I4
2450 PRINT D1$;"OVER RUN FROM PREVIOUS LINE"
2460 I3=I3+1
2480 IF I3=1THEN GOTO 2170
2490 RETURN
2500 DEFFN'107
2510 GOSUB '33
2520 I3=(L*5)-2
2530 PRINT HEX(03060A0A0A),"             LINE FEED TEST"
2540 PRINT HEX(0A0A);"SHOULD PRINT ";I3;" STARS EVENLY SPACED DOWN THE PAGE"
2550 GOSUB '32
2560 PRINT HEX(0D0C0E),"LINE FEED TEST"
2570 FOR I4=1TO I3
   : PRINT HEX(0A2A)
   : NEXT I4
2580 PRINT " THERE SHOULD BE ";I3;" STARS EVENLY SPACED DOWN THIS PAGE."
2590 RETURN
2600 DEFFN'108
2610 GOSUB '33
2620 PRINT HEX(03060A0A0A),"        VERTICAL TAB TEST"
2630 DIM D3$21
   : D3$="** VERTICAL TAB NO.  "
2640 I3=1
2650 GOSUB '32
2660 PRINT HEX(0D0C0E),"VERTICAL TAB TEST"
2670 FOR I4=1TO 9
   : PRINT HEX(0B);D3$;I3
   : I3=I3+1
   : NEXT I4
2680 PRINT HEX(0D0D);"ACCEPTABLE RESULT IS 9 VERTICAL TABS EVENLY SPACED DOWN
     THE PAGE"
2690 RETURN
2700 DEFFN'109
2710 GOSUB '33
2720 PRINT HEX(03060A0A0A),"        HORIZONTAL TAB TEST"
2730 PRINT HEX(0A0A),"        THE ' V ' SHOULD LINE UP WITH THE ' O '"
2740 GOSUB '32
2750 PRINT HEX(0D0E);"HORIZONTAL TAB TEST";HEX(0F0A)
2760 FOR I4=1TO N/P
   : PRINT "         V";
   : NEXT I4
2770 PRINT HEX(0D)
2780 I3=P-1
2790 FOR I4=1TO N/P
2800 PRINT TAB(I3);"O";
2810 I3=I3+P
2820 NEXT I4
2830 PRINT HEX(0D)
2840 RETURN
2900 DEFFN'110
2910 GOSUB '33
2920 PRINT HEX(03060A0A0A),"        END OF DOCUMENT TEST"
2930 GOSUB '32
2940 PRINT HEX(0D0C0E),"END OF DOCUMENT TEST"
2950 PRINT HEX(0D0D)
2960 I3=4
   : D1$="LINE NO.  "
2970 FOR I4=1TO L*10-4
   : PRINT D1$;I3
   : I3=I3+1
   : NEXT I4
2980 PRINT D1$;I3;"  MUST BE THE LAST LINE ON THIS PAGE."
   : PRINT HEX(0C)
2990 RETURN
3000 DEFFN'111
3020 IF Q$="Y"THEN RETURN
3030 GOSUB '33
3040 PRINT HEX(03060A0A0A),"        CONTINUOUSLY SEND ONE CHARACTER"
3080 PRINT HEX(0A0A),"        THIS TEST CONTINUOUSLY SENDS"
3090 PRINT HEX(0A),"        ONE CHARACTER TO THE PRINTER."
3100 PRINT HEX(0A0A0A0A)
3110 INPUT "        KEY IN THE CHARACTER THAT YOU WANT TO SEND",V$
3120 PRINT HEX(0A0A),"        KEY ' I ' TO INTERUPT THIS DIAGNOSTIC"
3130 GOSUB '32
3150 PRINT V$;
3160 KEYIN K1$,3180,3180
3170 GOTO 3150
3180 IF K$="I"THEN RETURN
3190 ELSE GOTO 3150
3200 DEFFN'112
3220 IF Q1$="N"THEN RETURN
3230 GOSUB '33
3240 PRINT HEX(03060A0A0A),"        SELECT / DESELECT  &  ALARM  TESTS"
3250 PRINT HEX(0A0A0A),"      WHILE THE PRINTER IS PRINTING, DESELECT"
3260 PRINT HEX(0A),"      AND SELECT THE PRINTER AT LEAST 5 TIMES"
3270 PRINT HEX(0A),"      MAKE SURE THAT NO CHARACTERS ARE LOST."
3280 PRINT HEX(0A),"      KEY 'I' TO END THE PRINTING. AT THAT TIME"
3290 PRINT HEX(0A0A),"     THE ALARM SHOULD SOUND FIVE TIMES"
3300 GOSUB '32
3310 PRINT HEX(0D0C0E),"SELECT / DESELECT  &  ALARM TESTS"
3320 Y=L*9
3330 N1=N
3340 GOSUB '37
3360 FOR I3=1TO 5
3370 PRINT HEX(07)
3380 NEXT I3
3390 RETURN
3400 DEFFN'113
3420 IF Q1$="N"THEN RETURN
3430 GOSUB '33
3440 PRINT HEX(03060A0A0A),"        OPERATOR CLEAR TEST"
3450 PRINT HEX(0A0A),"    ( 1 )  DESELECT THE PRINTER"
3460 PRINT HEX(0A),"    ( 2 )  DEPRESS THE ' CLEAR ' BUTTON"
3470 PRINT HEX(0A),"    ( 3 )  SELECT THE PRINTER"
3480 PRINT HEX(070A),"    ( 4 )  KEY ' RETURN '"
3490 PRINT HEX(0A0A),"    IF NO ERROR, THE PRINTER PRINTS 'OPERATOR CLEAR TEST
     '"
3500 PRINT HEX(0A),"    IF AN ERROR DID OCCUR, THE PRINTER PRINTS"
3510 PRINT "    'ERROR IN OPERATOR CLEAR TEST'."
3520 GOSUB '32
3550 PRINT HEX(0E);" ERROR IN";
3580 INPUT V$
3590 PRINT HEX(0E);" OPERATOR CLEAR TEST"
   : RETURN
3600 DEFFN'114
3620 IF Q1$="N"THEN RETURN
3630 GOSUB '33
3640 PRINT HEX(03060A0A0A),"        PAPER OUT  &  FORMS OVERRIDE TEST"
3650 PRINT HEX(070A0A0A),"      ( 1 )  DESELECT THE PRINTER"
3660 PRINT HEX(0A),"      ( 2 )  TEAR THE PAPER AT THE NEXT PERFORATION"
3670 PRINT "             THAT WILL ENTER THE PRINTER"
3680 PRINT HEX(0A),"      ( 3 )  DEPRESS 'LINE FEED' UNTIL THE"
3690 PRINT "             FORMS OVERRIDE LAMP LIGHTS"
3700 PRINT HEX(0A),"      ( 4 )  SELECT THE PRINTER"
3710 PRINT HEX(0A),"      ( 6 )  DEPRESS 'FORMS OVERRIDE' TWICE"
3720 PRINT HEX(0A),"      ( 7 )  KEY 'RETURN'"
3730 INPUT V$
3740 GOSUB '32
3750 PRINT HEX(0E),"ERROR IF NOT AT BOTTOM OF PAGE"
3760 GOSUB '33
3770 PRINT HEX(0A0A07)
3780 INPUT "KEYIN ' C ' TO CONTINUE TESTING",V$
3790 IF V$<>"C"THEN GOTO 3780
   : RETURN
3800 DEFFN'115
3810 GOSUB '33
3820 PRINT HEX(03060A0A0A),"        PRINTHEAD POSITIONING TEST"
3830 FOR I1=1TO 1000
   : NEXT I1
3840 GOSUB '32
3850 PRINT HEX(0D0E),"PRINTHEAD POSITIONING TEST"
3860 S1$="l"
3870 FOR I4=1TO 10
3880 FOR I3=1TO N
   : PRINT S1$;
   : NEXT I3
3890 NEXT I4
   : RETURN
3900 DEFFN'117
3910 IF V8$="X"THEN RETURN
3920 GOSUB '33
   : PRINT HEX(03060A0A0A),"              V. F. U. CODE CHECK"
3930 PRINT HEX(0A);"THIS TEST CHECKS THE '02' CODES ON THE V. F. U.";HEX(0A0A)
3940 GOSUB '32
   : PRINT HEX(020D0C030F)
   : PRINT HEX(0D0C0E);"V. F. U. CODE TEST"
3950 PRINT HEX(0A0A0F)
3960 I1=LEN(V8$)
3970 FOR V=1TO I1
3980 V7$=STR(V8$,V,1)
3990 GOSUB '33
4000 ON VAL(V7$)GOTO 4010,4020,4030,4040,4050,4060,4070,4080,4090,4100,4110,41
     20,4130,4140,4150,4160,4170,4180,4190,4200
4010 GOSUB '201
   : GOTO 4210
4020 GOSUB '202
   : GOTO 4210
4030 GOSUB '203
   : GOTO 4210
4040 GOSUB '204
   : GOTO 4210
4050 GOSUB '205
   : GOTO 4210
4060 GOSUB '206
   : GOTO 4210
4070 GOSUB '207
   : GOTO 4210
4080 GOSUB '208
   : GOTO 4210
4090 GOSUB '209
   : GOTO 4210
4100 GOSUB '210
   : GOTO 4210
4110 GOSUB '211
   : GOTO 4210
4120 GOSUB '212
   : GOTO 4210
4130 GOSUB '213
   : GOTO 4210
4140 GOSUB '214
   : GOTO 4210
4150 GOSUB '215
   : GOTO 4210
4160 GOSUB '216
   : GOTO 4210
4170 GOSUB '217
   : GOTO 4210
4180 GOSUB '218
   : GOTO 4210
4190 GOSUB '219
   : GOTO 4210
4200 GOSUB '220
   : GOTO 4210
4210 NEXT V
4220 PRINT HEX(02040000020E)
   : RETURN
4230 DEFFN'201
4240 INPUT "SELECT ALTERNATE FONT 1,2 OR 3 ",D
4250 IF D>3THEN GOTO 4240
   : IF D=0THEN GOTO 4240
4260 GOSUB '32
4270 PRINT "ALTERNATE FONT # ";D
4280 ON DGOTO 4290,4300,4310
4290 PRINT HEX(0202020F)
   : GOSUB '104
   : GOTO 4320
4300 PRINT HEX(0202040F)
   : GOSUB '104
   : GOTO 4320
4310 PRINT HEX(0202080F)
   : GOSUB '104
   : GOTO 4320
4320 PRINT HEX(0202000F)
4330 RETURN
4340 DEFFN'202
4350 GOSUB '32
   : PRINT HEX(02040004000E)
   : PRINT HEX(0E)
4360 PRINT "DEFINE";HEX(0F);" THE MEANING OF HEX 0E."
4370 PRINT "IN THE PRECEDING PHRASE, 'DEFINE' SHOULD BE UNDERSCORED"
4380 PRINT HEX(0F),"( 02 04 00 04 00 0E CODE )"
4390 RETURN
4400 DEFFN'203
4410 PRINT HEX(0A),"THE PRINTER SHOULD HAVE DESELECTED. MANUALLY SELECT IT NOW
     ."
4420 GOSUB '32
   : PRINT HEX(02070F)
4430 RETURN
4440 DEFFN'204
4450 N1=N
   : Y=1
4460 GOSUB '32
   : PRINT HEX(020901020A000F)
4470 PRINT "SELECT 10 PITCH ( 02 09 01 02 0A 00 0F CODE )"
4480 PRINT "SHOULD PRINT 10 CHARACTERS PER INCH."
4490 GOSUB '37
4500 PRINT HEX(0209010200000F)
4510 RETURN
4520 DEFFN'205
4530 N1=N
   : Y=1
4540 GOSUB '32
   : PRINT HEX(020901020C000F)
4550 PRINT "SELECT 12 PITCH ( 02 09 01 02 0C 00 0F CODE )"
4560 PRINT "SHOULD PRINT 12 CHARACTERS PER INCH."
4570 GOSUB '37
4580 PRINT HEX(0209010200000F)
4590 RETURN
4600 DEFFN'206
4610 N1=N
   : Y=1
4620 GOSUB '32
   : PRINT HEX(0209010210100F)
4630 PRINT "SELECT 16.5 PITCH ( 02 09 01 02 10 10 0F CODE )"
4640 PRINT "SHOULD PRINT 16.5 CHARACTERS PER INCH."
4650 GOSUB '37
4660 PRINT HEX(0209010200000F)
4670 RETURN
4680 DEFFN'207
   : GOSUB '32
4690 PRINT HEX(0A)
   : PRINT HEX(020A0F)
4700 PRINT "                        ALL ON THE SAME LINE. ( 02 0A 0F CODE )"
4710 PRINT HEX(020A0E)
4720 PRINT "THIS SENTENCE SHOULD BE"
4730 PRINT "THIS SENTENCE SHOULD BE ON THE NEXT LINE. ( 02 0A 0E CODE )"
4740 RETURN
4750 DEFFN'208
4760 GOSUB '32
   : PRINT HEX(0A)
   : N1=N
   : Y=8
   : Q1$="X"
4770 PRINT HEX(020A0101080E),"EIGHT LINES PER INCH ( 02 0A 01 01 08 0E )"
4780 GOSUB '37
   : PRINT HEX(0A)
4790 PRINT HEX(020A0101060E),"SIX LINES PER INCH ( 02 0A 01 01 06 0E )"
4800 Y=6
4810 GOSUB '37
   : PRINT HEX(0A)
4820 PRINT HEX(020A0101060F),"AUTO LINE FEED IS NOW DISSABLED"
4830 PRINT "                               , SO THIS SENTENCE SHOULD BE ALL ON
      1 LINE."
4840 PRINT HEX(0A),"( 02 0A 01 01 06 0F CODE )"
4850 GOSUB '209
4860 RETURN
4870 DEFFN'209
4880 GOSUB '32
   : PRINT HEX(020D0C030F)
   : RETURN
4890 DEFFN'210
4900 GOSUB '32
   : PRINT HEX(02010201000F)
   : RETURN
4910 DEFFN'211
4920 GOSUB '32
   : PRINT HEX(0A0A)
4930 PRINT HEX(020A010206000E),"SHOULD PRINT EIGHT LINES PER INCH."
4940 N1=N
   : Y=8
   : Q1$="X"
4950 GOSUB '37
4960 PRINT HEX(0A0A)
4970 PRINT HEX(020A010208000E),"SHOULD PRINT SIX LINES PER INCH."
4980 Y=6
   : GOSUB '37
4990 RETURN
5000 DEFFN'212
5010 GOSUB '32
5020 PRINT HEX(0202020F)
   : PRINT HEX(020901020C000F)
5030 PRINT HEX(0A),"ALTERNATE FONT # 2  AND  12.2 PITCH"
5040 N1=N
   : Y=1
   : GOSUB '37
5050 PRINT HEX(0202000F)
   : PRINT HEX(020901020A000F)
5060 PRINT HEX(0A),"DEFAULT FONT  AND  10 PITCH"
5070 N1=N
   : Y=1
   : GOSUB '37
5080 PRINT HEX(0F)
5090 RETURN
5100 DEFFN'213
5110 GOSUB '32
5120 PRINT HEX(0A0F);"SHOULD PRINT ONE LINE OF ENHANCED PRINT."
5130 PRINT HEX(02040200000E)
5140 N1=N
   : Y=1
   : GOSUB '37
5150 PRINT HEX(0A0F);"SHOULD PRINT ONE LINE OF EXPANDED PRINT."
5160 PRINT HEX(02040000020E)
5170 N1=E
   : Y=1
   : GOSUB '37
5180 PRINT HEX(0A0F);"SHOULD PRINT ONE LINE OF UNDERLINED PRINT."
5190 PRINT HEX(02040004000E)
5200 N1=N
   : Y=1
   : GOSUB '37
5210 PRINT HEX(0A0F);"SHOULD PRINT ONE LINE OF ENHANCED AND UNDERLINED PRINT."
5220 PRINT HEX(02040204000E)
5230 N1=N
   : Y=1
   : GOSUB '37
5240 PRINT HEX(0A0F);"SHOULD PRINT ONE LINE OF EXPANDED AND UNDERLINED PRINT."
5250 PRINT HEX(02040004020E)
5260 N1=E
   : Y=1
   : GOSUB '37
5270 PRINT HEX(0A0F);"SHOULD PRINT ONE LINE OF ENHANCED AND EXPANDED PRINT."
5280 PRINT HEX(02040200020E)
5290 N1=E
   : Y=1
   : GOSUB '37
   : PRINT HEX(020D0C030F)
   : RETURN
5300 DEFFN'118
5310 GOSUB '33
5320 PRINT HEX(03060A0A0A),"THE WORDS 'ERROR IN THE' SHOULD BE DELETED BY A"
5330 PRINT HEX(0A),"7F CODE FROM THE ' DELETE THE LINE BUFFER ' SENTENCE."
5340 GOSUB '32
5350 PRINT "A 7F CODE SHOULD DELETE THE WORD 'ERROR' FROM THE FOLLOWING PHRASE
     "
5360 PRINT "ERROR IN THE ";
5370 PRINT HEX(7F);
5380 PRINT "'  DELETE THE LINE BUFFER  ' CODE ( 7F )."
5390 RETURN
5400 DEFFN'121
5410 GOSUB '33
5420 PRINT HEX(03060A0A),"PLATEN HEIGHT CHECK"
5430 FOR I1=1TO 8000
   : NEXT I1
5440 GOSUB '32
5450 IF Q$="Y"THEN PRINT HEX(0D0C0E),"SPECIAL PATTERNS"
5460 PRINT HEX(0A0A0A0A),"PLATEN HEIGHT CHECK"
5470 PRINT HEX(0A0A)
5480 FOR I3=1TO N/4
   : PRINT HEX(5F);"Z8S";
   : NEXT I3
5490 RETURN
5500 DEFFN'122
5510 GOSUB '33
5520 PRINT HEX(0A0A),"HAMMER STRIKE CHECK"
5530 GOSUB '32
5540 IF Q$="N"THEN GOTO 5560
5550 PRINT HEX(0A0A),"HAMMER STRIKE CHECK"
   : PRINT HEX(0A0A)
5560 V$="M"
   : GOSUB '40
5570 V$="Z"
   : GOSUB '40
5580 V$="H"
   : GOSUB '40
5590 RETURN
5600 DEFFN'123
5610 GOSUB '33
5620 PRINT HEX(0A0A),"RIBBON HEIGHT CHECK"
5630 GOSUB '32
5640 PRINT HEX(0A0A),"RIBBON HEIGHT CHECK"
   : PRINT HEX(0A0A)
5650 V$="H"
   : GOSUB '40
5660 FOR I3=1TO N
5670 PRINT HEX(4D5F);
   : NEXT I3
5680 FOR I3=1TO N
   : PRINT HEX(5F);
   : NEXT I3
5690 RETURN
5700 DEFFN'124
5710 GOSUB '33
5720 PRINT HEX(0A0A),"CARD GUIDE CHECK"
5730 GOSUB '32
5740 V$="M"
5750 PRINT HEX(0A0A),"CARD GUIDE CHECK"
5760 PRINT HEX(0A0A)
5770 GOSUB '40
5780 RETURN
5800 DEFFN'125
5810 GOSUB '33
5820 PRINT HEX(0A0A),"WORST CASE PATTERN"
5830 GOSUB '32
5840 PRINT HEX(0A0A),"WORST CASE PATTERN"
   : PRINT HEX(0A0A)
5850 D2$="IEHX"
5860 FOR I3=1TO N/4
5870 PRINT D2$;
5880 NEXT I3
5890 PRINT HEX(0D)
   : RETURN
5900 DEFFN'126
5910 GOSUB '33
5920 PRINT HEX(0A0A),"    SPIRAL PRINT & LINES PER INCH TESTS"
5930 PRINT HEX(0A),"    CHECK FOR ";L;" LINES PER INCH"
5940 GOSUB '32
5950 PRINT HEX(0A0A)
5960 Y=L
   : N1=N
5970 PRINT "CHECK FOR ";L;" LINES PER INCH"
   : PRINT HEX(0A0A)
5980 GOSUB '37
5990 RETURN
6000 DEFFN'127
6010 K$="X"
   : GOSUB '33
6020 PRINT HEX(0306070A0A0A0E),"                   WARNING"
6030 PRINT HEX(0A0A07),"       KEEP HANDS AWAY FROM PRINT HEAD AREA"
6040 PRINT HEX(0A0A0A),"       KEY ' I ' TO INTERUPT"
6050 FOR I1=1TO 5000
   : NEXT I1
6060 GOSUB '32
6070 FOR I4=1TO 50
6080 KEYIN K$,6090,6090
6090 IF K$="I"THEN GOTO 6140
6100 PRINT ".";
6110 FOR I3=1TO 130
   : PRINT " ";
   : NEXT I3
6120 PRINT "."
   : PRINT HEX(FAFA)
6130 NEXT I4
6140 GOSUB '33
6150 PRINT HEX(0703060A0A0A),"       DO YOU WANT TO CONTINUE THIS ROUTINE ?"
6160 PRINT HEX(0A0A)
6170 INPUT " Y OR N ?",V$
6180 IF V$="Y"THEN GOTO 6020
6190 K$="I"
   : RETURN
6200 DEFFN'128
6210 GOSUB '33
6220 PRINT HEX(03060A0A0A),"                    PLOTTER TEST"
6230 PRINT HEX(0A07),"PRINTER MUST HAVE WIDE PAPER TO RUN THIS TEST"
6240 PRINT HEX(0A),"THIS ROUTINE TESTS CODES E0,E4,E5,E6,E7,E8, AND FA"
6250 PRINT HEX(0A),"POWER THE PRINTER OFF, THEN ON AGAIN, AND SELECT IT"
6260 FOR I1=1TO 18000
   : NEXT I1
   : IF N<130THEN RETURN
6270 INPUT "KEY ' RETURN ' WHEN YOU ARE READY TO PROCEDE ",V$
6280 GOSUB '32
   : V$="O"
6290 PRINT HEX(E5)
6300 PRINT HEX(E7016B0000);V$
6310 PRINT HEX(E7016B0120);V$
6320 PRINT HEX(E700000120);V$
6330 PRINT HEX(E700000000);V$
6340 V$="."
6350 PRINT HEX(E7016B011E);V$
6360 PRINT HEX(E000000120);V$
6370 FOR I3=1TO 3
   : PRINT HEX(E687A0);
   : NEXT I3
6380 PRINT HEX(E4);V$
6390 PRINT HEX(E70000FEE0);V$
6400 PRINT HEX(E5)
   : PRINT HEX(E80186)
   : PRINT "               PLOTTER TEST"
6410 PRINT HEX(0A0A),"THIS ROUTINE TESTS CODES E0,E4,E5,E6,E7,E8, AND FA."
6420 PRINT "THE SEQUENCE FOR CREATING THE PATTERN TO THE LEFT IS AS FOLLOWS:"
6430 PRINT "1. E5 PUTS THE PRINT HEAD AT THE  ' POWER UP '  HOME POSITION."
6440 PRINT "2. VIA THE E7 CODE, FOUR O'S ARE PRINTED TO FORM A 6 INCH SQUARE."
6450 PRINT "3. THE E7 CODE IS AGAIN USED TO PRINT A DOT IN THE LOWER-RIGHT O."
6460 PRINT "4. E0 IS USED TO PRINT A DOT IN THE UPPER-RIGHT O."
6470 PRINT "5. E6 IS REPEATED 3 TIMES, TO POSITION THE PRINT HEAD FOR "
6480 PRINT "PRINTING THE DOT IN THE LOWER-LEFT O."
6490 PRINT "6. THERE, E4 ESTABLISHES A NEW  ' HOME '  REFERENCE POINT."
6500 PRINT "7. FINALLY, USING THE NEW  ' HOME '  REFERENCE, E7 MOVES"
6510 PRINT "THE PRINT HEAD INTO POSITION FOR PRINTING THE UPPER-LEFT DOT."
6520 PRINT HEX(0A);"IF ANY OF THE DOTS ARE OUT OF POSITION AND/OR THEY DON'T"
6530 PRINT "FORM A 6 INCH SQUARE, FOLLOW THE ABOVE SEQUENCE TO DETERMINE"
6540 PRINT "WHICH CODE FAILED."
6550 PRINT "PRIOR TO PRINTING THE ABOVE MESSAGE, AN E8 CODE WAS SENT, SO"
6560 PRINT "THE LEFT MARGIN SHOULD BE 1/2 INCH TO THE RIGHT OF THE BOX."
6570 PRINT HEX(0A)
6580 PRINT "                 TO PRINT THIS SENTENCE ALL ON ONE LINE."
6590 PRINT HEX(FA);"HEX 'FA' IS USED "
   : PRINT HEX(E5)
   : RETURN
6600 DEFFN'37
6650 DIM U$(2)108,U1$(2)108
6670 S$=F1$
6680 FOR I5=1TO N1
6690 STR(U$(),I5,1)=S$
6700 ADD(S$,01)
6710 IF S$>L1$THEN S$=F1$
6720 NEXT I5
6740 FOR I5=1TO Y
6750 IF N1=ETHEN PRINT HEX(0E);
6760 PRINT STR(U$(),1,N1)
6770 KEYIN Q1$,6780,6780
6780 IF Q1$="I"THEN RETURN
6850 MAT COPY U$()<2,N1>TO U1$()<1,N1-1>
6860 MAT COPY U$()<1,1>TO U1$()<N1,1>
6870 MAT COPY U1$()<1,N1>TO U$()<1,N1>
6880 NEXT I5
6890 RETURN
6900 DEFFN'40
6910 FOR I3=1TO N
6920 PRINT V$;
6930 NEXT I3
6940 RETURN
6950 DEFFN'116
6960 GOSUB '33
6970 PRINT HEX(03060A0A0A),"        HORIZONTAL TAB TEST"
6980 PRINT HEX(0A0A),"        THE ' V ' SHOULD LINE UP WITH THE ' O '"
6990 GOSUB '32
   : PRINT HEX(0A0A),"HORIZONTAL TAB TEST"
7000 I4=-1
7010 FOR I3=PTO N-PSTEP P
7020 PRINT TAB(I3+I4);HEX(1A);
7030 I4=I4+1
7040 NEXT I3
   : PRINT
7050 FOR I3=PTO N-PSTEP P
7060 PRINT HEX(09);"V";
7070 NEXT I3
   : PRINT
7080 FOR I3=PTO N-PSTEP P
7090 PRINT "         O";
   : NEXT I3
   : PRINT
   : RETURN
7100 DEFFN'119
7110 GOSUB '33
   : PRINT HEX(0A0A),"        SHORT LINE C.R. CHECK"
7120 GOSUB '32
7130 PRINT "SOFTWARE CARRIAGE RETURN CHECK"
7140 FOR I3=1TO N-36
   : PRINT HEX(20);
   : NEXT I3
7150 PRINT "NEXT TO LAST COLUMN MUST BE HERE  X"
7160 PRINT "HARDWARE CARRIAGE RETURN CHECK"
7170 FOR I3=1TO N-27
   : PRINT HEX(20);
   : NEXT I3
7180 PRINT "LAST COLUMN MUST BE HERE  X"
7190 RETURN
7200 DEFFN'120
7210 INPUT "DOES THIS PRINTER HAVE A 'TWIN SHEET FEEDER' ? Y OR N ?",K1$
7230 IF K1$<>"Y"THEN RETURN
7240 GOSUB '32
7250 PRINT HEX(0206020F)
7260 PRINT HEX(0C),"THIS PAGE SHOULD HAVE COME FROM THE FRONT TRAY."
7270 PRINT "( 02 06 02 0F CODE )"
7280 PRINT HEX(0206010F)
7290 PRINT HEX(020101080F)
7300 PRINT HEX(0C),"THIS PAGE SHOULD HAVE COME FROM THE REAR TRAY."
7310 PRINT "( 02 06 01 0F CODE )"
7320 PRINT "THE TOP MARGIN SHOULD BE 1/2 INCH, RATHER THAN THE USUAL 1 INCH."
7330 PRINT "( 02 01 01 08 0F CODE )"
7340 PRINT "ABC  V   THE V'S ON THIS LINE AND THE NEXT SHOULD LINE UP."
7350 PRINT HEX(020101040F),"ABC    V   ( 02 01 01 04 0F CODE )"
7360 PRINT "THE PLATEN SHOULD HAVE CLEARED."
7370 PRINT "( 02 03 0F CODE )"
7380 PRINT HEX(02030F)
7390 RETURN
7400 DEFFN'129
   : PRINT "DON'T SELECT TEST 29."
   : RETURN
7410 DEFFN'130
   : PRINT "DON'T SELECT TEST 30."
   : RETURN