image of READY prompt

Wang2200.org

Listing of file='ROMANS' on disk='vmedia/tbo_81.wvd.zip'

# Sector 750, program filename = 'ROMANS'
0010 REM ROMAN NUMERALS
   : GOTO 250
0020 DIM L$(8)1,V(8)
0030 REM %.35 SHOW ROMAN NUMERAL FOR DECIMAL
0040 DEFFN'35(V)
   : PRINT V,
0050 V=INT(V)
   : IF V>0THEN 60
   : PRINT "We had trouble with zero and negatives"
   : RETURN
0060 FOR A=7TO 1 STEP -1
0070 IF V<V(A)THEN 92
   : REM WAS TO 100
0080 PRINT L$(A);
0090 V=V-V(A)
   : GOTO 70
0091 REM .LOGIC CHECK FOR IX OR IV ETC.  (4 IN A ROW)
0092 IF A=1 THEN 100
   : C=0
0094 C=C+1
   : IF C=ATHEN 100
   : IF V<V(A)-V(C)THEN 94
0096 PRINT L$(C);L$(A);
   : V=V-V(A)+V(C)
0100 NEXT A
0110 PRINT
   : RETURN
0120 REM %.ENTER NUMBER IN DECIMAL
0130 PRINT "key positive integers only"
0140 INPUT "VALUE X",X
   : X=INT(X)
   : IF X<1THEN 130
0150 INPUT "VALUE Y",Y
   : Y=INT(Y)
   : IF Y<1THEN 130
0160 GOSUB '35(X)
   : GOSUB '35(Y)
   : PRINT ,"-------"
   : RETURN
0170 REM %. '0 GIVE ROMAN FOR DECIMAL
0180 DEFFN'0
   : INPUT "VALUE",V
   : GOSUB '35(V)
   : GOTO 180
0190 REM %. '1 ADDITION
0200 DEFFN'1
   : PRINT "ADD VALUES"
   : GOSUB 130
   : GOSUB '35(X+Y)
   : RETURN
0210 DEFFN'2
   : PRINT "SUBTRACT VALUES"
   : GOSUB 130
   : GOSUB '35(X-Y)
   : RETURN
0220 DEFFN'3
   : PRINT "MULTIPLY VALUES"
   : GOSUB 130
   : GOSUB '35(X*Y)
   : RETURN
0230 DEFFN'4
   : PRINT "DIVIDE VALUES"
   : GOSUB 130
   : GOSUB '35(X/Y)
   : RETURN
0240 REM %.SETUP
0250 L$(1)="I"
   : V(1)=1
   : L$(2)="V"
   : V(2)=5
0260 L$(3)="X"
   : V(3)=10
   : L$(4)="L"
   : V(4)=50
0270 L$(5)="C"
   : V(5)=100
   : L$(6)="D"
   : V(6)=500
0280 L$(7)="M"
   : V(7)=1000
0290 PRINT HEX(03);"ROMAN NUMERAL PLAYGROUND"
0300 PRINT "'0 TO SHOW A NUMERAL"
0310 PRINT "'1 FOR ADDITION"
0320 PRINT "'2 FOR SUBTRACTION"
0330 PRINT "'3 FOR MULTIPLICATION"
0340 PRINT "'4 FOR DIVISION"
0350 STOP "KEY DESIRED FUNCTION"