image of READY prompt

Wang2200.org

Listing of file='ISS.000M' on disk='vmedia/701-2427C.wvd.zip'

# Sector 175, program filename = 'ISS.000M'
0010 REM  ISS.000M, RELEASE 5-1, (11/07/79) - THIS PROGRAM IS A COPYRIGHT PROD
     UCT OF WANG LABS. INC., UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED

0050 COM Q1,Q1$8,S,S0,S1,S2,S3,S$3,S$(27)3,S1$64,S8$11,S9$11
   : DIM B$(3)83,C$(48)3
0120 %   THIS MUST BE STATEMENT 120
0360 PRINT HEX(0306)
   : PRINT AT(6,20);"ISS RELEASE 5.1"
   : S1$="ISS.200SISS.254S"
   : LOAD T<LEN(S1$)/8>S1$10,0BEG 420
0420 A$=$PSTAT(#PART)
   : IF STR(A$,9,1)="M"THEN S3=4
   : ELSE S3=3
   : IF S3=4AND STR(A$,10,1)<HEX(17)THEN 1430
   : IF S3=3AND STR(A$,10,1)<HEX(19)THEN 1450
0470 PRINT AT(10,0);
   : PRINT "FN     AUXILARY FUNCTIONS"
   : PRINT "--  -------------------------"
   : PRINT "00  DISPLAY EXISTING STATIONS"
   : PRINT "16  ADD NEW STATION"
0520 GOSUB '200("1","48",2,0,"ENTER STATION NUMBER",1)
   : A$="ISS.000D"
   : CONVERT Q9TO STR(A$,6,2),(##)
   : DATA LOAD DC OPEN T#0,A$
   : ERRORPRINT HEX(07)
   : GOTO 520
0570 DATA LOAD DC #0,B$()
   : $UNPACK(F=HEX(A0085003A003A00B))B$(1)TO Q1$,Q1,S$,S9$
   : $UNPACK(F=HEX(A003))B$(2)TO S$()
   : S2=Q9
   : $GIO/005(7601,A$)
   : A$=A$AND HEX(10)
   : IF STR(A$,1,1)=HEX(10)THEN S0=80
   : ELSE S0=64
   : SELECT PRINT 005(S0)
   : S=SPACEK
   : PRINT HEX(03);"LOADING SYSTEM CONFIGURATION"
0710 LOAD T"ISS.001M"
   : ERRORGOTO 720
0720 PRINT HEX(010A);"MOUNT ISS DISK AT ADDRESS ";S$
   : GOSUB '254
   : GOTO 710
0780 DEFFN'0
   : RETURN CLEAR
0810 C$()=" "
   : PRINT HEX(030A);"SEARCHING FOR ACTIVE STATIONS"
   : A$="ISS.000D"
   : FOR I=1TO 48
   : CONVERT ITO STR(A$,6,2),(##)
   : LIMITS T#0,A$,A,A,A,A
   : IF A<>2THEN 930
   : IF C$()=" "THEN C$()=STR(A$,6,2)
   : ELSE C$()=C$()&","&STR(A$,6,2)
   : PRINT AT(14,0);"EXISTING STATIONS = ";
   : FOR J=1TO 48
   : PRINT C$(J);
   : NEXT J
0930 NEXT I
0950 GOSUB '200("0","48",2,0,"ENTER STATION NUMBER TO REVIEW DEFAULTS   (0 = E
     ND)",1)
   : IF Q9=0THEN 1150
   : CONVERT Q9TO STR(A$,6,2),(##)
   : DATA LOAD DC OPEN T#0,A$
   : ERRORPRINT HEX(07)
   : GOTO 950
0990 DATA LOAD DC #0,B$()
   : $UNPACK(F=HEX(A0085003A003A00B))B$(1)TO Q1$,Q1,S$,S9$
   : $UNPACK(F=HEX(A003))B$(2)TO S$()
   : PRINT AT(4,22);"( STATION #";Q9;") "
   : PRINT AT(6,0);
   : PRINT TAB(5);"1  DATE            - ";Q1$
   : PRINT TAB(5);"2  PRINTER ADDRESS - ";STR(S$(1));TAB(80)
   : PRINT TAB(5);"3  DISK ADDRESSES  - ";
   : FOR I=2TO 9
   : PRINT STR(S$(I));" ";
   : NEXT I
1100 PRINT TAB(80);
   : PRINT TAB(5);"4  LOADING ADDRESS - ";S$
   : PRINT TAB(5);"5  MENU TO LOAD    - ";S9$;TAB(80)
   : GOTO 950
1150 PRINT HEX(03)
   : GOTO 470
1200 DEFFN'16
   : RETURN CLEAR
1220 PRINT HEX(03)
   : LIMITS T#0,"ISS.000D",A,A1,A1,A1
   : IF A1<>2THEN 1410
   : GOSUB '200("1","48",2,0,"ENTER STATION NUMBER TO CREATE",1)
   : A$="ISS.000D"
   : CONVERT Q9TO STR(A$,5,3),(###)
   : DATA SAVE DC OPEN T#0,(12)A$
   : ERRORPRINT HEX(07)
   : GOTO 1220
1310 DSKIP #0,10S
   : DATA SAVE DC #0,END
   : PRINT HEX(03);"CREATING STATION #";Q9
   : LIMITS T#0,A$,A0,A1,A1,A1
   : COPY T#0,(A,A+9)TO T#0,(A0)
   : PRINT HEX(03)
   : GOTO 470
1410 Q6$="MASTER DEFAULT FILE NOT AVAILABLE"
   : GOTO 1460
1430 Q6$="MVP OPERATING SYSTEM RELEASE 1.7 (MINIMUM) REQUIRED"
   : GOTO 1460
1450 Q6$="VP OPERATING SYSTEM RELEASE 1.9 (MINIMUM) REQUIRED"
1460 PRINT AT(1,0,80);Q6$
   : GOSUB '254
1510 DEFFN'31
1520 LOAD DC T#0,"START"
   : ERRORGOTO 1530
1530 PRINT HEX(010A);"MOUNT ISS DISK AT ADDRESS ";S$
   : GOSUB '254
   : GOTO 1520