image of READY prompt

Wang2200.org

Listing of file='INSTALL' on disk='vmedia/sds40.wvd.zip'

# Sector 487, program filename = 'INSTALL', protected file
0000 %SDSBASIC -- =INSTALL Program - Installs SDS-Extended BASIC-2 Demo Copy
0001 % TRADE SECRET -- THIS PROGRAM IS A PROPRIETARY PRODUCT OF
0002 % TRADE SECRET --       SOUTHERN DATA SYSTEMS, INC
0003 % TRADE SECRET -- UNAUTHORIZED USE OR REPRODUCTION IS PROHIHBITED
0004 %REV 4.0.1 04-17-87 RSD
0010 DIM Z1$(6)80,J$3,J1$3,K$3,M$1,X9$79
0050 DIM C$4
   : C$=ALL(00)
0101 DIM B1$(16)16
0130 SELECT PRINT 005(80),LIST 005(80),CO 005(80)
0170 PRINT HEX(03);
   : GOSUB '200
   : PRINT AT(2,12);BOX(1,54);"  SDS-Extended BASIC-2 Demo-Copy Installation P
     rogram"
0180 PRINT AT(14,7);"This program will install the demo copy of SDS-Extended B
     ASIC-2."
0190 PRINT AT(16,1);"Before running this program, you need to know the followi
     ng:";AT(17,1);"1- The address of the disk containing SDS-Extended BASIC-2
     .";AT(18,1);"2- The address of the disk where SDS-Extended BASIC-2 will b
     e installed."
0210 PRINT AT(20,1);HEX(0E);"NOTICE";HEX(0F);" --> A Backup of your system dis
     k should be done before proceeding."
0220 PRINT AT(22,7,70);"Touch any key to continue ";HEX(8B08020404000F);
   : KEYIN Z$
   : PRINT AT(14,1,9*80);
0230 PRINT AT(14,73);BOX(1,4);AT(14,1);
   : PRINT "Enter the Device Address of the disk received from SDS:
           ";
   : LINPUT -K$
   : Q7=5
   : GOSUB '203(K$)
   : PRINT AT(16,1,560);
   : IF E<>0THEN 230
0235 LIMITS T#5,"@SDS",S1,E1,Z,Z
   : IF S1<=0THEN 461
   : A8=E1-S1+1
   : LIMITS T#5,"@MVP",S2,E2,Z,Z
   : IF S2<=0THEN 461
   : A4=E2-S2+1
   : X9=A8+A4
0240 PRINT AT(15,73);BOX(-2,-4);BOX(1,4);AT(15,1,166);
   : Q1,Q2=-1
   : PRINT "Enter the Disk Address where SDS-Extended BASIC-2 is to be install
     ed:   ";
   : LINPUT -J$
   : IF J$=K$THEN 463
   : Q7=4
   : GOSUB '203(J$)
   : IF E<>0THEN 240
0250 PRINT AT(17,1,79);HEX(06);"Searching for existing '@MVP' file on disk ";J
     $
   : LIMITS T#4,"@MVP",S4,E4,Z,Z
   : IF S4>0THEN A6=E4-S4+1
   : ELSE A6=0
0252 PRINT AT(17,1,79);HEX(06);"Searching for existing '@SDS' file on disk ";J
     $
   : LIMITS T#4,"@SDS",S3,E3,Z,Z
   : IF S3>0THEN A2=E3-S3+1
   : ELSE A2=0
0270 PRINT AT(16,1,560);AT(17,7);"Verifying Space on Target disk"
0275 DATA LOAD BA T#4,(0)B1$()
   : D1=VAL(STR(B1$(),5,2),2)
   : D2=VAL(STR(B1$(),3,2),2)
   : D3=D1-D2
   : IF A2>=A8THEN X9=X9-A8
   : IF A6>=A4THEN X9=X9-A4
   : IF D3>X9THEN 300
0280 PRINT AT(16,1,560);AT(17,2);"Insufficient space available on target disk
     to install SDS-Extended BASIC-2."
0281 PRINT AT(18,1);HEX(0E);X9;HEX(0F);"additional sectors will be added by in
     stalling SDS-Extended BASIC-2."
0282 PRINT AT(19,2);"Only";D3;"sectors are available on your ";J$;" disk, ther
     efore you must either"
0283 PRINT AT(20,2);"Move the END paramater of this disk to at least";HEX(0E);
     D2+X9+2;HEX(0F);"or reorganize the disk."
0284 PRINT AT(21,2);"After you correct this problem, restart the INSTALL progr
     am."
0299 STOP
   : GOTO 299
0300 PRINT AT(17,1,79);"Moving '@SDS' from ";K$;" to ";J$;
   : IF S1>0THEN 303
   : GOSUB '204("Cannot locate '@SDS' file on disk")
   : GOTO 230
0303 IF A2=0THEN 321
   : IF A2<A8THEN 310
   : COPY T#5,(S1,E1)TO T#4,(S3)
   : ERRORX=ERR
   : GOTO 460
