image of READY prompt

Wang2200.org

Listing of file='609Open' on disk='vmedia/731-0071G.wvd.zip'

# Sector 712, program filename = '609Open'
3500 REM 609Open , RELEASE 0-0, (00/00/00) - COPYRIGHT WANG LABS. INC.
3501 DIM D8$1,T$2,D9$5,D6$6,B9$,B0$
3520 DEFFN'110(D9$,D8$)
   : IF VER(D9$,"####A")<>5THEN 3610
   : D0=POS(" ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"=STR(D9$,5)
     )-1
   : DATA LOAD DA T(B3+D0)A0$()
   : B9$=STR(A0$(),2,8)
   : C0=1
   : IF B9$=" "THEN 3620
3525 GOSUB '236(8,C0)
   : IF R1$<>HEX(00)THEN 3630
   : IF V1=0THEN 3640
   : MAT SEARCHSTR(U1$(),,V1*16),=STR(B9$,,8)TO T$STEP 16
   : IF T$>HEX(0000)THEN 3530
   : IF V1<8THEN 3640
   : C0=C0+8
   : GOTO 3525
3530 B9$=STR(U1$(),VAL(T$,2))
   : IF D8$="G"THEN B0$="GLOSSARY."
   : ELSE B0$="DOCUMENT."
   : B0$=B0$&STR(D9$,5,1)&"."&STR(D9$,,4)
   : B2$=" "
   : RETURN
3535 DEFFN'111(B0$,B9$,D6$,D8$)
   : GOSUB '211(B0$,B9$,D6$,D8$)
   : ON VAL(R1$)+1GOTO 3540,,,3650,,3660,3670
   : GOTO 3680
3540 B2$=" "
   : RETURN
3600 %This is line 3600 - do not renumber lines 3600-3699
3610 IF D8$="G"THEN B0$="Glossary"
   : ELSE B0$="Document"
   : B2$="Invalid "&STR(B0$,,8)&" Id"
   : RETURN
3620 B2$="Library '"&STR(D9$,5,1)&"' has not been established"
   : RETURN
3630 GOSUB 3690
   : B2$="Error in Query Volume = "&T$
   : RETURN
3640 B2$="Volume not recorded in master file"
   : RETURN
3650 B2$="Unknown "&STR(B0$,,8)
   : RETURN
3660 B2$="Incorrect Password"
   : RETURN
3670 B2$="Cannot Access "&STR(B0$,,8)&" "&STR(B0$,12,4)&STR(B0$,10,1)
   : RETURN
3680 GOSUB 3690
   : B2$="Error in Open File = "&T$
   : RETURN
3690 IF R1$>HEX(29)THEN CONVERT VAL(R1$)TO T$,(##)
   : ELSE HEXUNPACKR1$TO T$
   : RETURN