image of READY prompt

Wang2200.org

Listing of file='CRYPTO' on disk='vmedia/games.wvd.zip'

# Sector 861, program filename = 'CRYPTO'
0010 F9$="CRYPTOGRAM GAME"
   : REM T.OLSEN  WANG LABS 2200 R&D
0020 DIM Y$64,A$64,B$64,C$64,D$26,E$26,F$26,Z$1,Z1$1
0030 A9$="SOURCE TEXT"
   : B9$="ENCRYPTED TEXT"
   : C9$="YOUR SOLUTION"
0040 PRINT HEX(03)
0050 %TRIES MADE=####  CORRECT=##  CLUES=##
0060 D$="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
0070 GOSUB 80
   : STOP "KEY IN APPROPRIATE FUNCTION"
0080 PRINT HEX(010A0A0A0A0A0A0A0A)
0090 PRINT F9$;" FUNCTION KEYS ARE INPUT COMMANDS"
0100 PRINT "LETTERS CORRECT=";STR(F$,1,26)
0110 PRINT "KEY 0  TRY A NEW VALUE"
0120 PRINT "KEY 1  GET A CLUE"
0130 PRINT "KEY 2-14 AND 17-31 CANNED PHRASES"
0140 PRINT "KEY 15 ENTER A NEW PHRASE"
0150 PRINT "KEY 16 IF YOU CAN TYPE IN THE WHOLE PHRASE"
0160 RETURN
0170 DEFFN'15
   : PRINT HEX(03),F9$
0180 PRINT "TYPE A PHRASE ON ONE LINE WHICH WILL BE ENCRYPTED"
0190 A$=" "
   : INPUT A$
0200 A1=LEN(A$)
   : B$,C$=" "
0210 PRINT HEX(03);"RANDOMIZING"
0220 FOR C=1 TO A1
   : T=RND(1)
   : NEXT C
0230 C,T,T1=0
   : F$=" "
0240 PRINT "BUSY ENCRYPTING"
0250 GOSUB 630
   : REM ENCRYPT ALPHABET
0260 GOSUB 690
   : REM ENCRYPT PHRASE
0270 PRINT HEX(03);
   : GOSUB 80
0280 DEFFN'0
   : GOSUB 80
   : PRINT HEX(01);"ENCRYPTED PHRASE="
   : PRINT B$
   : PRINT C$
0290 Z$=" "
   : INPUT "CHARACTER=",Z$
0300 IF Z$=" "THEN 280
0310 X=1
0320 IF Z$=STR(D$,X,1)THEN 340
0330 X=X+1
   : IF X<27THEN 320
   : GOTO 280
0340 Z1$=" "
   : PRINT HEX(010A0A0A0A);
   : INPUT "CODED AS=",Z1$
0350 IF Z1$=" "THEN 340
0360 T=T+1
   : PRINT "TRY NUMBER ";T
0370 IF Z1$=STR(E$,X,1)THEN 400
0380 PRINT "YOU MISSED, TRY AGAIN"
0390 GOTO 480
0400 PRINT "CORRECT                       "
0410 T1=T1+1
0420 FOR W=1 TO A1
0430  IF Z1$<>STR(B$,W,1)THEN 450
0440  STR(C$,W,1)=Z$
0450 NEXT W
0460 W=0
0470 W=W+1
   : IF STR(D$,W,1)<>Z$THEN 470
   : STR(F$,W,1)=Z$
0480 IF A$<>C$THEN 280
0490 PRINT HEX(01);"COMPLETED PHRASE="
   : PRINT C$
0500 PRINT "YOU FINISHED";TAB(63)
0510 PRINT TAB(63)
   : PRINT TAB(63)
   : PRINT TAB(63)
   : PRINT HEX(0C0C0C)
0520 PRINTUSING 50,T,T1,C
0530 STOP
0540 DEFFN'1
   : C=C+1
0550 Y=INT(A1*RND(1))+1
0560 IF STR(C$,Y,1)<>" "THEN 550
0570 IF STR(A$,Y,1)=" "THEN 550
0580 Z$=STR(A$,Y,1)
   : Z1$=STR(B$,Y,1)
0590 PRINT HEX(010A0A0A);"CHARACTER=";TAB(63)
0600 PRINT "CLUE NO.=";C;TAB(63)
0610 PRINT "CHAR ";Z$;"=";Z1$;TAB(63)
0620 PRINT TAB(63)
   : GOTO 420
0630 E$=" "
   : REM ENCRYPT ALPHABET
0640 FOR X=1 TO 26
0650 Y=INT(26*RND(1))+1
0660 IF STR(E$,Y,1)<>" " THEN 650
0670 STR(E$,Y,1)=STR(D$,X,1)
0680 NEXT X
   : RETURN
0690 B$=" "
   : REM ENCRYPT PHRASE
0700 FOR W=1 TO A1
0710 Z$=STR(A$,W,1)
0720  FOR X=1 TO 26
0730   IF Z$=STR(D$,X,1) THEN 750
0740  NEXT X
   : STR(B$,W,1)=Z$
   : STR(C$,W,1)=Z$
   : GOTO 770
