image of READY prompt

Wang2200.org

Listing of file='START' on disk='vmedia/701-2046C.wvd.zip'

# Sector 408, program filename = 'START'
0010 REM .     START,  00-00 (6/28/75),   12002
0100 COM N5$(9)8,P8,P9,O0,O1,O2,O3,O4,O5,O8,D9$(32)8,E9$(7)2
   : DIM N1$(8)8,N2$(8),N3$(8),N4$(8),L$(8)2,L(8),L1(8)
   : DIM L2(8),D$(16),N9$(8),L4$(8)2,L1$(8)2,L2$(8)2
0130 DIM Q6$64,W$(3)8,Q4(3),Q5(3),Q1$8,W1$1,L9$(8),Z$64
   : SELECT PRINT 005
   : DIM N6$(8)8
   : INIT(20)N6$()
   : N6$(1)="M/MD010A"
   : N6$(3)="M/TD010A"
   : N6$(6)="M/DD010A"
   : N6$(7)="M/HD010A"
   : N6$(4)="M/VD010A"
   : INIT(20)N5$()
0230 E9$(1)="OK"
   : MAT COPY E9$()TO E9$()<3,10>
   : N1$(5)="WDMD010A"
   : N1$(1)="WM0D010A"
   : N1$(2)="WCPD010A"
   : N1$(6)="WDKD010A"
   : N1$(3)="PTRD010A"
   : N1$(4)="PRVD010A"
   : N1$(7)="PHAL010A"
0315 N1$(8)="COPY010A"
   : N2$(5)="DISK-INSTR."
   : N2$(1)="MEMORY"
   : N2$(2)="CPU"
   : N2$(6)="DISKS"
   : N2$(3)="PRINTER"
   : N2$(4)="PLATTER VERIFY"
   : N2$(7)="PERIPHERALS"
   : N2$(8)="COPY/VERIFY"
0390 N5$(9)="M/END"
   : INIT(20)D9$()
   : D9$(1)=HEX(0030303030303030)
   : GOSUB 2060
   : GOSUB '248(4,0,0)
   : PRINT "--------------------------------------"
   : GOSUB '248(6,6,0)
   : PRINT "1.  310             4.  B10"
0470 PRINT TAB(6);"2.  320             5.  B20"
   : PRINT TAB(6);"3.  350             6.  360"
0490 GOSUB '245("ENTER THE NO. TO CHOOSE THE PROGRAM DISK ADDRESS",1,0)
   : IF Q9>0THEN 530
0510 GOSUB 9480
   : GOTO 490
