Listing of file='MAZE' on disk='vmedia/best_of_BD_fules.wvd.zip'
# Sector 385, program filename = 'MAZE'
0010 DIM B$4,Q$(15)64,D$(15)64,R$(15)64,A$(15)64
: C=4
: D=61
: N1$="5"
: PRINT HEX(03);TAB(28);HEX(CDC1DAC5)
0020 PRINT " THIS WAS MADE POSSIBLE BY 'B&D FULES INC.' WHICH HAS PUT TH
EIR TIME AND EFFORT INTO BRINGING THIS GAME TO LIFE."
0030 PRINT
: INPUT "ENTER NICKNAME (MAX.=4 LETTERS)",B$
0040 PRINT
: INPUT "DO YOU NEED INSTRUCTIONS (SUGGESTED FOR 1'st TIME)",D$
: IF STR(D$,1,1)="Y"THEN 50
: J=3
: GOTO 240
0050 PRINT HEX(03)
: PRINT " HELLO ";B$;", WELCOME TO ";HEX(22);"MAZE";HEX(22);".";" A
FTER A FEW TRIES YOU WILL SEE THAT THE MAZE IS ";
0060 PRINT "SYSTEMATICALLY ARRANGED. HOWEVER, YOU WILL ALSO QUICKLY NOTICE TH
AT IT IS DARK IN THIS LABYRINTH OF PASSAGEWAYS SO YOU CAN'T SEE A DOOR
UNTIL YOU ARE RIGHT NEXT TO IT.";
0070 PRINT " THE OBJECT OF THE GAME IS TO SUCCESSFULLY REACH THE TOP OF TH
E SCREEN IN THE ALLOTTED NUMBER OF MOVES.";
0080 PRINT " WHEN THE COMPUTER ASKS YOU WHAT SKILL LEVEL, AN AVERAGE RE
PLY WOULD BE ABOUT TWO. A VERY DIFFICULT SKILL LEVEL WOULD BE ZERO AND A
VERY EASY ONE WOULD BE ABOUT FIVE. PLEASE NOTE:"
0090 KEYIN A$,100,100
: GOTO 90
0100 PRINT HEX(03);" A HIGHER NUMBER WILL NOT MAKE THE MAZE EASIER, IT WIL
L ONLY MAKE IT POSSIBLE TO TAKE MORE TIME TO GET THROUGH THE MAZE WIT
HOUT DYING OF EXHAUSTION."
0110 PRINT " MOVEMENT IS ACCOMPLISHED BY USING THE NUMERIC KEYPAD:"
0120 PRINT TAB(28);" ";HEX(8A)
0130 PRINT TAB(28);" 8"
0140 PRINT TAB(28);HEX(5F);"4 6\84"
0150 PRINT TAB(28);" 2"
0160 PRINT TAB(28);" v"
0170 PRINT " TO MOVE UP WAIT UNTIL YOU ARE TOLD THERE IS A DOOR ABOVE YO
U. WHEN YOU ARE MOVING SIDEWAYS YOU WILL AUTOMATICALLY STOP AT A DOOR."
0180 KEYIN A$,190,190
: GOTO 180
0190 PRINT HEX(03);"THIS IS A SAMPLE MAZE FOR YOUR CONVENIENCE;"
0200 J=J+1
: IF J=1THEN 260
: IF J=2THEN 210
: IF J>2THEN 320
0210 FOR K=1TO 15
: PRINT Q$(K);
: FOR O=1TO 40
: NEXT O
: NEXT K
0220 KEYIN A$,230,230
: GOTO 220
0230 PRINT
: PRINT TAB(30);"GOOD LUCK!"
: PRINT TAB(30);"The Management"
0240 C=4
: D=61
: PRINT HEX(06)
: PRINT
: PRINT "WHAT SKILL LEVEL, ";B$;
: INPUT P
: IF P>5THEN 250
: P=P*75+250
: GOTO 260
0250 P=400
0260 PRINT HEX(03);
: C=4
: D=61
: INIT(20)R$(),A$(),D$(),Q$()
: FOR I=1TO 15STEP 2
: INIT(80)A$(I)
: INIT("-")R$(I)
: NEXT I
0270 FOR I=1 TO 15
: INIT(80)STR(A$(I),1,1)
: INIT(86)STR(R$(I),1,1)
: NEXT I
0280 FOR I=1 TO 15
: INIT(80)STR(A$(I),64,1)
: INIT(86)STR(R$(I),64,1)
: NEXT I
0290 FOR I=1 TO 9 STEP 4
: A=INT(RND(1)*(D-C))+C
: STR(A$(I),A,1)=" "
: C=INT(RND(1)*(A-4))+4
: D=INT(RND(1)*(61-A))+A
: STR(A$(I+2),C,1),STR(A$(I+2),D,1)=" "
0300 E=INT(RND(1)*(D-C))+C
: IF E=A THEN 300
: STR(A$(I+1),E,1)=HEX(80)
: NEXT I
: A=INT(RND(1)*(D-C))+C
: STR(A$(13),A,1)=" "
: STR(A$(14),1,1),STR(A$(14),64,1)=HEX(80)
0310 REM ****** BORED COMPLETE ******
: GOSUB 490
: GOTO 200
0320 STR(R$(14),32,1)=HEX(8D)
: B=14
: C=32
0330 PRINT HEX(01);"Y";
: PRINT HEX(01);
: FOR I=1 TO 14
: PRINT R$(I)
: NEXT I
0340 IF STR(A$(B+1),C,1)<>HEX(80)THEN 460
: IF STR(A$(B-1),C,1)<>HEX(80)THEN 440
0350 IF STR(A$(B-1),C,1)<>HEX(80)THEN 440
0360 CONVERT PTO P$,(###)
: PRINT HEX(01);" ";
: PRINT HEX(01);"YOU HAVE ";P$;" MORE MOVES, ";B$;
0370 G=G+1
: KEYIN N1$,380,500
: IF G>10THEN 380
: GOTO 370
0380 G=0
: IF N1$="5"THEN 370
: IF N1$<"2"THEN 370
: IF N1$>"8"THEN 370
: CONVERT N1$ TO A
: P=P-1
: IF P<1 THEN 480
: A=A/2
: ON A GOTO 390,400,410,420
: GOTO 340
0390 IF STR(A$(B+1),C,1)=HEX(80) THEN 470
: STR(R$(B),C,1),STR(Q$(B),C,1)="."
: B=B+1
: STR(R$(B),C,1),STR(Q$(B),C,1)=HEX(8D)
: GOTO 330
0400 IF STR(A$(B),C-1,1)=HEX(80) THEN 470
: STR(R$(B),C,1),STR(Q$(B),C,1)="."
: C=C-1
: STR(R$(B),C,1),STR(Q$(B),C,1)=HEX(8D)
: GOTO 330
0410 IF STR(A$(B),C+1,1)=HEX(80) THEN 470
: STR(R$(B),C,1),STR(Q$(B),C,1)="."
: C=C+1
: STR(R$(B),C,1),STR(Q$(B),C,1)=HEX(8D)
: GOTO 330
0420 IF STR(A$(B-1),C,1)=HEX(80) THEN 470
: STR(R$(B),C,1),STR(Q$(B),C,1)="."
: B=B-1
: IF B<2THEN 430
: STR(R$(B),C,1),STR(Q$(B),C,1)=HEX(8D)
: GOTO 330
0430 PRINT HEX(03)
: FOR H7=1 TO 6
: PRINT HEX(030A0A0A0A0A0A0A);
: FOR I=1 TO 80
: NEXT I
: PRINT TAB(25);"YOU DID IT!!"
: PRINT TAB(17);"WITH ONLY";P;"MOVES TO SPARE!!"
: FOR I=1 TO 60
: NEXT I
: NEXT H7
: GOTO 510
0440 PRINT HEX(01);" ";
: PRINT HEX(01);"THERE IS A DOOR ABOVE YOU, ";B$;
: P=P-1
: FOR I=1 TO 100
: NEXT I
: IF B/2<>INT(B/2) THEN 370
: IF STR(R$(B-1),C,1)="."THEN 450
: STR(R$(B-1),C,1)=" "
: FOR I=1 TO 14
: PRINT R$(I);
: NEXT I
: N1$="5"
: GOTO 370
0450 N1$="5"
: GOTO 370
0460 PRINT HEX(01);"THERE IS A DOOR BELOW YOU, ";B$;
: P=P-1
: FOR I=1 TO 100
: NEXT I
: IF B/2<>INT(B/2) THEN 350
: N1$="5"
: GOTO 350
0470 N1$="5"
: PRINT HEX(01);"YOU HIT A WALL ";B$;" ! ! ! ! ";
: FOR I=1TO 200
: NEXT I
: P=P-2
: GOTO 330
0480 PRINT HEX(03);"YOU JUST DIED OF HUNGER AND EXHAUSTION!"
: PRINT "THE SOLUTION IS..."
: FOR I=1 TO 200
: NEXT I
: GOTO 510
0490 MAT COPY A$() TO Q$()
: FOR I=1 TO 15
: ADD(Q$(I),0B)
: NEXT I
: RETURN
0500 N1$="5"
: PRINT HEX(03);
: INPUT "ENTER CODE NAME",C$
: IF LEN(C$)<3THEN 330
: IF STR(C$,1,1)<>"B"THEN 330
: IF STR(C$,3,1)<>"D"THEN 330
: FOR I=1 TO 15
: PRINT Q$(I)
: NEXT I
: PRINT HEX(0C0C);
: STOP
: GOTO 330
0510 PRINT HEX(03);B$;" THE SOLUTION WAS;"
: FOR I=1 TO 15
: FOR L=1TO 50
: NEXT L
: PRINT Q$(I)
: NEXT I
: PRINT HEX(0C0C)
0520 KEYIN A$,530,530
: GOTO 520
0530 PRINT HEX(03)
: INPUT "PLAY AGAIN",H$
: N1$="5"
: IF STR(H$,1,1)="Y"THEN 240
: PRINT HEX(030A0A0A0A0A);TAB(23);"THIS HAS BEEN..."
: PRINT
: FOR I=1TO 100
: NEXT I
0540 PRINT TAB(19);"A B&D FULES PRODUCTION"
: PRINT TAB(25);"THANK YOU."