image of READY prompt

Wang2200.org

Listing of file='2229TENS' on disk='vmedia/2229_diagnostics.wvd.zip'

# Sector 378, program filename = '2229TENS'
0010 COM F9$8
   : F9$="2229TENS"
   : LOAD T"2229STRT"
0020 REM % "2229TENS" - part of 2229 utilities package
0025 REM % COPYRIGHT WANG LABORATORIES, INC., 1986,1987
0030 REM % Perform tape tensioning procedure  --  ST  01/21/1983
0040 DIM R$16,T$30,M$40
   : T$="TENSION TAPE CARTRIDGE"
   : GOSUB '151
   : $OPEN #4
0050 PRINT AT(2,5);"This program will rewind, then unwind a tape cartridge in
     order to"
0055 PRINT AT(3,5);"establish a uniform tape tension."
0060 PRINT AT(5,0);"     This procedure should be run whenever :"
0070 PRINT AT(7,10);"1 - A new cartridge is to be used"
0080 PRINT AT(8,10);"2 - A cartridge has unrecoverable read errors"
0090 PRINT AT(9,10);"3 - A cartridge has been subjected to extreme environment
     al conditions"
0100 PRINT AT(14,0);"Insert cartridge"
   : GOSUB '152
0120 PRINT HEX(06),AT(2,0,);
   : GOSUB '104
   : REM LOAD TAPE
0130 GOSUB '105
   : REM UNLOAD TAPE
0140 GOSUB '104
0150 GOSUB '105
0160 PRINT AT(2,0,);AT(10,0);"DONE";HEX(07)
   : $CLOSE#4
   : GOSUB '153
   : STOP
   : GOTO 10
5250 DEFFN'104
   : REM % LOAD TAPE
5260 PRINT HEX(020404000E)
   : M$="Loading Tape"
   : GOSUB '160
   : $GIO#4(4404 8701,R$)
   : PRINT HEX(0F)
   : GOSUB '222
   : REM GET ERROR
   : IF E=0THEN RETURN
   : IF E<>3THEN 7540
5275 GOSUB '208
   : GOTO 5260
5300 DEFFN'105
   : REM % UNLOAD TAPE
5305 PRINT HEX(020404000E)
   : M$="Unloading tape"
   : GOSUB '160
5310 $GIO#4(4405 8701,R$)
   : STR(R$,1,1)=HEX(00)
   : PRINT HEX(0F)
   : GOSUB '222
5315 IF E=0THEN RETURN
   : IF E<>3THEN 7540
   : GOSUB '208
   : GOTO 5305
6500 DEFFN'160
   : REM PRINT OUT MESSAGE
   : PRINT HEX(06),AT(10,0,320);M$
   : RETURN
7510 DEFFN'222
   : REM % Check error return
   : E=VAL(STR(R$,1,1))
   : IF E=0THEN RETURN
   : RESTORE LINE7520,E
   : READ E$
   : IF E=2THEN C3=1
   : REM SET OUT OF TAPE FLAG
   : RETURN
7520 DATA "ILLEGAL COMMAND","OUT OF TAPE","TAPE NOT READY","WRITE PROTECTED","
     RESULTS PENDING","DATA ERROR","FILE MARK FOUND","TAPE FAULT"
7530 REM % Errors
7540 PRINT "Error ";E;" - ";E$
   : STOP
7560 DEFFN'152
   : REM % WAIT FOR RETURN KEY
7565 PRINT
   : PRINT "Press RETURN"
7570 DEFFN'154
   : KEYIN K$
7580 KEYIN K$,7580,7580
   : RETURN
   : REM FLUSH EXTRA KEYSTROKES
8500 DEFFN'208
   : REM % ERROR MESSAGE FOR TAPE UNIT NOT READY
8510 M$="Tape drive is not ready "
   : GOSUB '160
   : E=VAL(STR(S$,10,1))
   : GOSUB '152
   : RETURN
8567 DEFFN'151
   : PRINT HEX(03);AT(0,40-(LEN(T$)/2));HEX(020402040E);T$;HEX(0F)
   : RETURN
8700 DEFFN'126
   : RETURN CLEAR ALL
   : GOTO 20
8710 DEFFN'127
   : RETURN CLEAR ALL
   : $PSTAT=".2229"
   : F$=".2229"
   : LOAD RUN
8720 DEFFN'153
   : PRINT AT(18,0);"Press FN/TAB to restart current utility"
   : PRINT "Press Shift FN/TAB to return to menu"
   : RETURN