Listing of file='TPUT060A' on disk='vmedia/733-1004.wvd.zip'
# Sector 239, program filename = 'TPUT060A'
0012 REM . TPUT060A, 00-00(04/10/77), 10189A
0029 DIM C$(52)40,D$(2)41
: SELECT #107B
: O$="C"
: B9=0
: I9=1
: PRINT HEX(03);"2209A - CARD READER TO TAPE DATA TRANSFER UTILITY"
0080 GOTO 590
0090 DATA LOAD BT(N=82)/629,D$()
: IF STR(D$(2),41,1)=HEX(00)THEN 160
: IF STR(D$(2),41,1)=HEX(C0)THEN 170
: GOSUB '248(1,0,4)
: GOSUB '243(" * READ ERROR *, KEY (EXEC) TO CONTINUE",0)
: GOSUB '248(1,0,4)
: GOTO 90
0160 RETURN
0170 GOSUB '248(1,0,4)
: GOSUB '243("HOPPER IS EMPTY, RE-FILL DATA CARDS, KEY (EXEC) TO RESUME",0)
: GOSUB '248(1,0,4)
: GOTO 90
0210 GOSUB 90
: IF STR(D$(1),1,2)="&&"THEN 390
: IF STR(D$(1),1,4)="EOF1"THEN 460
0240 C$(I9)=STR(D$(1),1,40)
: STR(C$(I9+1),1,1)=STR(D$(1),41,1)
: STR(C$(I9+1),2,39)=STR(D$(2),1,39)
: IF (I9+1)*40>=S9THEN 300
: I9=I9+2
: GOTO 210
0300 L0=S9
: B9=B9+1
: GOSUB '204(1)
: GOSUB '31(11)
: INIT(20)C$()
: PRINT HEX(010A);
: PRINT " WRITE BLOCK # ";B9;" ON TAPE"
: I9=1
: GOTO 210
0390 GOSUB '31(10)
: GOSUB '31(10)
: GOSUB '31(6)
: O$="C"
: GOSUB '248(1,0,4)
: PRINT HEX(010A);" END OF PROGRAM"
: STOP
0460 IF I9=1THEN 510
: L0=S9
: B9=B9+1
: GOSUB '204(1)
: GOSUB '31(11)
0510 GOSUB '31(10)
: L0=-9999
: CONVERT B9TO STR(D$(2),15,6),(######)
: GOSUB 930
: GOSUB 90
: L0=-9999
: GOSUB 930
: GOTO 210
0590 GOSUB '243("LOAD CARDS INTO CARD READER, KEY (EXEC) TO RESUME",0)
: GOSUB 90
: T=0
: GOSUB '243("MOUNT THE TAPE, KEY (EXEC) TO RESUME",0)
: GOSUB '31(13)
: GOSUB '248(1,0,8)
0630 GOSUB '243("ENTER THE LABEL TYPE OF CARD DATA FILE (I/A/N)",1)
: V0$=Q6$
: IF V0$="I"THEN 700
: IF V0$="A"THEN 710
: IF V0$="N"THEN 770
: GOSUB 9854
: GOTO 630
0700 T=1
0710 GOSUB '210(1)
: GOSUB 90
: GOSUB '210(3)
: GOSUB 90
: GOSUB '210(5)
: GOSUB 90
0770 GOSUB '42
: IF V0$<>"N"THEN 850
0790 GOSUB '243("ENTER THE OBJECT FILE DATA TYPE (E=EBCDIC,A=ASCII)",1)
: T=0
: IF Q6$="A"THEN 850
: T=1
: IF Q6$="E"THEN 850
: GOSUB 9854
: GOTO 790
0850 GOSUB '248(1,0,4)
: INIT(20)C$()
: GOTO 240
0880 DEFFN'210(Z0)
: L$(Z0)=STR(D$(1),1,40)
: STR(L$(Z0+1),1,1)=STR(D$(1),41,1)
: STR(L$(Z0+1),2,39)=STR(D$(2),1,39)
: RETURN
0930 C$(1)=STR(D$(1),1,40)
: STR(C$(2),1,1)=STR(D$(1),41,1)
: STR(C$(2),2,39)=STR(D$(2),1,39)
: GOSUB '204(1)
: GOSUB '31(11)
: RETURN
9121 DEFFN'42
: GOSUB 9353
9125 GOSUB '31(6)
: O$="O"
: GOSUB '31(12)
: GOSUB '204(0)
: GOSUB 9391
: IF T9=1THEN 9125
: IF V0$<>"N"THEN 9147
: S9=80
: GOSUB '31(6)
: U1=0
: RETURN
9147 GOSUB 9301
: IF T8=1THEN 9125
: GOSUB '248(1,0,8)
: GOSUB '31(12)
: GOSUB '204(0)
: GOSUB '245("ENTER TODAY'S DATE IN (YYDDD) FORMAT",5,0)
: CONVERT Q9TO W5$,(#####)
: IF STR(C$(2),9,5)<=W5$THEN 9177
9163 GOSUB '208(2,W5$,9,5," * ATTEMPT TO WRITE ON UNEXPIRED TAPE *",0,0)
: IF T9=1THEN 9125
: IF STR(C$(2),14,1)="0"THEN 9177
: GOSUB '248(1,0,8)
: GOSUB '243("ENTER THE DATASET NAME",17)
9173 GOSUB '208(1,Q6$,5,17," * THE DATASET NAMES DO NOT MATCH *",0,1)
: IF T8=1THEN 9125
9177 GOSUB '31(1)
: GOSUB '201(3,0)
: GOSUB '201(5,0)
: CONVERT STR(L$(5),6,5)TO S9
: GOSUB '31(10)
: U1=0
: RETURN
9257 DEFFN'208(Z0,Z0$,Z8,Z9,Z1$,Z7,Z6)
: T8,T9=0
: IF STR(C$(Z0),Z8,Z9)=Z0$THEN 9271
9263 GOSUB '248(1,0,8)
: PRINT HEX(0A0A);Z1$
: T8=1
: IF Z7=0THEN 9273
9271 RETURN
9273 IF Z6=1THEN 9287
: PRINT HEX(010A);"KEY 'C' TO CONTINUE, 'S' TO STOP"
: T9=0
9279 KEYIN Z$,9283,9283
: GOTO 9279
9283 IF Z$="C"THEN 9293
: IF Z$<>"S"THEN 9279
9287 GOSUB '243("REMOVE THE TAPE, KEY (EXEC) TO RESUME",0)
: T9=1
: GOSUB '243("MOUNT THE TAPE, KEY (EXEC) TO RESUME",0)
: GOSUB '31(13)
9293 GOSUB '248(1,0,10)
: RETURN
9301 GOSUB '208(1,STR(L$(1),5,6),5,6," * THE VSN. DO NOT MATCH *",1,0)
: IF T8=0THEN 9313
: PRINT " ---------------------"
: PRINT " THE INTERNAL VSN. = ";STR(C$(1),5,6)
9309 PRINT " THE EXTERNAL VSN. = ";STR(L$(1),5,6)
: GOSUB 9287
9313 RETURN
9353 IF O$="C"THEN 9357
: STOP " * ATTEMPT TO OPEN A NON-CLOSED FILE *"
9357 RETURN
9359 IF O$="O"THEN 9363
: STOP " * ATTEMPT TO CLOSE A CLOSED FILE *"
9363 RETURN
9365 DEFFN'201(Z1,Z2)
: C$(1)=L$(Z1)
: C$(2)=L$(Z1+1)
: L0=80
: IF Z2=0THEN 9385
: IF Z2=2THEN 9383
: STR(C$(1),1,4)="EOF1"
: STR(C$(2),15,6)=W6$
: GOTO 9385
9383 STR(C$(1),1,4)="EOF2"
9385 GOSUB '204(1)
: GOSUB '31(11)
: RETURN
9391 GOSUB 9417
: IF V0$<>"N"THEN 9409
: IF S8<>80THEN 9407
: IF STR(C$(1),1,4)<>"VOL1"THEN 9407
9399 Z6=1
: Z7=0
: Z1$=" * LABEL TYPES ARE NOT IDENTICAL *"
: GOSUB 9263
9407 RETURN
9409 GOSUB '208(1,"VOL1",1,4," * LABEL TYPES ARE NOT IDENTICAL *",0,1)
: IF S8<>80THEN 9399
: RETURN
9417 S8=256*VAL(STR(B$,9,1))+VAL(STR(B$,10,1))
: RETURN