0750  REM CHARACTER TO BE ENCRYPTED IS ALPHABETIC
0760 STR(B$,W,1)=STR(E$,X,1)
   : X=26
   : NEXT X
0770 NEXT W
   : RETURN
0780 DEFFN'16
   : PRINT "TYPE THE ENTIRE PHRASE EMBEDDED IN DOUBLE QUOTES."
0790 INPUT Y$
   : T=T+1
   : IF A$<>Y$THEN 380
0800 T1=T1+1
   : GOTO 500
0810 DEFFN'2
0820 A$="THE QUICK BROWN FOX JUMPED OVER THE LAZY DOG'S BACK."
0830 GOTO 200
0840 DEFFN'3
0850 A$="THE WANG 2200-A IS ABLE TO PLAY CRYPTO GAMES."
0860 GOTO 200
0870 DEFFN'4
0880 A$="WE CAN ALSO DO PAYROLLS, INVENTORY, TEACHING AIDS, PLUS"
0890 GOTO 200
0900 DEFFN'5
0910 A$="USE AN ACE AXE TO RUN KIDS OFF OF YOUR BIKE PATH."
0920 GOTO 200
0930 DEFFN'6
0940 A$="NOBODY SHOOTS AT SANTA CLAUS. ALFRED E. SMITH"
0950 GOTO 200
0960 DEFFN'7
0970 A$="NO MATTER HOW THIN YOU SLICE IT, IT'S STILL BOLONEY."
0980 GOTO 200
0990 DEFFN'8
1000 A$="THOUGH IT BE HONEST, IT IS NEVER GOOD TO BRING BAD NEWS."
1010 GOTO 200
1020 DEFFN'9
1030 A$="GOOD WINE IS A GOOD FAMILIAR CREATURE IF IT BE WELL USED."
1040 GOTO 200
1050 DEFFN'10
1060 A$="FAULTILY FAULTLESS, ICILY REGULAR, SPLENDIDLY NULL. MAUD."
1070 GOTO 200
1080 DEFFN'11
1090 A$="POETS ARE THE HIEROPHANTS OF AN UNAPPREHENDED INSPIRATION."
1100 GOTO 200
1110 DEFFN'12
1120 A$="IS THERE SUCH A WORD AS ANTIDISESTABLISHMENTARIANISM?"
1130 GOTO 200
1140 DEFFN'13
1150 A$="THE LETTERS OF THE ALPHABET ARE 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"
1160 GOTO 200
1170 DEFFN'14
1180 STOP "NO PHRASE STORED FOR THIS FUNCTION KEY."
1190 GOTO 200
1200 DEFFN'17
1210 A$="LOUD LAMB BAAS SEND ECHO OVER THIS FIVE ACRE FARM UNIT."
1220 GOTO 200
1230 DEFFN'18
1240 A$="ABLE WAS I ERE I SAW ELBA.  NAPOLEON BONAPARTE"
1250 GOTO 200
1260 DEFFN'19
1270 A$="SATOR, AREPO, TENET, OPERA, ROTAS.  MAGIC SQUARE"
1280 GOTO 200
1290 DEFFN'20
1300 A$="ALASKAN USED IVORY OF WALRUS TUSK FOR NEW CARVED CURIOSITY."
1310 GOTO 200
1320 DEFFN'21
1330 A$="REALIZE THE IDEAL; IDEALIZE THE REAL."
1340 GOTO 200
1350 DEFFN'22
1360 A$="CORPULENT DERELICT COURTED OPULENT RELICT."
1370 GOTO 200
1380 DEFFN'23
1390 A$="RUMBA, SAMBA BOTH RIGHT MAD, BUT I DIG MOST THAT MAMBO."
1400 GOTO 200
1410 DEFFN'24
1420 A$="HIS FROZEN ASSETS CONSISTED OF FREEZER KEPT STACKS OF STEAKS."
1430 GOTO 200
1440 DEFFN'25
1450 A$="WE SHIRK IRKSOME HOMEWORK."
1460 GOTO 200
1470 DEFFN'26
1480 A$="CRISP CRYPTS STYMIE ME."
1490 GOTO 200
1500 DEFFN'27
1510 A$="BAGGY CLOTHES DECREED BY THE HAUTE COUTURE ARE GHASTLY."
1520 GOTO 200
1530 DEFFN'28
1540 A$="MEDIUM ABJURED OUIJA BOARD"
1550 GOTO 200
1560 DEFFN'29
1570 A$="OUR HEP JAVA FINCHES JUMP FIVE INCHES FROM PERCH."
1580 GOTO 200
1590 DEFFN'30
1600 A$="HORSESHOER QUIT QUOITS."
1610 GOTO 200
1620 DEFFN'31
1630 A$="QUAKING SKIN DIVER AVOIDS TAKING GROTESQUE SQUID."
1640 DEFFN'14
   : LOAD DC R"MENU"