image of READY prompt

Wang2200.org

Listing of file='28B ' on disk='vmedia/glbr_22.wvd.zip'

# Sector 467, program filename = '28B'
0500 REM SUBROUTINE FACTORISING NUMERICS
0510 DEFFN' 26(X(I),N,C)
0520 FOR I=N-1 TO 1 STEP -1
0530 FOR J=1 TO I
0540 IF C=1 THEN 560
0550 IF X(J)<=X(J+1) THEN 570
   : A=X(J)
   : X(J)=X(J+1)
   : X(J+1)=A
0555 GOTO 570
0560 IF X(J)>=X(J+1) THEN 570
   : A=X(J)
   : X(J)=X(J+1)
   : X(J+1)=A
0570 NEXT J
   : NEXT I
0580 RETURN
0590 REM SUBROUTINE FACTORISING ALPHA NUMERICS
0600 DEFFN' 27(A$(I),N)
0610 FOR I=N-1 TO 1 STEP -1
0620 FOR J=1 TO I
0630 IF A$(J)<=A$(J+1) THEN 640
   : B$=A$(J)
   : A$(J)=A$(J+1)
   :            A$(J+1)=B$
0640 NEXT J
   : NEXT I
0650 RETURN
0660 REM SUBROUTINE PACKING INTEGERS
0670 DEFFN' 28(X(I),N)
0680 Y=N/2
0690 IF Y-INT(Y)=0 THEN 700
   : N=N+1
   : X(N)=0
0700 M=0
0710 FOR I=1 TO N-1 STEP 2
0720 X(I-M)=X(I)+X(I+1)/1.0E06
0730 M=M+1
0740 NEXT I
0750 FOR I=N/2+1 TO N
0760 X(I)=0
0770 NEXT I
0780 RETURN
0790 REM SUBROUTINE UNPACKING INTEGERS
0800 DEFFN' 29(X(I),N)
0805 Y=N/2
   : IF Y-INT(Y)=0THEN 810
   : N=N+1
   : X(N)=0
0810 FOR J=N TO 2 STEP -2
0820 X(J-1)=X(J/2)
0830 NEXT J
0840 FOR I=1TO N-1STEP 2
0850 X(I+1)=(X(I)-INT(X(I)))*1.0E06
0860 X(I)=INT(X(I))
0870 NEXT I
0880 RETURN
0890 REM SUBROUTINE PACKING NUMERICS
0900 DEFFN' 30(X(I),N)
0910 Y=N/2
0920 IF Y-INT(Y)=0 THEN 930
   : N=N+1
   : X(N)=1
0930 M=0
0940 FOR I=1TO N-1STEP 2
0950 X(I-M)=INT(LOG(X(I))*1.0E03)+INT(LOG(X(I+1))*1.0E03)/           1.0E06
0960 M=M+1
0970 NEXT I
0980 FOR I=N/2+1 TO N
0990 X(I)=0
1000 NEXT I
1010 RETURN
1020 REM SUBROUTINE UNPACKING NUMERICS
1030 DEFFN' 31(X(I),N)
1040 Y=N/2
1050 IF Y-INT(Y)=0 THEN 1060
   : N=N+1
   : X(N)=0
1060 FOR J=N TO 2 STEP -2
1070 X(J-1)=X(J/2)
1080 NEXT J
1090 FOR I=1 TO N-1 STEP 2
1100 X(I+1)=EXP((X(I)-INT(X(I)))*1.0E03)
1110 X(I)=EXP(INT(X(I))/1.0E03)
1120 NEXT I
1130 FOR I=1 TO N
1140 IF X(I)<>1 THEN 1150
   : X(I)=0
1150 NEXT I
1160 RETURN