image of READY prompt

Wang2200.org

Listing of file='33B ' on disk='vmedia/glbr_22.wvd.zip'

# Sector 689, program filename = '33B'
0001 X=1
   : DIM C(5),D(5)
0005 DEFFNC(X)=INT(13*RND(X)+1)
0010 PRINT
   : PRINT ,"***BLACKJACK***"
0030 A=0
0031 P=2
   : FOR I=1 TO 5
   : C(I),D(I)=0
   : NEXT I
0035 PRINT
   : PRINT "YOUR BET IS";
   : INPUT B
   : IF B<=0 THEN 35
0036 PRINT "YOUR CARDS ARE:",
0040 FOR I=1 TO 2
   : C(I)=FNC(X)
   : D(I)=FNC(X)
0045 R=C(I)
   : GOSUB 900
0050 IF C(I)<10 THEN 52
   : C(I)=10
0052 IF D(I)<10 THEN 54
   : D(I)=10
0054 NEXT I
0055 IF C(1)<>1 THEN 60
   : IF C(2)>9 THEN 65
   : GOTO 70
0060 IF C(2)<>1 THEN 70
   : IF C(1)<=9 THEN 70
0065 N8=2
0070 PRINT TAB(38);"DEALER SHOWS:";
   : R=D(1)
   : GOSUB 900
   : PRINT
0071 IF N8=2 THEN 210
   : X8=1
   : X9=2
0072 P=P+1
   : IF P=6 THEN 200
0073 R=0
0075 FOR I=X8 TO X9
   : IF C(I)<>1 THEN 95
0080 PRINT "IS YOUR ACE 1 OR 11";
   : INPUT Z
   : I=X9
0085 R=10
   : IF Z=11 THEN 95
0090 R=0
   : IF Z<>1 THEN 80
0095 NEXT I
0100 S=C(1)+C(2)+C(3)+C(4)+C(5)+R
0105 IF S>21 THEN 260
0110 PRINT "YOU NOW HAVE:";S
0115 PRINT "DO YOU WANT A HIT (1=YES,2=NO)";
   : INPUT Z
0120 IF Z=2 THEN 400
   : IF Z<>1 THEN 115
0125 C(P)=FNC(X)
   : PRINT "YOUR CARD IS ";
0130 R=C(P)
   : GOSUB 900
   : PRINT
   : X8,X9=P
   : GOTO 72
0200 PRINT "CONGRATULATIONS! 5 CARD  CHARLIE WINS!"
   : A=A+B
0205 A=A+B
   : GOTO 220
0210 PRINT "CONGRATULATONS! YOU HAVE BLACKJACK!"
0215 A=A+3*B/2
0220 PRINT "YOUR WINNINGS ARE:";A
0225 N8,S=0
   : GOTO 31
0230 PRINT "DEALER BUSTS. YOU WIN!"
   : GOTO 205
0240 IF T>=S THEN 250
0245 PRINT "YOU WIN!"
   : GOTO 205
0250 PRINT "SORRY, DEALER WINS!"
   : GOTO 265
0260 PRINT "YOU BUSTED--YOU LOSE"
0265 A=A-B
   : GOTO 220
0400 P=2
0405 R=0
   : FOR I=1 TO 5
   : IF D(I)<>1 THEN 415
0410 R=10
   : I=5
0415 NEXT I
0420 T=D(1)+D(2)+D(3)+D(4)+D(5)+R
0425 IF T<22 THEN 430
   : T=T-R
0430 PRINT "DEALER HAS:";T
0435 IF T>21 THEN 230
   : IF T>16 THEN 240
0437 P=P+1
   : IF P=6 THEN 200
0440 D(P)=FNC(X)
0445 PRINT "DEALER GETS A";
   : R=D(P)
   : GOSUB 900
   : PRINT
0450 GOTO 405
0900 IF R>1 THEN 905
   : PRINT " ACE";
   : GOTO 925
0905 IF R<13 THEN 910
   : PRINT " KING";
   : GOTO 925
0910 IF R<12 THEN 915
   : PRINT " QUEEN";
   : GOTO 925
0915 IF R<11 THEN 920
   : PRINT " JACK";
   : GOTO 925
0920 PRINT R;
0925 RETURN