image of READY prompt

Wang2200.org

Listing of file='TBO.CINT' on disk='vmedia/toolbox.wvd.zip'

# Sector 1175, program filename = 'TBO.CINT'
0010 REM TBO.CINT INTEREST CALCULATION 7/24/86
0020 SELECT LIST 005(80),PRINT 005(80)
0030 PRINT HEX(0D0C030E);"Interest calculation"
0040 REM Y=YEARS  Y1=START  Y2=END Y0=INCREMENT
0050 Y1=5
   : Y2=20
   : Y0=5
0051 P1=5
   : P2=15
   : P0=1
   : S9=12
   : S8=.25
0060 DEFFN'10
   : SELECT LIST 005(80),PRINT 005(80)
0070 PRINT "Min years =",Y1,
   : INPUT " or",Y1
0080 PRINT "Max years =",Y2,
   : INPUT " or",Y2
0090 IF Y2=Y1THEN 100
   : PRINT "Years step =",Y0,
   : INPUT " or",Y0
0100 REM %0  P Principal, P1 Low amount, P2 Hi amount, P0 Amount increment
0101 PRINT "Enter amounts in thousands"
0102 PRINT "Low principal =",S1,
   : INPUT " or",S1
0104 PRINT "Hi  principal =",S2,
   : INPUT " or",S2
0106 IF S1=S2THEN 110
   : PRINT "Amount step=",S0,
   : INPUT " or",S0
0110 PRINT "Low % rate =",S9,
   : INPUT " or",S9
   : R1=S9/100
0115 PRINT "Interest step =",S8,
   : INPUT " or",S8
   : R0=S8/100
0120 REM %0  R1 Low interest rate, R2 Hi interest rate, R0 Interest increment
0125 P1=S1*1000
   : P2=S2*1000
   : P0=S0*1000
0130 R2=R1+9*R0
0135 H=0
   : INPUT "For hard copy Key 1 (RETURN)",H
   : IF H=0THEN 140
   : SELECT PRINT 215(132)
0138 PRINT HEX(0D0C030E);"Interest calculation"
0140 GOSUB 250
0150 % $###,###  ##.###%
0160 % ###  $####.##
0170 FOR P=P1 TO P2 STEP P0
0180 FOR R=R1 TO R2 STEP R0
0190 PRINTUSING 150,P,R*100;
0200 FOR Y=Y1TO Y2 STEP Y0
0210 I=R/12
   : N=Y*12
   : M=P*I/(1-(1+I)^(-N))
0220 PRINTUSING 160,Y,INT(100*M)/100;
0230 NEXT Y
   : PRINT
   : NEXT R
0232 KEYIN C$,233,233
   : GOTO 236
0233 GOSUB 250
   : PRINT "Pause";HEX(0D);
0234 KEYIN C$,235,235
   : GOTO 234
0235 PRINT ,,
0236 B=B+1
   : IF B<8THEN 238
   : B=0
   : IF H<>1THEN 238
0237 PRINT HEX(0D0C030E);"Interest calculation"
   : GOSUB 250
0238 PRINT
   : NEXT P
0240 GOSUB 250
   : END
0250 PRINT "  Loan     Rate  ";
0260 FOR Y=Y1TO Y2 STEP Y0
   : PRINTUSING 160,"#Yr","Pay";
   : NEXT Y
   : PRINT
0270 RETURN