image of READY prompt

Wang2200.org

Listing of file='TBO.FNAM' on disk='vmedia/toolbox.wvd.zip'

# Sector 1030, program filename = 'TBO.FNAM'
0010 REM %.TBO.FNAM 04/11/91  TBO Find names in index
0020 PRINT HEX(03);AT(0,25);HEX(0E);"Find names in index"
0025 PRINT "Key specific file name, display will show drives with occurence"
   : PRINT " or ID and * wild card  will show number of occurences."
0030 COM B$(16)16,D$(28)4,I$(28)8,C$1,K$1
   : D$=SELECT #0
   : K$=STR(D$,2,1)
   : AND (K$,37)
   : ON POS("123"=K$)GOSUB 32,34,36
   : PRINT "Addr Index  Cur.End .. Looking at cabinet ";D$
   : GOTO 40
0032 D$()="D11 D12 D13 D14 D15 D16 D17 D18 D19 D1A D1B D1C D1D D1E D51 D52 D53
      D54 D55 D56 D57 D58 D59 D5A D5B D5C D5D D5E"
   : RETURN
0034 D$()="D21 D22 D23 D24 D25 D26 D27 D28 D29 D2A D2B D2C D2D D2E D61 D62 D63
      D64 D65 D66 D67 D68 D69 D6A D6B D6C D6D D6E"
   : RETURN
0036 D$()="D31 D32 D33 D34 D35 D36 D37 D38 D39 D3A D3B D3C D3D D3E D71 D72 D73
      D74 D75 D76 D77 D78 D79 D7A D7B D7C D7D D7E"
   : RETURN
0040 DIM N$8
0050 REM %.Get index data
0060 FOR D=1TO 28
0070 D$=D$(D)
   : IF D$=" "THEN 100
0080 SELECT #1<D$>
   : DATA LOAD BA T#1,(0)B$()
   : ERRORINIT(00)B$()
   : D$(D)=" "
0090 C$,I$,I$(D)=B$()
   : IF I$>HEX(0000000000000000)THEN DO
   : C$=C$AND HEX(03)
   : K$=" "
   : IF C$=HEX(01)THEN K$="'"
   : IF C$=HEX(02)THEN K$="&"
   : PRINTUSING "### #### # #######  ",D$;VAL(STR(I$,2));K$;VAL(STR(I$,4),2);
   : END DO
0100 NEXT D
0110 PRINT
   : PRINT "Will search",STR(D$(),,56)
   : PRINT ,STR(D$(),57,56)
0120 LINPUT "Name "-N$
   : N=LEN(N$)
   : K$=STR(N$,N,1)
   : IF K$="*"THEN N=N-1
   : IF N=0THEN N=1
   : IF K$<>"*"THEN N=8
0130 FOR D=1TO 28
0140 I$=I$(D)
   : IF I$=HEX(0000000000000000)OR I$=" "THEN 220
   : D$=D$(D)
   : SELECT #1<D$>
0150 C=0
0160 FOR I=0TO VAL(STR(I$,2))
0170 DATA LOAD BA T#1,(I)B$()
0180 FOR X=1TO 16
   : IF STR(B$(X),9,N)<>STR(N$,,N)THEN 190
   : C=C+1
   : IF C=1THEN PRINT " on ";D$;
0185 IF N=8THEN DO
   : X=16
   : I=VAL(STR(I$,2))
   : END DO
0190 NEXT X
0200 NEXT I
0210 IF C>0AND N<8THEN PRINT C,
0220 NEXT D
   : PRINT
   : GOTO 120