Listing of file='ASKAWHAT' on disk='vmedia/bsc_3271_rel_1.14.04.wvd.zip'
# Sector 1181, program filename = 'ASKAWHAT'
0010 REM ASKAWHAT 03/20/91
0020 COM D8$20,N$64,N$(16)8,A$64,B$1,C$1,A,B,C,W$64,Z$64
0030 DIM D,D1,I,A1$(16)16,A1$
0040 $PSTAT="3270STRT"
0042 SELECT CI 001,INPUT 001,LIST 005(80),CO 005(80),PRINT 005(80)
0044 PRINT HEX(03020402000E);" WHAT PROCEDURE? WANG 2200/3270 Release 01.1
4.02."
0046 PRINT HEX(020400000F)
0050 INIT(".")N$,A$
0080 IF STR(A$,#TERM,1)<>"."THEN 140
0090 REM %.Configuration options
0100 REM .Terminals -----Name-------Functions
0110 A$="1.........Configuration 123456789A."
: IF STR(A$,#TERM,1)<>"."THEN 140
0120 A$=".2........the Supervisor 123..6789.."
: IF STR(A$,#TERM,1)<>"."THEN 140
0130 A$="12345678..an Operator 1.3...7.9..."
0140 A1$=STR(A$,28)
0150 REM Offline-TermnalsFunction
0160 STR(N$,17)="1.......12345678"
: REM /.Configuration
0170 STR(N$,33)="12......123456.."
: REM /.Supervisor
0180 STR(N$,49)="123456781...5..."
: REM /.Operator
0190 REM
0210 INIT(0A)D8$
: STR(D8$,1,1)=HEX(01)
: Z$=" "
0220 DIM E$64
: A=1
: RESTORE 2
: READ E$
0230 N$(1)="ASKAWHAT"
: N$(2)="ASKACALL"
: N$(6)="ASKASAVE"
0240 N$(3)="ASKAEMUL"
: N$(4)="ASKAPARM"
: N$(7)="ASKALOAD"
0260 PRINT "TO OPERATE -- Press S.F. KEY or DIGIT corresponding to name,"
0270 PRINT "or position # via RETURN, SPACE or BACKSPACE and key RUN"
0280 PRINT " Functions for ";STR(A$,11,17);" on Term=";#TERM;" Part.=";#PART;
0290 D=5
: D1=2
0300 GOSUB 660
: REM /SET DISPLAY
0310 ON IGOTO 340
0320 % ' ## to ########################################
0330 GOSUB 390
: REM /K.B./CRT INTERACTION
0340 E$=A1$(A)
: W$=" "
0350 B$=STR(E$,9,1)
: $PSTAT=" "
0360 LOAD DC T#0,STR(E$,1,8)
0370 DEFFN'0
: W$=" "
: COM CLEAR
: LOAD DC T#0,"START"
0380 REM %^.K.B./CRT INTERACTION
0390 DIM A$(1)13,M$(1)2
0400 A$(1)=HEX(080D2082313233343536373839)
0410 REM ......CRBSRN.1.2.3.4.5.6.7.8.9
0420 A=1
: GOTO 560
0430 KEYIN C$,,600
0440 REM LOWER PAD
0450 MAT SEARCHA$(),=C$TO M$()
: C=VAL(STR(M$(1),2))
0460 IF C=0THEN 430
0470 PRINT STR(D8$,1,A+D-1);BOX(-1,-55);TAB(D1+1)
0480 ON CGOTO 550,530,530,630
0490 REM .....BS..CR..SP..RUN
0500 REM DIGIT
0510 AND (C$,0F)
: GOTO 600
0520 REM CR CARRIAGE RETURN or SPACE
0530 A=A+1
: IF A<=ITHEN 560
: A=1
: GOTO 560
0540 REM BS BACKSPACE
0550 A=A-1
: IF A>0THEN 560
: A=I
0560 PRINT STR(D8$,1,A+D-1);BOX(1,55);TAB(D1);"#";HEX(08);
0570 SELECT PRINT 005
0580 GOTO 430
0590 REM S.F.
0600 IF C$=HEX(00)THEN 370
0610 C=VAL(C$)
: IF C>ITHEN 560
0620 PRINT STR(D8$,1,A+D-1);BOX(-1,-55);TAB(D1+1)
: A=C
0630 PRINT STR(D8$,1,A+D-1);BOX(1,7);TAB(D1);"*";
0640 RETURN
0650 REM % ** SET DISPLAY ***
0660 I=0
: RESTORE
: PRINT
: B=0
0670 READ E$
: IF E$=" "THEN RETURN
: B=B+1
0680 IF STR(A1$,B,1)="."THEN 670
: A1$(I+1)=E$
0690 A$=STR(E$,10)
: I=I+1
: PRINTUSING 320,I,A$
: GOTO 670
0700 REM + ....!....1....!....2....!....3
0710 DATA "B327010 <Attach to a running 3270 cluster"
0720 DATA "ASKASTR1<Load a 3270 cluster"
0730 DATA "3270OFFL Load 3270 off-line functions"
0740 DATA "ASKAEMUL<Create a new 3270 configuration"
0750 DATA "ASKASTRT Change or create any T.C. configuration"
0760 DATA "ASKASTR1 Load any T.C. configuration"
0770 DATA "B3270MON Monitor cluster status display"
0780 DATA "B327030 Detach from a running 3270 cluster"
0790 DATA "@PSTAT Monitor 2200 partition status"
0800 DATA " "