Listing of file='MENU010A' on disk='vmedia/701-2110C.wvd.zip'
# Sector 75, program filename = 'MENU010A'
0010 REM MENU010A,02-00 (09/06/78)
0030 COM R1$8,R2$1,R9$8,R9$(16)
: COM Q6$64,W$8,W3$3,W4$1,W$(3)8,Q4(3),Q5(3)
: DIM A$8,B$30
: SELECT PRINT 005(64),CO 005(64)
: PRINT HEX(030A0A)
: GOTO 580
0100 DEFFN'33(Q6$)
: PRINT HEX(030A0A0A0A0A0A)
: PRINT TAB(10);"* * * * * * * * * * * * * * * * * * * * * * * *"
: PRINT TAB(10);"* *"
0140 PRINT TAB(10);"* SYSTEM NOW LOADING *"
: PRINT TAB(10);"*";TAB(35-INT(LEN(Q6$)/2));Q6$;TAB(56);"*"
: PRINT TAB(10);"* *"
0170 PRINT TAB(10);"* * * * * * * * * * * * * * * * * * * * * * * *"
: RETURN
0200 DEFFN'0
: GOSUB '53("DE1.010A","DATA ENTRY 1")
: GOSUB '33("DATA ENTRY 1")
: COM CLEAR R1$
: LOAD DC T#1,"DE1.010A"
0260 DEFFN'1
: GOSUB '53("ATOM020A","ATOMIZE")
: GOSUB '33("ATOMIZE")
: LOAD DC T#1,"ATOM020A"30,6999
0310 DEFFN'2
: GOSUB '53("ATOM030A","DE-ATOMIZE")
: GOSUB '33("DE-ATOMIZE")
: LOAD DC T#1,"ATOM030A"30,6999
0360 DEFFN'3
: GOSUB '53("OFFLINE","OFF-LINE PRINT")
: GOSUB '33("OFF-LINE PRINT")
: COM CLEAR R1$
: LOAD DC T#1,"OFFLINE"
0420 DEFFN'4
: GOSUB '53("TCFORMAT","TC SUBROUTINES")
: GOSUB '33("TC SUBROUTINES")
: COM CLEAR
: LOAD DC T#1,"TCFORMAT"
0470 DEFFN'5
: GOSUB '53("QUIKLIST","LIST/DUMP TC FILES")
: GOSUB '33("LIST/DUMP TC FILES")
: COM CLEAR R1$
: LOAD DC T#1,"QUIKLIST"
0520 DEFFN'15
: GOSUB '53("ISSM000A","DESIRED ISS PROGRAMS")
: COM CLEAR
: LOAD DC T#0,"START"
0580 PRINT TAB(14);"TELECOMMUNICATIONS SUPPORT SYSTEM"
: PRINT
: PRINT "----------------------------------------------------------------"
0610 PRINT "FN KEY PROGRAM NAME FN KEY PROGRAM NAME"
: PRINT "----------------------------------------------------------------"
0630 PRINT " 00 - DATA ENTRY 1 03 - 0FF-LINE PRINT"
: PRINT " 01 - ATOMIZE 04 - TC SUBROUTINES"
0650 PRINT " 02 - DE-ATOMIZE 05 - LIST/DUMP TC FILES"
: PRINT " 15 - RETURN TO ISS"
: STOP
: END
0700 DEFFN'53(A$,B$)
0710 GOSUB '229(1,A$)
: IF R=1THEN 760
: PRINT HEX(010A);"PLEASE MOUNT PLATTER CONTAINING ";B$;".";TAB(80)
: GOSUB '254
: GOTO 710
0760 RETURN
7000 DEFFN'242(W0,Q6$)
: IF W0<=0THEN 7010
: INIT(Q6$)Q6$
: PRINT STR(Q6$,1,W0);
7010 RETURN
7020 DEFFN'254
: GOSUB '248(2,0,1)
: INPUT "KEY RETURN(EXEC) TO RESUME ",Q6$
: W4$=Q6$
: GOSUB '248(1,0,3)
: Q6$=W4$
: RETURN
7030 DEFFN'243(Q6$,Q0)
: GOSUB 7150
7040 SELECT CO 205
: Q6$=" "
: INPUT Q6$
: IF Q0=0THEN 7180
: IF LEN(Q6$)<=Q0THEN 7180
: GOSUB 7140
7050 DEFFN'244(Q0)
: GOSUB 7170
: GOSUB 7160
: GOTO 7040
7060 DEFFN'245(Q6$,Q2,Q3)
: Q0=ABS(Q2)+Q3+1
: GOSUB 7150
7070 IF ABS(Q2)+ABS(Q3)=0THEN 7080
: GOSUB '242(ABS(Q2)+2,HEX(09))
: PRINT "/"
: GOTO 7090
7080 PRINT ,," "
7090 GOSUB 7170
: SELECT CO 205
: Q9,W0=-1E-99
: INPUT Q9
: IF W0=Q9THEN 7100
: IF ABS(Q2)+Q3=0THEN 7130
: IF Q9>=0THEN 7120
: IF Q2<=0THEN 7120
7100 GOSUB 7140
7110 DEFFN'246(Q2,Q3)
: Q0=ABS(Q2)+Q3+1
: GOSUB 7170
: GOSUB 7160
: GOTO 7070
7120 IF ABS(Q9)>=10^ABS(Q2)THEN 7100
: W0=ABS(Q9*10^Q3)
: IF INT(W0)<>W0THEN 7100
7130 GOSUB '248(3,0,1)
: RETURN
7140 DEFFN'55
: GOSUB '248(3,0,1)
: PRINT "RE-ENTER"
: RETURN
7150 SELECT PRINT 005(64),CO 005
: PRINT HEX(010A);STR(Q6$,1);
7160 SELECT PRINT 005(64),CO 005
: GOSUB '242(Q0+2,"-")
: PRINT TAB(64)
7170 PRINT HEX(010A0A)
: RETURN
7180 PRINT HEX(0A);TAB(64)
: SELECT PRINT 005(64),CO 005
: RETURN
7190 DEFFN'248(Q6,Q7,Q8)
: GOSUB 7210
: IF Q8<1THEN 7200
: GOSUB 7200
: SELECT PRINT 205
: PRINT TAB(64-Q7)
: IF Q8<2THEN 7200
: FOR W0=2TO Q8
: PRINT HEX(0A);TAB(64)
: NEXT W0
7200 PRINT HEX(01)
: GOSUB '242(Q7,HEX(09))
: GOSUB '242(Q6,HEX(0A))
7210 SELECT PRINT 005(64),CO 005
: RETURN
7220 DEFFN'229(R9,R9$)
: DATA LOAD BA T#R9,(0,R3)R9$()
: R4=VAL(STR(R9$(1),2))
: R1$=R9$
: XOR (STR(R1$,2),R1$)
: R=3*VAL(STR(R1$,8))
: R=INT(R/256)+R-INT(R/256)*256
: R3,R5=R-INT(R/R4)*R4
7230 DATA LOAD BA T#R9,(R3,R)R9$()
: R,R6=0
: FOR R7=2-SGN(R3)TO 16
: R2$=STR(R9$(R7),1,1)
: IF R2$=HEX(00)THEN 7240
: IF R2$=HEX(21)THEN 7250
: IF STR(R9$(R7),9)<>R9$THEN 7250
: R=SGN(16.5-VAL(R2$))*(2-SGN(VAL(STR(R9$(R7),2,1))))
: R6=R7
7240 RETURN
7250 NEXT R7
: R2$=HEX(00)
: R3=R3-1
: IF R3=R5THEN 7240
: IF R3>=0THEN 7230
: R3=R4-1
: GOTO 7230
7260 DEFFN'228(R9,R9$,R1)
: GOSUB '229(R9,R9$)
: ON VAL(R2$)-15GOTO 7320,7330
: R2$="0"
: DATA LOAD BA T#R9,(0,R3)R9$()
: AND (STR(R9$(1),3,1),7F)
: R2=VAL(STR(R9$(1),3,1))*256+VAL(STR(R9$(1),4,1))
: AND (STR(R9$(1),5,1),7F)
7270 R3=VAL(STR(R9$(1),5,1))*256+VAL(STR(R9$(1),6,1))
: IF R3-R2<R1+2THEN 7310
: DATA SAVE DC OPEN T#R9,(R3-R2),R9$
: RETURN
7280 DEFFN'227(R9,R9$,R1)
: GOSUB '229(R9,R9$)
: IF R2$=HEX(00)THEN 7310
: LIMITS T#R9,R9$,R2,R3,R0
: DATA LOAD BA T#R9,(0,R4)R9$()
: AND (STR(R9$(1),3,1),7F)
: R4=VAL(STR(R9$(1),3,1))*256+VAL(STR(R9$(1),4,1))
: IF R4-1<>R3THEN 7320
7290 IF R2+R0+R1-1>=R3THEN 7330
: R2,R4=R2+R1+R0-1
: DATA LOAD BA T#R9,(R3,R3)R9$()
: DATA SAVE BA T#R9,(R4,R3)R9$()
: GOSUB '229(R9,R9$)
: R4=R2
: BIN(STR(R9$(R6),5,1))=INT(R4/256)
: BIN(STR(R9$(R6),6,1))=R4-INT(R4/256)*256
7300 DATA SAVE BA T#R9,(R3,R3)R9$()
: DATA LOAD BA T#R9,(0,R3)R9$()
: BIN(STR(R9$(1),3,1))=INT((R4+1)/256)
: BIN(STR(R9$(1),4,1))=R4+1-INT((R4+1)/256)*256
: DATA SAVE BA T#R9,(0,R3)R9$()
: R2$="0"
: RETURN
7310 R2$="3"
: RETURN
7320 R2$="2"
: RETURN
7330 R2$="1"
: RETURN