Listing of file='@DOSDEL' on disk='vmedia/734-8446-A.wvd.zip'
# Sector 1711, program filename = '@DOSDEL'
0010 REM %^ @DOSDEL UTILITY BY KIRIT BAXI EAME R&D
0020 REM % Version 1.0 20 JUN 1991
0030 REM ***********************************************
0040 REM * *
0050 REM * DELETE Program *
0060 REM * *
0070 REM ***********************************************
0100 REM % DEFINE VARIABLES
0110 DIM A$(16)32,D$(16),A$1,B$4,C$16,D$3,E$2,F$2,G$2,H$8,J$11,L$2,M$4,N$1,O$1
,P$1,Q$1,V$11
: PRINT HEX(06)
0120 REM % CHECK IF DISK READY
: DATA LOAD BA T#N,(0)D$()
: ERRORE=ERR
: IF E=98THEN DO
: PRINT HEX(070E);"Please insert Diskette in Drive"
: END DO
: IF E=98THEN 400
0130 REM ADDRESS SET BY DOS
0140 REM % FIND DISK TYPE AND SET OFFSET SECTOR
0150 DATA LOAD BMT#N,(1440,L)A$()
: ERRORE=ERR
: IF E=98THEN Y=10
: V=13
: GOTO 170
0160 DATA LOAD BMT#N,(4800,L)A$()
: ERRORE=ERR
: IF E=98THEN Y=30
: V=27
: GOTO 170
0170 A1,B,C,D,D2=0
: IF Y=0THEN DO
: Y=10
: V=13
: END DO
0180 REM % TRANSFER THE FILE T0 DELETE TO J$
: A9=0
: IF I1$="*.*"THEN A9=1
: MAT SEARCHI1$,="."TO E$
: A=VAL(E$,2)
: IF A=0THEN 190
: STR(J$,1,8)=STR(I1$,1,A-1)
: STR(J$,9,3)=STR(I1$,A+1,3)
: $TRAN(STR(J$,1,11),HEX(2000))R
: GOTO 210
0190 J$=I1$
0200 REM % LAST CHANCE!!
0210 PRINT HEX(0E07);"Are you sure (Y/N)?";
0220 PRINT HEX(02050F);
: KEYIN A$
: A$=A$OR HEX(20)
: IF A$="n"THEN 400
: IF A$<>"y"THEN 220
0230 PRINT A$
0240 REM
0250 REM % GET THE DIRECTORY INFORMATION AND CHECK FOR FILES TO DELETE
0260 FOR Z=YTO Y+VSTEP 2
0270 DATA LOAD BMT#N,(Z,L)A$()
0280 FOR X=1TO 16
: IF STR(A$(X),1,1)=HEX(00)OR STR(A$(X),1,1)=HEX(E5)OR STR(A$(X),12,1)=HEX(
28)OR STR(A$(X),12,1)=HEX(03)OR STR(A$(X),12,1)>HEX(7F)THEN GOTO 340
: IF STR(A$(X),12,1)=HEX(27)OR STR(A$(X),12,1)=HEX(02)OR STR(A$(X),12,1)=HE
X(01)THEN 290
: ELSE GOTO 300
0290 GOTO 340
0300 IF A9=1THEN 330
0310 IF STR(A$(X),1,11)=STR(J$,1,11)THEN STR(A$(X),1,1)=HEX(E5)
0320 IF STR(A$(X),1,11)=STR(J$,1,11)THEN GOTO 390
: ELSE GOTO 340
0330 REM % DEL FILES IN ROOT ONLY
: IF STR(A$(X),12,1)>HEX(10)THEN STR(A$(X),1,1)=HEX(E5)
0340 NEXT X
0350 DATA SAVE BMT#N,(Z,L)A$()
0360 NEXT Z
0370 GOTO 400
0380 % Delete ############ #####
0390 DATA SAVE BMT#N,(Z,L)A$()
0400 REM % RET > COMMAND PROC
: PRINT
: I4$="R"
: LOAD T"@DOS"