image of READY prompt

Wang2200.org

Listing of file='TBO.SECT' on disk='vmedia/toolbox.wvd.zip'

# Sector 683, program filename = 'TBO.SECT'
0010 REM % TBO.SECT from John Byrd VCR 10/08/89
   : DIM B$5,Z$1,K$1,A$(16),L$30,B$(16),A$3
   : A$,Z$,B$=" "
0020 PRINT HEX(0F060301);BOX(23,79);BOX(4,79);AT(21,0);BOX(0,79);HEX(0E);AT(1,
     22);"Find a File Using a Sector Address";HEX(0F);AT(21,2);"Enter a Sector
      Address, then the Disk Address to Search for a File on."
0030 PRINT AT(6,27);"Sector Address is -";AT(8,27);"Disk Address is   -";AT(10
     ,0);BOX(0,79);AT(10,26);BOX(11,0);AT(11,2);"Indexed Sectors =";AT(13,2);"
     Current End     =";AT(15,2);"Disk Scratched  =";AT(12,30);"Name      Type
        Start   End     Used    Free"
0040 PRINT AT(13,30);"========   ==    =====   =====   =====   ====="
0050 PRINT HEX(0E);AT(6,47);
   : LINPUT B$
   : PRINT HEX(0F06);AT(6,48);B$
   : CONVERT B$TO S1
   : ERRORGOTO 50
0060 PRINT HEX(0E);AT(8,47);
   : LINPUT A$
   : PRINT HEX(0F06);AT(8,48);A$
   : SELECT #1<A$>
   : ERRORGOTO 60
0065 PRINT AT(15,30,49)
0070 DATA LOAD BA T#1,(0)A$()
   : IF VAL(STR(A$(),2))<1THEN 72
   : E1=VAL(STR(A$(),2))
   : E2=VAL(STR(A$(),5),2)-1
   : E3=VAL(STR(A$(),3),2)-1
   : PRINT AT(11,20);
   : PRINTUSING "###",E1
   : PRINT AT(13,20);
   : PRINTUSING "#####",E3
   : PRINT AT(15,20);
   : PRINTUSING "#####",E2
   : IF S1<E1THEN 75
   : IF S1>E3THEN 77
   : A=0
   : GOTO 80
0072 PRINT HEX(0E07);AT(15,30);"This Disk is Not Scratched Yet";HEX(0F)
   : GOTO 50
0075 PRINT HEX(0E07);AT(15,30);"< INDEX >";HEX(0F)
   : GOTO 50
0077 PRINT HEX(0E07);AT(15,30);"Sector is Larger Than the Current End";HEX(0F)
   : GOTO 50
0080 B=0
   : DATA LOAD BA T#1,(A)A$()
0090 B=B+1
   : IF A=0AND B=1THEN 90
   : IF STR(A$(B),,1)=HEX(00)THEN 100
   : D1=VAL(STR(A$(B),3),2)
   : D2=VAL(STR(A$(B),5),2)
   : IF S1>=D1AND S1<=D2THEN 120
   : IF B=16THEN 100
   : GOTO 90
0100 A=A+1
   : IF A>=E1THEN 110
   : GOTO 80
0110 PRINT HEX(0E07);AT(15,30);"No Cataloged File Contains This Sector";HEX(0F
     )
   : GOTO 50
0120 DATA LOAD BA T#1,(D2)B$()
   : D3=VAL(STR(B$(),2),2)
   : D4=D2-D1-D3+1
   : L$=STR(A$(B),9,8)
   : STR(L$,9)=STR(A$(B),,2)
   : CONVERT D1TO STR(L$,11),(#####)
   : CONVERT D2TO STR(L$,16),(#####)
   : CONVERT D3TO STR(L$,21),(#####)
   : CONVERT D4TO STR(L$,26),(#####)
0130 $TRAN(STR(L$,10,1),HEX(440050800000))R
   : $TRAN(STR(L$,9,1),HEX(5311))R
   : IF STR(L$,9,1)<>"S"THEN STR(L$,9,1)=Z$
   : PRINT HEX(0E07);AT(15,30);
0140 PRINTUSING "########   ##    #####   #####   #####   #####",STR(L$,1),STR
     (L$,9),STR(L$,11),STR(L$,16),STR(L$,21),STR(L$,26)
   : PRINT HEX(0F)
   : GOTO 50