image of READY prompt

Wang2200.org

Listing of file='P31D030A' on disk='vmedia/702-0079.wvd.zip'

# Sector 810, program filename = 'P31D030A'
0010 REM % P31D030A    MOD 1/14/80    J. BROOKS
0050 SELECT PRINT 005
   : Q7,Q9=0
0070 IF Q9=0THEN 100
   : IF Q9=1THEN 80
   : IF Q9=2THEN 1350
   : GOTO 50
0080 REM
0100 PRINT HEX(03);"2200 HARDWARE DIGNOSTICS - 2231W 10 PITCH ----------------
     ------"
   : PRINT HEX(0A0A0A0A0A0A0A0A0A0A0A0A0A0A);"DIGNSOTIC MENU ; KEY 'RESET' AND
      SF'31"
   : PRINT HEX(010A0A0A);"1. 204","2. 214","3. 215","4. 216"
0110 PRINT HEX(0C0C);
   : INPUT "SELECT PRINT ADDRESS",Q
   : PRINT HEX(0A0A0D)
0120 INPUT "KEY 'EXEC' TO START",Z9$
0130 PRINT "-------------------------"
   : PRINT "EXECUTING PROGRAM"
0140 DIM T$(1)1,C$(5)22,I$(1)5,C1$(5)22,A$64,C2$(22)1,C3$(10)
0150 GOSUB '100
0200 IF Q9=1THEN 450
0220 PRINT HEX(0C)
   : PRINT "1. THIS IS THE FIRST LINE OF THE PRINT OUT"
   : PRINT
   : PRINT
   : PRINT
   : PRINT
   : PRINT "6. THIS IS THE SIXTH LINE."
   : PRINT "7. VERTICAL TAB STARTS FROM THIS LINE"
   : FOR I=1TO 8
   : N=(1+I)*6
   : PRINT HEX(0B)
   : PRINTUSING 340,N
0340 %##. VERTICAL TAB, HEX(0B)
0350 NEXT I
   : PRINT "55. THE NEXT TEST IS FOR THE LINE FEED CODE HEX(0A)"
   : FOR I=1TO 3
   : PRINT HEX(0A)
   : NEXT I
   : PRINT "59. THIS LINE SHOULD BE PRINTED BEFORE FORM FEED HEX(0C)"
   : PRINT HEX(0C)
0410 PRINT "1.-----------------------THIS SHOULD BE THE FIRST LINE AFTER FORM
     FEED.-----------------------------------------"
0420 A$=HEX(410D00420D00430D00440D00450D00460D)
   : PRINT A$
0450 FOR I=1TO 10
   : PRINT "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890-=!@#$%^&*()-+';/./:?.abcdefgh
     ijklmnopqrstuvwxyz!@#$%^&*()-+1234567890-=!@#$"
   : PRINT HEX(0E)
0470 PRINT "TTTT====5555wwwwjjjjMMMM;;;;;;;;jjjjjjjjTT==55wwjjMM;;;;"
   : NEXT I
   : FOR I=1TO 448
   : PRINT "AB";
   : NEXT I
   : PRINT HEX(0B)
   : IF Q9=1THEN 670
0530 PRINT "THIS LINE SHOULD NOT BE PRINTED, UNLESS THE PRINTER IS NOT RESPOND
     ING TO THE DELETE CODE HEX(7F)";HEX(7F)
   : PRINT "37. YOU SHOULD HEAR THE BELL SOUND THREE TIMES"
   : PRINT HEX(07)
   : FOR D=1TO 300
   : NEXT D
0580 PRINT HEX(07)
   : FOR D=1TO 300
   : NEXT D
   : PRINT HEX(07)
   : PRINT "38. AFTER THIS LINE IS PRINTED THERE SHOULD BE A FORM-FEED"
   : PRINT HEX(0C)
   : N=1
0590 IF Q7=1THEN 50
0650 PRINT "EXAMINE THE FOLLOWING OUTPUT FOR PRINT QUALITY AND CONSISTENCY IN
     THE PRINT PATTERN"
   : PRINT HEX(0E);"TEST 2"
