image of READY prompt

Wang2200.org

Listing of file='609date ' on disk='vmedia/701-2738G.wvd.zip'

# Sector 1038, program filename = '609date'
0010 REM "609date" - PROGRAM TO MODIFY CURRENT DATE
0030 DIM S5(1),S0(1),T5(1),S3(1)
   : DIM T1$(1)1,S1$(1)1
   : DIM T1(6),S6(6),S1(6),T2$(6)80
   : DIM T2(3),S7(3),S2(3),S4(3),T5$(7)8
   : DIM S2$(6)2
   : DIM S1$3
   : DIM S2$1,T1$80,T2$2,S0,S4,S5,S6,S7,S9,T0,T2,T3,T5,C0,T7
   : DIM J$
   : DIM T5$(7)8,J7$8,J6$64,J5$64
   : DIM J1$1,J2$1,J3$1,J4$2
   : DATA LOAD DC OPEN T#0,"609@D0"
   : DATA LOAD DC A0$()
0180 J$=STR(A0$(),1,6)
   : RESTORE LINE2510
   : GOSUB '61
   : PRINT HEX(03);
   : IF A9$="D"THEN ROTATEC(STR(J$,,4),8)
   : IF A9$="D"THEN ROTATEC(STR(J$,,4),8)
   : T5$(1)=STR(J$,1,2)
   : T5$(2)=STR(J$,3,2)
   : T5$(3)=STR(J$,5,2)
0240 GOSUB '62
   : ON T5GOTO 310,280,280
   : GOSUB '31
0280 GOSUB 2560
   : PRINT AT(23,0,);T1$;HEX(07);
   : GOTO 240
0310 J$=STR(T5$(1),1,2)&STR(T5$(2),1,2)&STR(T5$(3),1,2)
   : J5$=STR(J$,1,2)&"/"&STR(J$,3,2)&"/"&STR(J$,5,2)
   : IF A9$="D"THEN J5$=STR(J$,3,2)&"/"&STR(J$,1,2)&"/"&STR(J$,5,2)
   : GOSUB '221(J5$)
   : IF J5$<>"E"THEN 380
   : GOSUB 2565
   : PRINT AT(23,0,);T1$;HEX(07);
   : GOTO 240
0380 IF A9$="D"THEN ROTATEC(STR(J$,1,4),8)
   : IF A9$="D"THEN ROTATEC(STR(J$,1,4),8)
   : STR(A0$(),1,6)=J$
   : DBACKSPACE #0,BEG
   : DATA SAVE DC #0,A0$()
   : STR(R2$,1,6)=STR(J$,,6)
   : GOSUB '31
0670 DEFFN'221(J5$)
   : J7$=J5$
   : IF J5$=" "THEN 810
   : IF POS(J5$="/")-1<>NUM(J5$)THEN 810
   : CONVERT STR(J5$,1,NUM(J5$))TO J8
   : IF J8<1THEN 810
   : IF J8>12THEN 810
   : STR(J5$,1)=STR(J5$,POS(J5$="/")+1)
   : IF POS(J5$="/")-1<>NUM(J5$)THEN 810
   : CONVERT STR(J5$,1,NUM(J5$))TO J6
0680 IF J6<1THEN 810
   : IF J6>31THEN 810
   : STR(J5$,1)=STR(J5$,POS(J5$="/")+1)
   : IF NUM(J5$)<>64THEN 810
   : CONVERT J5$TO J0
   : J7=(1-SGN(J0-INT(J0/4)*4))*SGN((J8-1)*(J8-2))
   : ON J8GOTO 800,790,780,770,760,750,740,730,720,710,700,690
0690 J7=J7+30
0700 J7=J7+31
0710 J7=J7+30
0720 J7=J7+31
0730 J7=J7+31
0740 J7=J7+30
0750 J7=J7+31
0760 J7=J7+30
0770 J7=J7+31
0780 J7=J7+28
0790 J7=J7+31
0800 J9=J7+J6+J0*1000
   : RETURN
0810 J5$="E"
   : RETURN
0820 DEFFN'223(J9)
   : J1=INT(J9/1E3)
   : J2=J9-J1*1E3
   : J3=1-SGN(J1-INT(J1/4)*4)
   : IF J2<=334+J3THEN 830
   : J4=J2-334-J3
   : J5=12
   : GOTO 940
0830 IF J2<=304+J3THEN 840
   : J4=J2-304-J3
   : J5=11
   : GOTO 940
0840 IF J2<=273+J3THEN 850
   : J4=J2-273-J3
   : J5=10
   : GOTO 940
0850 IF J2<=243+J3THEN 860
   : J4=J2-243-J3
   : J5=9
   : GOTO 940
0860 IF J2<=212+J3THEN 870
   : J4=J2-212-J3
   : J5=8
   : GOTO 940
0870 IF J2<=181+J3THEN 880
   : J4=J2-181-J3
   : J5=7
   : GOTO 940
0880 IF J2<=151+J3THEN 890
   : J4=J2-151-J3
   : J5=6
   : GOTO 940
0890 IF J2<=120+J3THEN 900
   : J4=J2-120-J3
   : J5=5
   : GOTO 940
0900 IF J2<=90+J3THEN 910
   : J4=J2-90-J3
   : J5=4
   : GOTO 940
0910 IF J2<=59+J3THEN 920
   : J4=J2-59-J3
   : J5=3
   : GOTO 940
0920 IF J2<=31THEN 930
   : J4=J2-31
   : J5=2
   : GOTO 940
0930 J4=J2
   : J5=1
0940 CONVERT J5TO STR(J7$,1,2),(##)
   : CONVERT J4TO STR(J7$,4,2),(##)
   : CONVERT J1TO STR(J7$,7,2),(##)
   : STR(J7$,3,1),STR(J7$,6,1)="/"
   : RETURN
0950 DEFFN'224(J)
   : J2=INT(365.25*(INT(J/1E3)-1))+J-INT(J/1E3)*1E3
   : J=INT((J2)/365.25)
   : J=J*1E3+(J2-INT(365.25*J))+1E3
   : RETURN
0960 DEFFN'225(J1,J2)
   : J3=INT(365.25*(INT(J2/1E3)-1))+J2-INT(J2/1E3)*1E3
   : J3=J3-(INT(365.25*(INT(J1/1E3)-1))+J1-INT(J1/1E3)*1E3)
   : RETURN
0970 DEFFN'226(J)
   : GOSUB '224(J)
   : GOSUB '223(J)
   : T5$(1)="SAT"
   : T5$(2)="SUN"
   : T5$(3)="MON"
   : T5$(4)="TUES"
   : T5$(5)="WED"
   : T5$(6)="THURS"
   : T5$(7)="FRI"
   : J3=J1
   : J2=J4
   : J1=J5
0990 DEFFN'31
   : COM CLEAR C
   : LOAD DC T"609menu"
2500 % DO NOT RENUMBER THE FOLLOWING
2510 DATA 4,0,0,"WANG 2200 Word Processing System"
   : DATA 4,3,20,"Please enter the correct date and time :"
   : DATA 4,5,20,"Date :"
   : DATA 2,5,27,2," "
   : DATA 4,5,29,"/"
   : DATA 2,5,30,2," "
   : DATA 4,5,32,"/"
   : DATA 2,5,33,2," "
   : DATA 4,5,48,"Time : HH:MM"
   : DATA 0
2560 T1$="Invalid Key"
   : RETURN
2565 T1$="Invalid Date"
   : RETURN