image of READY prompt

Wang2200.org

Listing of file='BREAKOUT' on disk='vmedia/best_of_BD_fules.wvd.zip'

# Sector 363, program filename = 'BREAKOUT'
0010 DIM A$(15)64
   : INIT(80)A$()
   : A=32
   : B=6
   : PRINT HEX(03);
   : Z=5
   : GOSUB 250
0020 INIT("#")A$(4)
   : INIT(8B)A$(5)
   : INIT("=")A$(6)
   : FOR I=1TO 64STEP 4
   : STR(A$(4),I,1),STR(A$(5),I,1),STR(A$(6),I,1)="("
   : NEXT I
   : FOR I=4TO 64STEP 4
   : STR(A$(4),I,1),STR(A$(5),I,1),STR(A$(6),I,1)=")"
   : NEXT I
0030 B=B-1
   : IF B<1THEN 210
   : E1=-1
   : K=INT(RND(1)*Z)-2
   : E=14
   : D=INT(RND(1)*(Z-2))+A+1
0040 KEYIN A$,50,50
0050 ON VAL(A$)-48GOTO 60,130,70,80,130,90,100,130,110
   : GOTO 130
0060 A1=-1
   : GOTO 120
0070 A1=1
   : GOTO 120
0080 A1=-3
   : GOTO 120
0090 A1=3
   : GOTO 120
0100 A1=-5
   : GOTO 120
0110 A1=5
0120 IF A+A1<1THEN 130
   : IF A+A1>65-ZTHEN 130
   : A=A+A1
0130 INIT(80)A$(15)
   : IF STR(A$(E),D,1)<>HEX(80)THEN 200
   : STR(A$(15),A,Z)="-------"
   : STR(A$(15),64,1)=HEX(01)
0140 STR(A$(E),D,1)="."
   : PRINT HEX(01);"SCORE=";S;"     BALLS LEFT";B-1;HEX(01);
   : MAT PRINT A$;
   : STR(A$(E),D,1)=HEX(80)
0150 IF D+K>64THEN 170
   : IF D+K<1THEN 170
0160 E=E+E1
   : D=D+K
   : IF E<2THEN 180
   : IF E=15THEN 190
   : GOTO 40
0170 K=-K
   : GOTO 160
0180 E1=-E1
   : GOTO 40
0190 E=15
   : E1=-1
   : IF D>A+(Z-1)THEN 310
   : IF D<ATHEN 310
   : K=D-A-3+INT(6/Z)
   : GOTO 130
0200 STR(A$(E),INT((D-1)/4)*4+1,4)=HEX(80808080)
   : S=S+(7-E)
   : E1=-E1
   : GOTO 130
0210 E$="GAME OVER"
0220 INIT(80)A$(15)
   : STR(A$(15),A,Z)="-------"
   : STR(A$(15),64,1)=HEX(01)
0230 STR(A$(E),D,1)="."
   : PRINT HEX(01);"SCORE=";S;"     BALLS LEFT";B-1;HEX(01);
   : MAT PRINT A$;
0240 FOR I=1TO 5
   : PRINT HEX(010A0A0A0A0A0A0A);TAB(29);E$
   : FOR O=1TO 50
   : NEXT O
   : PRINT HEX(010A0A0A0A0A0A0A);TAB(60);" "
   : FOR O=1TO 50
   : NEXT O
   : NEXT I
   : IF B<1THEN 320
   : GOTO 30
0250 PRINT "KEYIN 'P' TO CHANGE PADDLE SIZE, AND 'B' TO CHANGE BALL NO."
   : PRINT HEX(0A0A0A0A0A0A0A0A0A0A)
0260 PRINT HEX(0C);"PADDLE=";Z;"BLOCKS LONG","NUMBER OF BALLS=";B-1
0270 KEYIN A$,280,270
   : GOTO 270
0280 IF A$=HEX(0D)THEN 300
   : IF A$="B"THEN 290
   : IF A$<>"P"THEN 270
   : Z=Z+2
   : IF Z<9THEN 260
   : Z=3
   : GOTO 260
0290 B=B+2
   : IF B<9THEN 260
   : B=2
   : GOTO 260
0300 PRINT HEX(03)
   : RETURN
0310 E$="LOSTBALL"
   : GOTO 220
0320 END