image of READY prompt

Wang2200.org

Listing of file='TPUT020A' on disk='vmedia/733-1004.wvd.zip'

# Sector 81, program filename = 'TPUT020A'
0012 REM .     TPUT020A,     00-00 (04/10/77),     10189A
0029 DIM C$(2)40,W2$40
   : SELECT #107B
   : O$="C"
   : PRINT HEX(03);"VOLUME LABEL INITIALIZATION PROGRAM"
0060 GOSUB '245("ENTER THE NUMBER OF THE TAPES TO BE INITIALIZED",2,0)
   : IF Q9>0THEN 100
   : GOSUB 9854
   : GOTO 60
0100 V0=Q9
0110 S7=S7+1
   : IF S7<10THEN 150
   : CONVERT S7TO STR(W2$,13,2),(##)
   : GOTO 160
0150 CONVERT S7TO STR(W2$,14,1),(#)
0160 STR(W2$,1,12)="MOUNT TAPE #"
   : STR(W2$,15,22)=", KEY (EXEC) TO RESUME"
   : GOSUB '243(W2$,0)
0180 GOSUB '248(5,0,5)
   : GOSUB '31(13)
   : GOSUB '248(1,0,9)
0190 GOSUB '245("ENTER LABEL CONTENTS (1=ENTER LABEL, 0=SKIP)",1,0)
   : I9=Q9
   : T9=0
   : IF Q9>=0THEN 220
   : GOSUB 9854
   : GOTO 190
0220 IF Q9<=1THEN 230
   : GOSUB 9854
   : GOTO 190
0230 T=0
0240 GOSUB '243("ENTER LABEL TYPE (I=IBM, A=ANSI, N=NO)",1)
   : V0$=Q6$
   : IF Q6$="I"THEN 320
   : IF Q6$="A"THEN 330
   : IF Q6$="N"THEN 310
   : GOSUB 9854
   : GOTO 240
0310 L$(1),L$(2),L$(3)=A2$
   : GOTO 530
0320 T=1
0330 IF I9=0THEN 530
0340 L$(1),L$(2),L$(3)=A2$
   : L$="VOLUME LABEL     "
   : GOSUB '248(1,0,7)
   : STR(L$(1),1,4)="VOL1"
   : GOSUB 1045
   : PRINT HEX(0A0A0A0A);
   : GOSUB '206(1,1,4)
   : GOSUB '243("ENTER THE VOLUME SERIAL NUMBER (REQUIRED)",6)
0420 STR(L$(1),5,6)=Q6$
   : GOSUB '206(1,5,10)
   : GOSUB '243("ENTER THE OWNER NAME & ADDRESS CODE",10)
   : STR(L$(2),2,10)=Q6$
   : GOSUB '206(1,42,51)
   : GOSUB 1425
0480 KEYIN Z$,500,500
   : GOTO 480
0500 GOSUB '209(1)
   : IF T6=1THEN 340
   : PRINT HEX(03);"VOLUME LABEL INITIALIZATION PROGRAM"
0530 GOSUB '243("ENTER TAPE FILE STATUS (O=OLD, N=NEW)",1)
   : IF Q6$="O"THEN 600
   : IF Q6$="N"THEN 580
   : GOSUB 9854
   : GOTO 530
0580 O$="O"
   : GOTO 630
0600 GOSUB '42
   : IF S6=1THEN 190
   : IF T9=1THEN 180
0630 C$(1)=L$(1)
   : C$(2)=L$(2)
   : L0=80
   : S9=0
   : GOSUB '31(6)
   : GOSUB '204(1)
   : GOSUB '31(11)
   : INIT(30)C$()
   : STR(C$(1),1,4)="HDR1"
   : GOSUB '204(1)
   : GOSUB '31(11)
   : GOSUB '31(10)
   : GOSUB '31(6)
   : GOSUB '31(12)
   : GOSUB '204(0)
   : IF STR(C$(1),5,6)<>"      "THEN 800
0790 STR(C$(1),5,6)="BLANKS"
0800 PRINT HEX(0A0A0A0A);"     THE VSN. ON THE TAPE = ";STR(C$(1),5,6)
   : GOSUB '31(6)
   : O$="C"
   : V0=V0-1
   : IF V0>0THEN 110
   : GOSUB '248(1,0,4)
   : PRINT "LOAD THE UTILITY MENU"
   : LOAD DC F"START"
9121 DEFFN'42
   : S6=0
   : GOSUB 9353
   : GOSUB '31(6)
   : O$="O"
   : GOSUB '31(12)
   : GOSUB '204(0)
   : GOSUB 9391
   : IF S6=1THEN 9184
   : IF T9=1THEN 9184
   : IF V0$<>"N"THEN 9146
   : GOSUB '31(6)
   : RETURN
9146 GOSUB '243("ENTER THE VOLUME SERIAL NUMBER",6)
   : W3$=Q6$
   : GOSUB 9301
   : IF T9=1THEN 9184
   : IF S6=1THEN 9184
   : GOSUB '248(1,0,8)
   : GOSUB '31(12)
   : GOSUB '204(0)
   : GOSUB '245("ENTER TODAY'S DATE IN (YYDDD) FORMAT",5,0)
   : CONVERT Q9TO W5$,(#####)
9166 IF STR(C$(2),9,5)<=W5$THEN 9184
   : GOSUB '208(2,W5$,9,5," * ATTEMPT TO WRITE ON UNEXPIRED TAPE *",0,0)
   : IF T9=1THEN 9184
   : IF STR(C$(2),14,1)="0"THEN 9184
   : GOSUB '248(1,0,8)
   : GOSUB '243("ENTER THE DATASET NAME",17)
9178 GOSUB '208(1,Q6$,5,17," * THE DATASET NAMES DO NOT MATCH *",0,1)
9184 RETURN
9257 DEFFN'208(Z0,Z0$,Z8,Z9,Z1$,Z7,Z6)
   : T8,T9=0
   : IF STR(C$(Z0),Z8,Z9)=Z0$THEN 9271
9263 GOSUB '248(1,0,8)
   : PRINT HEX(0A0A);Z1$
   : T8=1
   : IF Z7=0THEN 9273
9271 RETURN
9273 IF Z6=1THEN 9288
9275 PRINT HEX(010A);"KEY 'C' TO CONTINUE, 'S' TO STOP"
   : T9,S6=0
9279 KEYIN Z$,9283,9283
   : GOTO 9279
9283 IF Z$="C"THEN 9297
   : IF Z$<>"S"THEN 9279
   : GOSUB '248(1,0,8)
   : GOSUB '31(6)
9288 GOSUB '245("ENTER 1 TO RE-ENTER LABEL, 0 TO MOUNT TAPE",1,0)
   : S6=Q9
   : IF Q9=1THEN 9296
   : IF Q9=0THEN 9294
   : GOSUB 9854
   : GOTO 9288
9294 GOSUB '243("REMOVE THE TAPE, KEY (EXEC) TO RESUME",0)
   : T9=1
9296 O$="C"
9297 GOSUB '248(1,0,8)
   : RETURN
9301 GOSUB '208(1,W3$,5,6," * THE VSN. DO NOT MATCH *",1,0)
   : IF T8=0THEN 9313
   : PRINT "     ---------------------"
   : PRINT "     THE INTERNAL VSN. = ";STR(C$(1),5,6)
   : PRINT "     THE EXTERNAL VSN. = ";W3$
   : GOSUB 9275
9313 RETURN
9353 IF O$="C"THEN 9357
   : STOP "   * ATTEMPT TO OPEN A NON-CLOSED FILE *"
9357 RETURN
9359 IF O$="O"THEN 9363
   : STOP "   * ATTEMPT TO CLOSE A CLOSED FILE *"
9363 RETURN
9365 DEFFN'201(Z1,Z2)
   : C$(1)=L$(Z1)
   : C$(2)=L$(Z1+1)
   : L0=80
   : IF Z2=0THEN 9385
   : IF Z2=2THEN 9383
   : STR(C$(1),1,4)="EOF1"
   : STR(C$(2),15,6)=W6$
   : GOTO 9385
9383 STR(C$(1),1,4)="EOF2"
9385 GOSUB '204(1)
   : GOSUB '31(11)
   : RETURN
9391 GOSUB 9417
   : IF V0$<>"N"THEN 9411
   : IF S8<>80THEN 9409
   : IF STR(C$(1),1,4)=HEX(E5D6D3F1)THEN 9401
   : IF STR(C$(1),1,4)<>"VOL1"THEN 9409
9401 Z6=1
   : Z7=0
   : Z1$=" * LABEL TYPES ARE NOT IDENTICAL *"
   : GOSUB 9263
9409 RETURN
9411 GOSUB '208(1,"VOL1",1,4," * LABEL TYPES ARE NOT IDENTICAL *",0,1)
   : IF S8<>80THEN 9401
   : RETURN
9417 S8=256*VAL(STR(B$,9,1))+VAL(STR(B$,10,1))
   : RETURN
9420 GOSUB '248(1,0,15)
   : PRINT "  SEARCH & LOAD THE PROGRAM"
   : RETURN