Listing of file='CNEWYEAR' on disk='vmedia/2282_graphics_crt_demos.wvd.zip'
# Sector 141, program filename = 'CNEWYEAR'
0001 REM %HOLIDAY GREETING PROGRAM - 02/25/82 - by R.L. Droz
0002 COM P$3
0003 DIM S1$64,L(7,2)
0005 PRINT HEX(0D03),,HEX(020400020F0E);" CHINESE NEWYEAR GREETING PROGRAM. "
: PRINT
0006 LINPUT "GRAPHICS CRT IS AT WHICH ADDRESS?" -P$
0007 MAT SEARCH "13151604", = STR(P$,2,2) TO L$
: IF STR(L$,,2)=HEX(0000) THEN 5
0008 SELECT PLOT <P$>
0015 SELECT D
0020 PRINT AT(4,0,79);
: INPUT "GREGORIAN (WESTERN) YEAR",Y
: ERRORGOTO 20
0043 PLOT <,,HEX(0603E5)>
: ERRORGOTO 5
0045 GOSUB '60(1000,"HAPPY CHINESE NEWYEAR")
0047 RESTORE LINE 48,1+MOD(Y-1900,12)
: READ A$
0048 DATA "Rat","Ox","Tiger","Hare","Dragon","Snake","Horse","Sheep","Monkey",
"Rooster","Dog","Pig"
0050 S1$="(The Year of the " & A$ & ")"
: GOSUB '60(Y9,S1$)
0062 $IF OFF /005,65
: SELECT P9
: PRINT "2200 Chinese New Year Greeting program running ..."
0063 REM PRINT "To stop program, enter $RELEASE TERMINAL TO";#PART
0064 SELECT P
: REM $RELEASE TERMINAL
: $PSTAT="GREETING"
0065 REM % DRAW FIGURE
: M=3
0066 PLOT <,,R>,<320,20,U>,<0,10*M,D>,<60*M,0,D>,<0,-5*M,D>,<10*M,0,D>,<-10*M
,0,D>,<0,-5*M,D>,<-60*M,0,D>
0067 REM % BLINK LIGHTS
0068 RESTORE LINE 69
: FOR I=1 TO 7
: READ L
: L(I,1)=M*(L+75)+320
: READ L
: L(I,2)=M*L+25
: NEXT I
0069 DATA 2,2, -2,-2, -5,-5, 5,5, 7,-3, -9,7, 5,5
0070 PLOT <1,,C>,<10,,S>
0080 FOR J=1 TO 500
: L=MOD(7*RND(1),7)
: PLOT <,,R>,<L(L+1,1),L(L+1,2),"*">
0085 IF RND(1)>.5 THEN PLOT <,,HEX(E1)>
: ELSE PLOT <,,HEX(E2)>
0090 FOR I=1 TO 10
: $BREAK 255
: NEXT I
: NEXT J
0091 PLOT <,,HEX(E2)>
: FOR J=1 TO 7
: PLOT <,,R>,<L(J,1),L(J,2),"*">
: NEXT J
0092 PLOT <2,,C>,<20,15,S>,<,,R>,<360,20,HEX(E1)>,<,,"BANG !!">
0093 FOR I=1 TO 10
: $IF OFF /005,94
: PRINT HEX(070D)
0094 FOR J=1 TO 30
: $BREAK 255
: NEXT J
: NEXT I
: GOTO 43
0099 REM % CENTER WORDS
0100 DEFFN'60(Y9,S1$)
: C=MIN(INT(80/LEN(S1$)),4)
: S=MAX(10*C,800/LEN(S1$))
0110 $TRAN (S1$, " ] ") R
: PLOT <,,R>,<C,,C>,<S,,S>,<S/2,MIN(512-S,Y9),S1$>
0120 Y9=MIN(Y9,512)-2.5*S
: RETURN
1000 DEFFN'31
: COM CLEAR P$
: LOAD DC T "!"