0530 IF Q9>6THEN 510
   : O0=Q9
   : CONVERT O0TO STR(D9$(32),1,1),(#)
   : ON Q9GOTO 580,600,620,640,660,680
   : GOTO 510
0580 SELECT #6310
   : GOTO 690
0600 SELECT #6320
   : GOTO 690
0620 SELECT #6350
   : GOTO 690
0640 SELECT #6B10
   : GOTO 690
0660 SELECT #6B20
   : GOTO 690
0680 SELECT #6360
0690 GOSUB '248(1,0,9)
   : O8=1
0710 GOSUB '243("DO YOU DESIRE A HARD COPY (Y OR N)",1)
   : IF Q6$="N"THEN 840
   : IF Q6$="Y"THEN 760
   : GOSUB 9480
   : GOTO 710
0760 O8=2
0770 GOSUB '245("ENTER 1 FOR 2201 PRINTER, 0 FOR OTHERS",1,0)
   : IF Q9=0THEN 840
   : IF Q9=1THEN 820
   : GOSUB 9480
   : GOTO 770
0820 O8=3
   : GOSUB 2060
0840 GOSUB '248(1,0,4)
   : PRINT "  SEARCH THE INDEX PROGRAMS"
   : FOR I=1TO 8
   : L(I)=9
   : NEXT I
   : A,N,E=0
   : INIT(20)N3$()
0900 DATA LOAD BA T#6,(A,A)D$()
   : FOR I=1TO 16
   : IF A+I=2THEN 1050
   : IF STR(D$(I),1,1)=HEX(00)THEN 1040
   : IF STR(D$(I),1,1)<>HEX(10)THEN 1050
   : INIT(FF)L$()
   : MAT SEARCHN1$(),=STR(D$(I),9,8)TO L$()STEP 8
   : IF L$(2)<>HEX(0000)THEN 1050
   : N=N+1
   : L2=VAL(STR(L$(1),2,1))
1000 L2=INT((L2-1)/8)+1
   : L(N)=L2
   : N3$(N)=N2$(L2)
   : GOTO 1050
1040 I=16
1050 NEXT I
   : IF A>=23THEN 1080
   : IF E<>1THEN 900
1080 IF N>0THEN 1120
   : GOSUB '248(1,0,1)
   : PRINT "  NO PROGRAM ON THE DISK"
   : STOP
1120 MAT CONVERT L()TO L9$()
   : MAT SORTL9$()TO L2$(),L1$()
   : FOR I=1TO N
   : L2=VAL(STR(L1$(I),1,1))
   : L2(I)=L2
   : NEXT I
   : MAT COPY N3$()TO N9$()
   : GOSUB '33("2200 HARDWARE DIAGNOSTIC MENU",3,N)
   : N1=0
   : INIT(" ")N4$()
   : FOR I=1TO 8
   : L1(I)=9
   : NEXT I
1250 GOSUB '245("ENTER THE PROGRAM # TO CHOOSE THE DIAGNOSTIC ( 0 TO STOP )
     ",2,0)
   : IF Q9=0THEN 1470
   : IF Q9>NTHEN 1290
   : IF Q9>=1THEN 1310
1290 GOSUB 9480
   : GOTO 1250
1310 IF N1=0THEN 1390
   : E=0
   : FOR I=1TO N1
   : IF Q9<>L1(I)THEN 1370
   : E=1
   : I=N1
1370 NEXT I
   : IF E=1THEN 1290
1390 N1=N1+1
   : L1(N1)=Q9
   : N4$(N1)=N3$(L2(Q9))
   : N9=INT((Q9-1)/V4)
   : N8=Q9-N9*V4
   : GOSUB '248(4+N8,N9*20+3,0)
   : PRINT "*"
   : GOTO 1250
1470 MAT CONVERT L1()TO L9$()
   : MAT SORTL9$()TO L2$(),L1$()
   : FOR I=1TO N1
   : L2=VAL(STR(L1$(I),1,1))
   : L2(I)=L2
   : NEXT I
   : D9$(N1+2)="MSGD010A"
   : INIT(" ")N9$()
   : MAT COPY N4$()TO N9$()
   : IF N1>0THEN 1600
   : GOSUB 2060
1580 PRINT " NO PROGRAMS ASSIGNED, RUN DISTURBED"
   : STOP
1600 GOSUB '33("2200 HARDWARE DIAGNOSTIC MENU",2,N1)
1610 GOSUB '245("IF OK. ENTER 0, IF NOT ENTER 1",1,0)
   : IF Q9=0THEN 1660
   : IF Q9=1THEN 1120
   : GOSUB 9480
   : GOTO 1610
1660 GOSUB '248(1,0,14)
   : P8,P9=0
   : CONVERT O8TO STR(D9$(1),8,1),(#)
   : FOR I=1TO N1
   : MAT SEARCHN2$(),=N9$(L2(I))TO L$()STEP 16
   : L3=INT(VAL(STR(L$(1),2))-1)/16+1
   : D9$(I+1)=N1$(L3)
   : N5$(I)=N6$(L3)
   : NEXT I
   : LOAD DC T#6,"M/START"
1760 DEFFN'33(Z$,V1,V2)
   : V3=32
   : IF V1=2THEN 1800
   : V3=20
1800 V4=INT((V2-1)/V1)+1
   : PRINT HEX(03);Z$
   : PRINT HEX(0A0A0A);
   : PRINT "-----------------------------------------"
   : FOR I=1TO V4
   : PRINTUSING 2050,I,N9$(L2(I))
   : NEXT I
   : Q6=4
   : E=0
   : FOR I=V4+1TO V4*2
   : Q6=Q6+1
   : IF I<=V2THEN 1910
   : I=V4*2
   : E=1
   : GOTO 1930
1910 GOSUB '248(Q6,V3,0)
   : PRINTUSING 2050,I,N9$(L2(I))
1930 NEXT I
   : IF E<>0THEN 2040
   : Q6=4
   : FOR I=V4*2+1TO V4*3
   : Q6=Q6+1
   : IF I<=V2THEN 2010
   : I=V4*3
   : GOTO 2030
2010 GOSUB '248(Q6,V3*2,0)
   : PRINTUSING 2050,I,N9$(L2(I))
2030 NEXT I
2040 RETURN
2050 % ##  ###############
2060 PRINT HEX(03);"2200 HARDWARE DIAGNOSTIC MENU"
   : RETURN
9000 Q6=3
   : GOTO 9610
9020 DEFFN'254
   : GOSUB '243("KEY RETURN(EXEC) TO RESUME",0)
   : W4$=Q6$
   : GOSUB '248(0,0,4)
   : Q6$=W4$
   : RETURN
9080 DEFFN'242(W0,Q6$)
   : IF W0<=0THEN 9760
   : IF W0=1THEN 9120
   : STR(Q6$,2)=STR(Q6$,1,W0-1)
9120 PRINT Q6$;
   : RETURN
9140 DEFFN'243(Q6$,Q0)
   : GOSUB 9510
9160 SELECT CO 205
   : Q6$=" "
   : INPUT Q6$
   : IF Q0=0THEN 9580
   : IF LEN(Q6$)<=Q0THEN 9580
   : GOSUB 9480
9220 DEFFN'244(Q0)
   : GOSUB 9560
   : GOSUB 9530
   : GOTO 9160
9260 DEFFN'245(Q6$,Q2,Q3)
   : Q0=ABS(Q2)+Q3+1
   : GOSUB 9510
9290 GOSUB '242(ABS(Q2)+2,HEX(09))
   : PRINT "/"
   : GOSUB 9560
   : SELECT CO 205
   : Q9,W0=-1E-99
   : INPUT Q9
   : IF W0=Q9THEN 9380
   : IF Q9>=0THEN 9440
   : IF Q2<=0THEN 9440
9380 GOSUB 9480
9390 DEFFN'246(Q2,Q3)
   : Q0=ABS(Q2)+Q3+1
   : GOSUB 9560
   : GOSUB 9530
   : GOTO 9290
9440 IF ABS(Q9)>=10^ABS(Q2)THEN 9380
   : W0=ABS(Q9*10^Q3)
   : IF INT(W0)<>W0THEN 9380
   : GOTO 9000
9480 GOSUB 9000
   : PRINT "RE-ENTER"
   : RETURN
9510 GOSUB 9760
   : PRINT HEX(010A);STR(Q6$,1);
9530 GOSUB 9760
   : GOSUB '242(Q0+2,"-")
   : PRINT TAB(64)
9560 PRINT HEX(010A0A)
   : RETURN
9580 PRINT HEX(0A);TAB(64)
   : GOTO 9760
9600 Q6=0
9610 Q7=0
   : Q8=1
9630 DEFFN'248(Q6,Q7,Q8)
   : GOSUB 9760
   : IF Q8<1THEN 9730
   : GOSUB 9730
   : SELECT PRINT 205
   : Q6$=" "
   : PRINT STR(Q6$,Q7+1)
   : IF Q8<2THEN 9730
   : FOR W0=2TO Q8
   : PRINT HEX(0A);STR(Q6$,1)
   : NEXT W0
9730 PRINT HEX(01)
   : GOSUB '242(Q7,HEX(09))
   : GOSUB '242(Q6,HEX(0A))
9760 SELECT PRINT 005(64),CO 005
   : RETURN
9780 DEFFN'10"SELECT CO 005";HEX(0D)
9800 DEFFN'0
   : LOAD DC T#6,"COPY010A"