0305 GOTO 400
0310 X9=0
0311 X9=X9+1
   : CONVERT X9TO C$,(#)
   : O$="@SDS"&C$
   : SCRATCH T#4,"@SDS"
   : DATA SAVE DC OPEN T#4,("@SDS")O$
   : ERRORX=ERR
   : IF X=83THEN 311
   : GOTO 460
0321 MOVE T#5,"@SDS"TO T#4,
   : ERRORX=ERR
   : GOTO 460
0400 PRINT AT(17,1,79);"Moving SDS-Preloader from ";K$;" to ";J$;
   : IF S2>0THEN 411
   : GOSUB '204("Cannot locate '@MVP' Preloader file on disk")
   : GOTO 230
0411 IF A6=0THEN 429
0415 X9=0
   : O$="@MVPold"
   : GOTO 419
0418 X9=X9+1
   : CONVERT X9TO C$,(#)
   : O$="@MVPold"&C$
0419 SCRATCH T#4,"@MVP"
   : DATA SAVE DC OPEN T#4,("@MVP")O$
   : ERRORX=ERR
   : IF X=83THEN 418
   : GOTO 462
0429 MOVE T#5,"@MVP"TO T#4,
   : ERRORX=ERR
   : GOTO 460
0430 GOTO 530
0460 GOSUB '204("Error occurred during move - Cannot proceed")
   : GOTO 230
0461 GOSUB '204("Required files missing on installation disk - Cannot proceed"
     )
   : GOTO 230
0462 GOSUB '204("Too many '@MVPold#' files on target disk - Cannot proceed")
   : GOTO 230
0463 GOSUB '204("Target disk cannot equal source disk - Cannot proceed")
   : GOTO 230
0530 PRINT AT(4,1);HEX(0E);"A new @GENPART is on the source disk for 1 megabyt
     e or larger memory modules";
0531 PRINT AT(5,1);HEX(0E);"A new HELP file is also available on the source di
     sk";
0549 PRINT AT(17,1,79);HEX(0F);"The installation has been successfully complet
     ed."
   : PRINT AT(18,1,79);"You must exit and reboot to use";HEX(0E);" SDS-Extende
     d BASIC-2";HEX(0F)
   : PRINT
0550 STOP
   : GOTO 550
1040 DEFFN'200
   : SELECT PRINT 005(80)
   : PRINT HEX(0306)
   : R,C=7
   : X=10
   : Y=46-X
1050 Z1$(1),Z1$(4),Z1$(5)=ALL(FC)
   : Z1$(2),Z1$(6)=ALL(FF)
1060 STR(Z1$(3),1,20)=HEX(C0C0C0C0C0C0C0C0C0C0C0FFD5C0C0C0C0C0C0C0)
1070 STR(Z1$(4),1,20)=HEX(E8FCFCFCFCFCE8FCFCFCD4FFD5FCFCFCFCFCFCE8)
1080 STR(Z1$(5),1,20)=HEX(EAFFFCFCFCFCEAFFE8FCD4FFD5FFFDFCFCFCFCE8)
1090 STR(Z1$(6),1,20)=HEX(E8FCFCFCFEFFEAFFFCFCFCFFD5FCFCFCFCFEFFEA)
1100 PRINT HEX(0202020E);
1110 PRINT AT(R,C+X);STR(Z1$(3),1,20);AT(R+1,C);STR(Z1$(1),1,X);STR(Z1$(4),1,2
     0+Y);AT(R+2,C);STR(Z1$(2),1,X);STR(Z1$(5),1,20+Y);AT(R+3,C);STR(Z1$(1),1,
     X);STR(Z1$(6),1,20+Y);
1120 PRINT AT(R+4,C+34);"southern data systems, inc.";HEX(0202000F);
   : RETURN
1150 DEFFN'203(J1$)
   : E=0
   : IF 3<>LEN(J1$)THEN 1180
   : M$=J1$
   : IF M$="D"OR M$="B"OR M$="3"THEN 1160
   : IF J1$="ED0"THEN 1160
   : GOSUB '204("Illegal device entry - Is not a D,B,3 prefix or 'ED0'")
   : RETURN
1160 SELECT #Q7<J1$>
   : DATA LOAD BA T#Q7,(0)B1$()
   : ERRORY=ERR
   : IF Y=48THEN 1190
   : PRINT AT(22,1,79);"Error";Y;"has occurred - correct and retry";
   : E=1
1170 RETURN
1180 GOSUB '204("Invalid length - must be at least 3 Characters")
   : RETURN
1190 GOSUB '204("Address selected not in device table or not valid")
   : RETURN
1200 DEFFN'204(X9$)
   : PRINT AT(21,1,79);X9$;
   : E=1
   : PRINT AT(22,1,79);"Touch any key to continue ";HEX(8B08020404000F);
   : KEYIN Z$
   : RETURN