image of READY prompt

Wang2200.org

Listing of file='BATNUM' on disk='vmedia/gamesall.wvd.zip'

# Sector 286, program filename = 'BATNUM'
0030 PRINT HEX(03)
0040 PRINT ,"***BATNUM***"
   : PRINT
0050 PRINT "THIS IS A GAME WHERE THE COMPUTER IS YOUR OPPONENT"
0060 PRINT "IN A BATTLE OF NUMBERS."
   : PRINT
0070 PRINT "THE GAME STARTS WITH AN ASSUMED PILE OF OBJECTS. YOU"
0080 PRINT "AND THE COMPUTER ALTERNATELY REMOVE OBJECTS FROM THE"
0090 PRINT "PILE. WINNING IS DEFINED IN ADVANCE AS TAKING THE "
0100 PRINT "LAST OBJECT OR NOT. YOU MAY ALSO SPECIFY OTHER CONDITIONS"
0110 PRINT "OF PLAY. DON'T USE ZERO OR YOU'RE IN BIG TROUBLE."
0120 PRINT
   : PRINT
   : PRINT
   : PRINT
0130 PRINT "ENTER PILE SIZE:";
   : INPUT N
0140 IF N<>INT(N)THEN 130
0150 IF N<=1THEN 130
0160 PRINT "ENTER WIN OPTION (1=TAKE LAST, 2=AVOID LAST)";
0170 INPUT M
   : IF M=1THEN 190
0180 IF M<>2THEN 160
0190 PRINT "MIN. AND MAX. NO. OF OBJECTS THAT CAN BE TAKEN";
   : INPUT A,B
0200 IF A<1THEN 190
   : IF A>BTHEN 190
0210 IF A<>INT(A)THEN 190
   : IF B<>INT(B)THEN 190
0220 PRINT "ENTER START OPTION (1=COMPUTER FIRST, 2=YOU FIRST)";
0230 INPUT S
   : PRINT
   : IF S=1THEN 240
   : IF S<>2THEN 220
0240 C=A+B
   : IF S=2THEN 270
0250 GOSUB 280
   : IF W=1THEN 120
0260 IF W=1THEN 120
0270 GOSUB 410
   : IF W=1THEN 120
   : GOTO 250
0280 Q=N
   : IF M=1THEN 320
   : Q=Q-1
0290 IF N>ATHEN 350
   : W=1
0300 PRINT "COMPUTER TAKES ";N;"AND LOSES"
0310 RETURN
0320 IF N>BTHEN 350
   : W=1
0330 PRINT "COMPUTER TAKES ";N;"AND WINS --- HA-HA"
0340 RETURN
0350 P=Q-C*INT(Q/C)
0360 IF P>=ATHEN 370
   : P=A
0370 IF P<=BTHEN 380
   : P=B
0380 N=N-P
0390 PRINT "COMPUTER TAKES";P;"AND LEAVES";N
   : W=0
0400 RETURN
0410 PRINT "YOUR MOVE:";
0420 INPUT P
   : IF P<>0THEN 450
0430 PRINT "I TOLD YOU NOT TO DO THAT - I WIN BY FORFEIT - HA-HA"
0440 W=1
   : RETURN
0450 IF P<>INT(P)THEN 480
   : IF P>=ATHEN 470
0460 IF P=NTHEN 500
   : GOTO 480
0470 IF P<=BTHEN 490
0480 PRINT "ILLEGAL MOVE, REENTER IT:";
   : GOTO 420
0490 N=N-P
   : IF N<>0THEN 550
0500 IF M=1THEN 530
0510 PRINT "TOUGH LUCK, YOU LOSE--DUMMY"
0520 W=1
   : RETURN
0530 PRINT "CONGRATULATIONS, YOU WIN-BUT I'LL GET YOU SOON"
0540 W=1
   : RETURN
0550 IF N>=0THEN 560
   : N=N+P
   : GOTO 480
0560 W=0
   : RETURN