image of READY prompt

Wang2200.org

Listing of file='INVT250A' on disk='vmedia/701-2661A.wvd.zip'

# Sector 455, program filename = 'INVT250A'
0010 REM INVT250A, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0170 DIM C6$1,C6$(2)21,C7$13,D6$8,B$1
   : GOTO 4000
4000 SELECT @PARTS0$
   : GOSUB '93(" ")
   : IF I0$=" "THEN 4500
   : C6$(1)="LOW STOCK REPORT"
   : C6$(2)="INACTIVE ITEMS REPORT"
4060 L=L0
   : PRINT AT(4,0,);TAB(10);"OPTIONS AVAILABLE ==> "
   : PRINT ,"0 = RETURN TO MENU"
   : PRINT ,"1 = ";C6$(1)
   : PRINT ,"2 = ";C6$(2)
   : GOSUB '100("0","2",1,0,"ENTER OPTION DESIRED",1)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : C6$=Q6$
   : IF Q9=0THEN 4500
   : PRINT HEX(03);TAB(24);C6$(Q9)
   : IF Q9=1THEN 4280
4170 GOSUB '100(" ","^",8,0,"ENTER CUTOFF DATE  (MM/DD/YY)",2)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : GOSUB '121(Q6$)
   : IF Q6$<>"E"THEN 4230
   : PRINT AT(3,0);HEX(07);"Invalid date, re-enter."
   : GOTO 4170
4230 GOSUB '123(U9)
   : D6=U9
   : D6$=U9$
   : PRINT AT(4,0);"Cutoff date = ";D6$;TAB(40);D6
4280 PRINT AT(5,0);"Processing product ID  ";HEX(06)
   : GOSUB '235(1,0)
   : GOSUB '91
   : IF J0=7THEN 4060
   : IF J0>0THEN 4500
4330 GOSUB '78(2)
   : PRINT AT(5,23,Q0);F1$
   : C7$=" "
   : IF C6$="2"AND H0<=D6THEN GOSUB 6230
   : IF E+E1-E3<E4THEN C7$="BELOW MINIMUM"
   : IF E-E3<=0THEN C7$="OVERALLOCATED"
   : IF E<=0THEN C7$="OUT OF STOCK"
   : IF C6$="1"AND C7$>" "THEN GOSUB 6230
4430 IF J0=7THEN GOSUB '92
   : GOSUB '237(1,0)
   : IF Q$="E"THEN 4060
   : GOSUB '91
   : IF J0=7THEN 4430
   : IF J0=0THEN 4330
4500 DEFFN'31
   : IF J0>0THEN GOSUB '254
   : LOAD TM$
6010 DEFFN'90
   : SELECT PRINT 005(80)
   : Q6$=" "
   : KEYIN Q6$,6050,6050
6050 IF Q6$="P"THEN GOSUB '254
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : SELECT PRINT <I0$>(132)
   : IF L<L0THEN RETURN
   : P1=P1+1
   : PRINT HEX(0C0A0E);TAB(3);N2$
   : IF C6$="2"THEN PRINT "CUTOFF DATE ";D6$;TAB(55);C6$(2);
   : ELSE PRINT TAB(58);C6$(1);
   : PRINT TAB(110);Q1$;TAB(122);"PAGE ";P1
   : PRINT HEX(0A)
   : Q6$="RECMND"
   : Q7$="REORDER"
   : IF C6$="2"THEN Q6$,Q7$=" "
6140 PRINT TAB(47);"ON";TAB(64);"NET";TAB(83);"ON";TAB(88);Q6$;TAB(109);"LAST"
   : PRINT "PRODUCT ID";TAB(Q0+2);"DESCRIPTION";TAB(39);"U/M";TAB(46);"HAND";T
     AB(54);"ALLOC";TAB(63);"AVAIL";TAB(70);"MINIMUM";TAB(81);"ORDER";TAB(88);
     Q7$;TAB(97);"VENDOR";TAB(107);"ACTIVITY";TAB(116);
   : IF C6$="1"THEN PRINT "REMARKS";
   : PRINT
   : PRINT HEX(0A)
   : L=7
   : RETURN
6220 %####,###-
6230 L=L+1
   : GOSUB '123(H0)
   : GOSUB '90
   : PRINT F1$;TAB(Q0+2);STR(F2$,,MIN(36-Q0,LEN(F2$)));TAB(40);F3$;TAB(42);
   : PRINTUSING 6220,E;
   : PRINT TAB(51);
   : PRINTUSING 6220,E3;
   : PRINT TAB(60);
   : PRINTUSING 6220,E-E3;
   : PRINT TAB(69);
   : PRINTUSING 6220,E4;
   : PRINT TAB(78);
   : PRINTUSING 6220,E1;
   : IF C6$<>"1"OR E+E1-E3>=E4THEN 6380
   : PRINT TAB(87);
   : GOSUB 6540
   : PRINTUSING 6220,B8;
   : PRINT " ";B$;
6380 PRINT TAB(98);G2$;TAB(107);U9$;TAB(116);C7$
   : SELECT PRINT 005(80)
   : RETURN
6540 B6=E4
   : B7=E5
   : B0=E-E3
   : B1=E1
   : B$=" "
6600 DEFFN'176
   : B8=0
   : IF B0+B1>B6THEN 6760
   : B8=B7-B0-B1
   : IF A3$="F"THEN 6720
   : IF B8>B5THEN 6750
   : B8=B5
   : GOTO 6750
6720 IF B4>=B8THEN 6750
   : B$="M"
6750 B8=-INT(-B8/B4)*B4
6760 RETURN
9998 DEFFN'29"Q$=";HEX(22);"INVT250A";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
     )
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
     "GBS/MVP - Low stock/inactive items report.";HEX(22);":SELECT#15<I0$>:$OP
     EN#15:SELECTLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$CLOSE#15:
     SELECTLIST005(80)";HEX(0D)