0670 P3=1
   : FOR I=1TO 22
   : BIN(STR(I$(1),1))=INT(RND(1)*94+33)
   : C2$(I)=STR(I$(1),1)
   : STR(I$(1),2)=STR(I$(1),1)
   : MAT COPY I$()TO C1$()<P3,5>
   : P3=P3+5
   : NEXT I
   : FOR I=1TO 22
   : PRINT TAB(I*5-5);C2$(I);
   : NEXT I
   : FOR I=1TO 5
   : FOR J=1TO 5
   : PRINT C1$(J);
   : NEXT J
   : NEXT I
   : PRINT HEX(0D)
   : N=N+1
0800 IF N<10THEN 670
   : IF Q7=1THEN 50
   : IF Q9=1THEN 930
0850 PRINT HEX(0C);HEX(0E);"TEST 3"
   : P3=1
   : N=33
   : P4=1
   : FOR I=1TO 110
   : IF N<=112THEN 930
   : N=33
0930 BIN(I$(1))=N
   : N=N+1
   : MAT COPY I$()TO C$()<P3,1>
   : P3=P3+1
   : NEXT I
0980 FOR I=1TO 95
   : FOR J=1TO 5
   : IF P4=2THEN 1030
   : PRINT C$(J);
   : GOTO 1040
1030 PRINT HEX(0E);C$(J);
1040 NEXT J
   : T$(1)=STR(C$(5),22,1)
   : MAT COPY C$()<1,109>TO C1$()<2,109>
   : MAT COPY T$()<1,1>TO C1$()<1,1>
   : MAT COPY C1$()<1,110>TO C$()<1,110>
   : NEXT I
   : IF P4>1THEN 1050
   : P4=2
   : GOTO 980
1050 IF Q7=1THEN 50
   : IF Q9=1THEN 450
1130 PRINT HEX(0D0C);HEX(0E);"TEST 4"
   : A$="TUIHZ-/.#+/TUIHZ-/.#+/TUIHZ-/.#+/TUIHZ-/.#+/TUIHZ-/.#+/T"
   : FOR I=1TO 25
   : PRINT HEX(0E);A$
   : NEXT I
   : FOR I=1TO 25
   : PRINT A$;A$
   : NEXT I
1135 IF Q7=1THEN 50
1140 PRINT HEX(0C0E);"TEST 5"
1220 DATA "SKIP 1 LINE","SKIP 2 LINES","SKIP 3 LINES","SKIP 4 LINES","SKIP 5 L
     INES","SKIP 6 LINES","SKIP 7 LINES","SKIP 8 LINES","SKIP 9 LINES"
   : INIT(0A)L3$
   : FOR I=1TO 9
   : READ C3$(I)
   : NEXT I
   : FOR I=1TO 9
1280 PRINT C3$(I)
   : PRINT STR(L3$,1,I)
   : NEXT I
   : PRINT HEX(0A0A0A0A0E);"THIS SHOULD BE THE LAST LINE OF THIS PAGE, END OF
     TEST"
   : SELECT PRINT 005(64)
1340 SELECT PRINT 005(64)
   : PRINT "END OF PRINTER DIAGNOSTIC"
   : GOTO 50
1350 Q7=1
1360 GOSUB '100
   : INPUT "ENTER THE NUMBER OF THE TEST DESIRED, 1-5",Q8
   : IF Q8=1THEN 220
   : IF Q8=2THEN 650
   : IF Q8=3THEN 850
   : IF Q8=4THEN 1130
   : IF Q8=5THEN 1140
   : GOTO 50
1500 DEFFN'100
   : ON Q GOTO 1520,1530,1540,1550
1520 SELECT PRINT 204(112)
   : RETURN
1530 SELECT PRINT 214(112)
   : RETURN
1540 SELECT PRINT 215(112)
   : RETURN
1550 SELECT PRINT 216(112)
   : RETURN
9010 DEFFN'31
   : SELECT PRINT 005(64)
   : LOAD DC T"START"