Listing of file='CROSSRF0' on disk='vmedia/tbo_81.wvd.zip'
# Sector 185, program filename = 'CROSSRF0'
0010 REM 1/22/79 CROSSRF0 (PART 2 OF 2) T.OLSEN 2200R&D LIST (MEANINGS) & XREF
: GOTO 1630
0030 AND (B$,7F)
: C$=C$(VAL(B$)+1)
0040 Z=LEN(C$)
: C=C+Z
: IF C<M9THEN 50
: PRINT
: PRINT TAB(M+6);
: C=M+Z+6
: L=L+1
0050 PRINT C$;
0060 RETURN
0070 PRINT C$;
0080 J=J+1
: C$=B$(J)
: IF C$=T$THEN 60
: C=C+1
: IF C<M9THEN 70
: PRINT
: PRINT TAB(M+6);
: C=M+7
: L=L+1
: GOTO 70
0090 FOR Z=1TO 4
0100 IF B$(G)<>" "THEN 110
: G=G+1
: GOTO 100
0110 N$(Z),STR(Q$,Z)=B$(G)
: G=G+1
: NEXT Z
: RETURN
: REM %TEXT LOOP
: REM ....NF,COLON,CR,QUOTE,/,#,#,STMT,GOSUB,REM,HEX
0120 B$=B$(J)
: MAT SEARCHI$()<1,36>,=B$TO M$()
: ON VAL(STR(M$(1),2))+1GOTO 150,560,630,760,762,3020,3015,370,420,440,490
: IF W>0THEN 160
0130 C$=B$
: GOSUB 40
0140 J=J+1
: IF B$(J)<>")"THEN 120
: IF W<>-3THEN 120
: W=1
: GOTO 120
0150 IF B$<HEX(80)THEN 130
: IF V$=HEX(A5)THEN 480
0155 GOSUB 30
: ON Z GOTO 140
: IF STR(C$,Z,1)="("THEN 140
: PRINT " ";
: C=C+1
: GOTO 140
: REM %VARIABLE?
: REM ..$,MAT,DATA
: REM .F,R,T,E,C
0160 G=J
: GOSUB 90
: ON VAL(V2$)-7GOTO 830,770,1002
0170 ON VAL(STR(M$(1),2))-10GOTO 960,965,970,990,962
0180 IF B$(V)<>HEX(A4)THEN 190
: IF N$(2)=">"THEN 130
0190 Z=2
: R$=HEX(00)
: IF N$(2)<"0"THEN 200
: IF N$(2)>"9"THEN 200
: R$=N$(2)
: ROTATE(R$,4)
: ADD(R$,0D)
: Z=3
0200 IF N$(Z)="$"THEN 208
: ON VAL(V2$)+1GOTO 210,472,472
: FOR G=2 TO 3
: IF N$(G)=")"THEN 474
: NEXT G
: GOTO 210
0208 OR (R$,0C)
: Z=Z+1
0210 IF N$(Z)<>"("THEN 220
: OR (R$,02)
: Z=Z+1
0220 C$=B$
: G=Z-1
: IF Z=2THEN 230
: T$=N$(Z-1)
: GOSUB 70
: C=C+1
0230 GOSUB 40
: GOSUB 235
: GOTO 140
0235 ON Q1GOSUB 320,320
: Q$=B$
: STR(Q$,2)=R$
: IF U=0THEN 240
: MAT SEARCHU$()<1,2*U>,=STR(Q$,1,2)TO M$()STEP 2
: Z=VAL(STR(M$(1),2))
: IF Z<>0THEN 60
0240 U=U+1
: U$(U)=Q$
: IF Q=0THEN 310
0250 MAT SEARCHQ$()<1,Q*4>,=STR(Q$,1,2)TO M$()STEP 4
: Z=256*VAL(M$(1))+VAL(STR(M$(1),2))
: IF Z=0THEN 310
: Z=INT(Z/4)+1
: ADD(STR(Q$(1,Z),3,1),01)
: IF STR(Q$(1,Z),4)=HEX(13)THEN 270
0260 ADD(STR(Q$(1,Z),4),02)
: STR(X$(Z),VAL(STR(Q$(1,Z),4)),2)=STR(L$,1,2)
: RETURN
0270 IF X>X9THEN 1490
: X=X+1
: STR(X0$(X),1,21)=STR(X$(Z),1,21)
: G=VAL(STR(X$(Z),21))
: IF G<>0THEN 290
: G=X
0280 INIT(FF)X$(Z)
: BIN(STR(X$(Z),21))=G
: STR(Q$(1,Z),4)=HEX(FF)
: GOTO 260
0290 H=VAL(STR(X0$(G),21))
: IF H=0THEN 300
: G=VAL(STR(X0$(H),21))
: IF G<>0THEN 290
: G=H
0300 BIN(STR(X0$(G),21))=X
: STR(X0$(X),21)=HEX(00)
: G=VAL(STR(X$(Z),21))
: GOTO 280
0310 STR(Q$,3,2)=HEX(0101)
: IF Q=Q9THEN 1490
: Q=Q+1
: Q$(1,Q)=Q$
: INIT(FF)X$(Q)
: STR(X$(Q),1,2)=L$
: STR(X$(Q),21)=HEX(00)
: RETURN
: REM \D8FIND MEANING
0315 G=NUM(STR(Q$,2,3))+1
0320 IF G=4THEN 330
: Z=G+1
: IF N$(G)<>"("THEN 325
: STR(Q$,Z)=N$(Z)
: MAT SEARCHD$()<1,D7>,=STR(Q$,1,4)TO M$()STEP 20
: IF M$(1)>HEX(0000)THEN 335
0325 STR(Q$,Z)=" "
0330 MAT SEARCHD$()<1,D7>,=STR(Q$,1,4)TO M$()STEP 20
: IF M$(1)=HEX(0000)THEN 60
0335 Z=INT(256*VAL(M$(1))+VAL(STR(M$(1),2))/20)+1
: C$=STR(D$(Z),5)
: IF C$=" "THEN 60
0340 ON Q1 GOTO 350
: IF LEN(C$)+R1<37THEN 342
: IF R>3THEN 60
: R=R+1
: R1=1
0342 STR(R$(R),R1)=HEX(5B)
: STR(R$(R),R1+1)=C$
: R1=R1+3+LEN(C$)
: STR(R$(R),R1-2)=HEX(5D)
: RETURN
0350 IF C+LEN(C$)<74THEN 360
: PRINT
: PRINT TAB(M+6);
: C=M+7
: L=L+1
0360 C=C+LEN(C$)+2
: PRINT HEX(5F);C$;HEX(5F);
: RETURN
: REM \D8PROCESS ATOM
: REM FF=LINE #
0370 UNPACK(##)B$(J+1)TO G
: UNPACK(##)B$(J+2)TO H
: CONVERT H+G*100TO Q$,(####)
: Z=POS(Q$<>"0")
: IF Z>0THEN 380
: Q$="0"
: Z=1
0380 C$=STR(Q$,Z)
: GOSUB 40
: Q$=B$(J+1)
: STR(Q$,2)=B$(J+2)
: Z=0
0390 Z=Z+1
: IF Z>UTHEN 400
: IF U$(Z)<>Q$THEN 390
: J=J+3
: GOTO 120
0400 U$(Z)=Q$
: U=Z
: STR(Q$,3)=L$
: T=T+1
: IF T<256THEN 410
: T1=T1+1
: T=1
: IF T1>T9THEN 1490
0410 T$(T1,T)=Q$
: J=J+3
: GOTO 120
0420 G=J+1
: GOSUB 90
: IF N$(1)<>"'"THEN 155
: CONVERT STR(Q$,2,NUM(STR(Q$,2,3)))TO H
: PRINT "GOSUB";
: C=C+5
: ON Q1GOSUB 315,315
0430 PACK(####)Q$FROMH
: OR (STR(Q$,1,1),F0)
: J=J-2
: Z=0
: GOTO 390
0440 IF B$(J+1)="%"THEN 890
: IF B$(J+1)=HEX(D8)THEN 890
0450 B$=B$(J)
: GOSUB 30
0460 PRINT " ";
: C=C+1
0470 J=J+1
: B$=B$(J)
: IF B$>HEX(7F)THEN 450
: IF B$=HEX(0D)THEN 600
: IF B$=":"THEN 560
: C$=B$
: GOSUB 40
: GOTO 470
0472 IF B$(J-1)="("THEN 130
: IF B$(J-2)="("THEN 130
: GOTO 210
0474 C$=N$(G+1)
: G=3
: NEXT G
: IF C$=":"THEN 130
: IF C$=HEX(0D)THEN 130
: GOTO 210
0480 W=-2
: GOTO 155
0490 W=-3
: GOTO 155
: REM %PRINT COMMENT
0510 R=1
: IF R$(R)=" "THEN 540
: PRINT " ";
: C=C+2
: IF C<M3THEN 530
: IF C+LEN(R$(R))<M9THEN 530
0520 PRINT " "
: GOSUB 1030
0530 PRINT TAB(M3);R$(R);
: IF R=4THEN 540
: R=R+1
: IF R$(R)<>" "THEN 520
0540 INIT(" ")R$()
: R,R1=1
: RETURN
: REM %END OF STATEMENT
0560 J=J+1
: M=M1
: IF B$(J)<>HEX(A2)THEN 570
: IF B$(J+1)<>"/"THEN 570
: J=J+1
: M=M+M2
: PRINT TAB(M-1);
: IF C>MTHEN 460
: C=M
: GOTO 460
0570 GOSUB 510
: GOSUB 1010
: IF V$=HEX(D8)THEN 900
: J=J-1
: C=M+5+I
: PRINT TAB(C);
: S1=S1+1
: IF V1$=HEX(9F)THEN 580
: IF V1$<>HEX(9E)THEN 590
0580 IF V$=HEX(9F)THEN 590
: I=I+3
: PRINT " ";
0590 V1$=V$
: GOTO 130
0600 M=M1
0630 GOSUB 510
: IF V2$<HEX(0C)THEN 650
: GOSUB 1020
0650 J=J+4
: IF J>256THEN 660
: IF B$(J-1)=HEX(FF)THEN 690
0660 B=B+J-3
: IF H$=HEX(20)THEN 1480
0670 GOSUB 1090
0680 J=3
: IF B$(1)<>HEX(20)THEN 690
: IF B$(2)=HEX(FE)THEN 1480
0690 L$=B$(J)
: STR(L$,2)=B$(J+1)
: J=J+2
0700 U=0
: IF P5=0THEN 730
: SELECT PRINT 005
: PRINT HEX(0C);"ON LINE=";
: HEXPRINT L$;
: PRINT " VARS=";Q;"REFS>10=";X;"S.F.'S=";F;"LINE REFS=";T
0710 GOSUB 1060
: IF S2=0THEN 730
: UNPACK(####)STR(L$,1,2)TO I
: IF I>=S2THEN 725
0720 IF B$(J)=HEX(0D)THEN 650
: J=J+1
: GOTO 720
0725 IF I>S3THEN 720
0730 I=J
: GOSUB 1010
: V1$=V$
: I=J-I
: IF I=0THEN 740
: I=I-1
0740 S=S+1
: C=M+6+I
: PRINT TAB(M);
: HEXPRINT L$;
: IF V$=HEX(D8)THEN 880
: PRINT TAB(C);
: IF V$<>HEX(CE)THEN 120
: IF F>F9THEN 1490
: F=F+1
0750 F$(F,1)=HEX(FF)
: STR(F$(F,1),2)=L$
: G=J+1
: GOSUB 90
: IF N$(1)<>"'"THEN 120
: Z=NUM(STR(Q$,2,3))
: CONVERT STR(Q$,2,Z)TO Z
: BIN(STR(F$(F,1),1))=Z
: ON Q1GOSUB 315,315
: GOTO 120
0760 C=C+1
: PRINT HEX(22);
: T$=HEX(22)
0761 GOSUB 80
: GOSUB 40
: GOTO 140
0762 G=J
: GOSUB 90
: FOR Z=2 TO 4
: R$=N$(Z)
: IF R$<"0"THEN 768
: IF R$>"F"THEN 768
: IF R$<"9"THEN 764
: IF R$<"A"THEN 768
0764 NEXT Z
: C$=Q$
: J=G
: GOSUB 40
: GOTO 120
0768 Z=4
: NEXT Z
: GOTO 130
0770 Z=1
: G=J
: S$="ZER/CON/TRN/INV/IDN/MERGE/SORT/SEARCH//"
0780 H=G
0790 IF B$(H)=" "THEN 800
: IF B$(H)<>STR(S$,Z,1)THEN 810
: Z=Z+1
: IF STR(S$,Z,1)="/"THEN 820
0800 H=H+1
: GOTO 790
0810 Z=Z+1
: IF STR(S$,Z,1)<>"/"THEN 810
: Z=Z+1
: IF STR(S$,Z,1)<>"/"THEN 780
: GOTO 170
0820 FOR Z=GTO H
: PRINT B$(Z);
: NEXT Z
: C=C+H-G
: J=H+1
: GOTO 120
0830 IF STR(Q$,2,1)="="THEN 130
: IF Q$<>"TRAN"THEN 840
: GOSUB 860
: GOTO 140
0840 IF STR(Q$,1,3)<>"GIO"THEN 170
: GOSUB 860
: Z=J
0845 Z=Z-1
: IF B$(Z)=" "THEN 845
: IF B$(Z-1)="#"THEN 3030
: Z=J
0850 Z=Z+1
: IF B$(Z)="$"THEN 140
: IF B$(Z)=")"THEN 855
: IF B$(Z)<>","THEN 850
0855 T$=B$(Z)
: GOTO 761
0860 T$="("
: J=J-1
: GOSUB 80
: GOSUB 40
: RETURN
0880 PRINT " %";
: T$=HEX(0D)
: GOSUB 80
: GOTO 630
0890 J=J+1
0900 J=J+1
: C$=B$(J)
: IF C$<"0"THEN 910
: IF C$>"9"THEN 910
: IF C$="0"THEN 1680
: FOR Z=1TO VAL(C$)-48
: GOSUB 1020
: NEXT Z
: GOTO 920
0910 IF C$<>"^"THEN 930
: GOSUB 1040
0920 J=J+1
0930 PRINT " "
: PRINT HEX(0E);TAB(M/2);
: L=L+2
: C=M
0940 C$=B$(J)
: IF C$=HEX(0D)THEN 950
: IF C$=":"THEN 950
: GOSUB 40
: J=J+1
: GOTO 940
0950 PRINT
: GOTO 120
0960 IF Q$<>"FROM"THEN 970
: PRINT " FROM ";
: J=G
: GOTO 120
0962 IF B$(J-1)=HEX(E8)THEN 130
: IF B$(J-1)=HEX(EF)THEN 130
: GOTO 180
0965 IF V$<>HEX(EA)THEN 970
: IF B$(J-1)=")"THEN 130
0970 G=J
: ON VAL(V2$)-9GOTO 980,980,980
: GOTO 180
: REM .86,97,A1
0980 G=G-1
: IF B$(G)=" "THEN 980
: R$=B$(G)
: IF R$<HEX(86)THEN 180
: IF R$>HEX(BF)THEN 180
: IF R$=HEX(86)THEN 130
: IF R$<HEX(B4)THEN 180
: GOTO 130
0990 IF Q$<>"ERRO"THEN 1000
: PRINT "ERROR";
: J=G+1
: GOTO 120
1000 R$=B$(J-1)
: IF R$="."THEN 130
: IF R$>"9"THEN 180
: IF R$<"0"THEN 180
: IF B$(J-3)=HEX(FF)THEN 180
: GOTO 130
1002 IF N$(2)="="THEN 130
: GOTO 170
1005 J=J+1
1010 IF B$(J)=" "THEN 1005
: W=1
: V=J
1020 V$=B$(J)
: PRINT " "
: MAT SEARCHI$()<37,16>,=V$TO M$()
: V2$=STR(M$(1),2)
1030 L=L+1
: IF L<L9THEN 60
1040 L=4
: PRINT " "
: P=P+1
: E=-E
: IF P>1THEN 1050
: IF E<1THEN 1050
: PRINT HEX(0C)
: E=-E
1050 PRINT HEX(0C0E);TAB(M/2);P$," PAGE=";P
: PRINT TAB(M);D$;" ";E$
: PRINT " "
: RETURN
1060 IF P5<>0THEN 1070
: SELECT PRINT 005(64)
: RETURN
1070 SELECT PRINT 215(125)
: RETURN
1080 GOSUB 1060
: R,R1,T1=1
: B,F,H,T,Q,S,S1,X=0
: INIT(" ")R$()
: INIT(FF)T$(),Q$(),X$(),F$()
: GOSUB 1040
: RETURN
1090 IF D=0THEN 1100
: DATA LOAD BA T#2,(A,A)A$()
: GOTO 1110
1100 DATA LOAD BTA$()
1110 MAT COPY A$()TO B$()
: H$,B$=B$(1)
: AND (H$,20)
: AND (B$,90)
: IF B$=HEX(00)THEN 60
: STOP "PROTECTED PROGRAM"
: REM \D8SUMMARY
1120 GOSUB 1060
1130 DEFFN'11
: IF Q=0THEN 1345
1135 GOSUB 1440
: INIT(00)Q$
: W=10
: J,L=8
1140 T=255*T1+T-255
: PRINT TAB(M);"NUMBERED LINES=";S;" TOTAL STMTS=";S+S1;" FUNCTIONS=";F;" T
EXT AREA=";B
: PRINT TAB(M);"VARIABLES=";Q;" LINE REFERENCES=";T
1155 PRINT " "
: PRINT HEX(0E);TAB(M/2);"VARIABLES"
: IF Q>0THEN 1160
: PRINT TAB(M);"NONE"
: GOTO 1280
1160 MAT SORTQ$()TO T1$(),T2$()
: FOR J=1TO Q
: U=VAL(STR(T2$(1,J),2,1))
: B$,Q$=Q$(1,U)
: GOSUB 1420
: IF VAL(STR(Q$,3))/12+L<L9THEN 1170
: GOSUB 1440
1170 PRINT TAB(M);B$;
: V$=STR(Q$,2)
: IF B$="#"THEN 3010
1180 B$=V$
: STR(Q$,2)=" "
: Z=2
: AND (B$,F0)
: IF B$=HEX(00)THEN 1190
: ROTATE(B$,4)
: ADD(B$,2F)
: PRINT B$;
: STR(Q$,Z)=B$
: Z=3
1190 AND (V$,0F)
: IF V$<=HEX(03)THEN 1200
: PRINT "$";
: STR(Q$,Z)="$"
: Z=Z+1
1200 AND (V$,03)
: IF V$=HEX(00)THEN 1210
: PRINT "()";
: STR(Q$,Z)="("
1210 MAT SEARCHD$()<1,D7>,=STR(Q$,1,4)TO M$()STEP 20
: IF M$(1)=HEX(0000)THEN 1215
: Z=256*VAL(M$(1))+VAL(STR(M$(1),2))
: Z=INT(Z/20)+1
: PRINT TAB(M+6);STR(D$(Z),5)
: L=L+1
1215 H=VAL(STR(X$(U),21))
: Z=1
1220 IF H=0THEN 1270
: C$=X0$(H)
: GOSUB 1230
: H=VAL(STR(C$,21))
: GOTO 1220
1230 G=1
: PRINT TAB(M+6);"--";
1240 Z=Z+1
: HEXPRINT STR(C$,G,2);
: IF Z>VAL(STR(Q$(1,U),3))THEN 60
: G=G+2
: IF G>20THEN 1250
: PRINT ", ";
: GOTO 1240
1250 GOSUB 1410
: RETURN
1270 C$=X$(U)
: GOSUB 1230
: NEXT J
1280 GOSUB 1460
: PRINT "SPECIAL FUNCTIONS"
: PRINT TAB(M);
: IF F<>0THEN 1290
: PRINT "NONE"
: GOTO 1330
1290 MAT SORTF$()TO T1$(),T2$()
: FOR J=1TO F
: C$=" "
: U=VAL(T2$(1,J))
: B$=F$(U,1)
: IF B$<>HEX(FF)THEN 1300
: Q$="USER"
: GOTO 1305
1300 CONVERT VAL(B$)TO Q$,(####)
: G=POS(Q$>"0")
: IF G>0THEN 1302
: G=4
1302 STR(Q$,2,3)=STR(Q$,G)
: STR(Q$,1,1)="'"
1305 PRINT Q$;" AT ";
: HEXPRINT STR(F$(U,1),2,2);
: GOSUB 315
: ON Q1GOTO 1310
: IF C$=" "THEN 1310
: PRINT "--";C$;
1310 IF F=JTHEN 1320
: PRINT ",";
1315 PRINT TAB(M+35);
: IF J/2<>INT(J/2)THEN 1320
: GOSUB 1420
: PRINT TAB(M);
1320 NEXT J
1330 GOSUB 1460
: PRINT "STATEMENT NUMBERS"
: IF T>0THEN 1350
: PRINT TAB(M);"NONE"
1340 IF D6=1THEN 1345
: D7,D8=0
1345 PRINT
: PRINT TAB(M);HEX(0E);"END OF LIST ";P$
: RETURN
1350 MAT SORTT$() TO T1$(),T2$()
: G,H=1
1360 C$=T$(VAL(T2$(G,H)),VAL(STR(T2$(G,H),2,1)))
: IF STR(C$,1,1)=HEX(FF)THEN 1340
: IF STR(Q$,1,2)=STR(C$,1,2)THEN 1390
: Q$=C$
: GOSUB 1420
: PRINT TAB(M);
: HEXPRINT STR(Q$,1,2);
1370 PRINT TAB(M+6);"--";
: Z=1
1380 HEXPRINT STR(C$,3,2);
: H=H+1
: IF H<256THEN 1360
: G=G+1
: H=1
: IF G>T9THEN 1340
: GOTO 1360
1390 Z=Z+1
: IF Z<=WTHEN 1400
: GOSUB 1410
: GOTO 1370
1400 PRINT ", ";
: GOTO 1380
1410 PRINT ","
: GOTO 1430
1420 PRINT " "
1430 L=L+1
: IF L<L9THEN 60
1440 P=P+1
: PRINT " "
: L=4
: PRINT HEX(0C0E);TAB(M/2);P$;" CROSS-REFS";" PAGE=";P
: PRINT TAB(M);D$;" ";E$
: PRINT " "
: E=-E
: RETURN
1460 PRINT
: PRINT " "
: L=L+4
: GOSUB 1430
: PRINT HEX(0E);TAB(M/2);
: IF L>3THEN 60
: L=4
: RETURN
1480 DEFFN'10
: GOSUB 1120
: PRINT HEX(07)
1485 P6=P6+1
: IF P6<=P7THEN 1488
: PRINT HEX(0C)
: FOR Z=1 TO 50
: PRINT HEX(0A);
: NEXT Z
: PRINT " "
: SELECT PRINT 005(64)
: STOP "END OF JOB"
1486 DEFFN'12
: INPUT "RESTART AT PROGRAM ",P6
1488 IF STR(P$(P6),1,8)<>" "THEN 1630
: D7,D8=0
: GOTO 1485
1490 SELECT PRINT 215(79)
: PRINT
: PRINT HEX(0E);"PARTIAL CROSS-REF FOLLOWS"
: GOSUB 1120
: GOSUB 1080
: GOTO 680
: REM %1SET-UP
1630 SELECT PRINT 005(64)
: IF D=0THEN 1640
: P$=P$(P6)
: ON VAL(STR(P$(P6),9))GOSUB 3001,3002,3003,3004,3005,3006,3007
: LIMITS T#2,P$,A,Q,P
: E$=E$(P6)
1640 GOSUB 1090
: J=1
: INIT(20)P$
1650 B$=B$(J+1)
: IF B$=HEX(FF)THEN 1660
: STR(P$,J,1)=B$
: J=J+1
: IF J<9THEN 1650
1660 P=0
: PRINT P6;" OF ";P7,"DEV.=";D,P$
: PRINT
: GOSUB 1080
: GOTO 670
: REM %REM%0
1680 G=J
: PRINT "REM%0";
1690 Z,H=1
: Q$,C$=" "
1700 G=G+1
: R$=B$(G)
: IF R$=" "THEN 1710
: IF R$=":"THEN 910
: IF R$=HEX(0D)THEN 910
: IF G>255THEN 910
: IF Z>1THEN 1705
1702 IF R$="'"THEN 1705
: IF R$="#"THEN 1705
: IF R$="/"THEN 1705
: IF R$<"A"THEN 1700
: IF R$>"Z"THEN 1700
1705 STR(Q$,Z)=R$
: Z=Z+1
: IF Z<5THEN 1700
1710 IF Q$=" "THEN 1700
1720 G=G+1
: IF B$(G)=" "THEN 1720
: G=G-1
1730 G=G+1
: R$=B$(G)
: IF R$=":"THEN 1740
: IF R$=","THEN 1740
: IF R$=HEX(0D)THEN 1740
: STR(C$,H)=R$
: H=H+1
: IF G>255THEN 910
: IF H<16THEN 1730
: H=16
: GOTO 1730
1740 MAT SEARCHD$()<1,D7>,=STR(Q$,1,4)TO M$()STEP 20
: IF M$(1)=HEX(0000)THEN 1750
: Z=256*VAL(M$(1))+VAL(STR(M$(1),2))
: Z=INT(Z/20)+1
: GOTO 1770
1750 IF D8<D9THEN 1760
: Z,D8=D8-1
1760 Z,D8=D8+1
: D7=D8*20
1770 D$(Z)=Q$
: STR(D$(Z),5)=C$
: PRINT TAB(M+28);STR(Q$,1,4);" = ";C$
: GOSUB 1030
: IF R$=","THEN 1690
: J=G-1
: GOTO 470
2045 DEFFN'15
: PRINT "CROSSRF0 -- S.F. ENTRIES"
2050 PRINT "'0 AFTER MEANING ENTRY","'1 IN DISK FILE NAMES"
: PRINT "'10 SUMMARY TO PRINTER/CONTINUE","'11 SUMMARY ONLY"
: PRINT "'12 PICKUP LIST WITH PROGRAM #",
2055 PRINT "'15 S.F. ACTION"
: RETURN
3001 SELECT #2310
: RETURN
3002 SELECT #2B10
: RETURN
3003 SELECT #2320
: RETURN
3004 SELECT #2B20
: RETURN
3005 SELECT #2330
: RETURN
3006 SELECT #2B30
: RETURN
3007 SELECT #2350
: RETURN
3010 PRINT V$;
: STR(Q$,3)=" "
: GOTO 1210
3015 B$(J)="#"
3020 IF V$=HEX(95)THEN 130
: G=J
: GOSUB 90
: IF Q$<"#0"THEN 130
: C$,B$="#"
: G=2
: R$=N$(2)
: GOTO 230
3030 G=Z-1
: GOSUB 90
: C$,B$="#"
: G=2
: R$=N$(2)
: GOSUB 235
: Z=J
: GOTO 850
3040 DEFFN'0
: LOAD DC T"START"