image of READY prompt

Wang2200.org

Listing of file='TBO.CMD' on disk='vmedia/toolbox.wvd.zip'

# Sector 807, program filename = 'TBO.CMD'
0010 REM .TBO.CMD  05/18/83 COMPARE DATA FILES
0015 IF D1$(10)=" "THEN LOAD T#0,"TBODISKS"8000,8800 BEG 20
0020 DIM A$(16)16,B$(16)16,D(300),C$1,C1$1,Z$64
0040 SELECT PRINT 005(64)
   : PRINT HEX(03);"COMPARE DATA FILES"
0050 GOSUB '98
   : REM /Get surface
   : SELECT #1<D1$(D9)>
   : D1=D9
0060 LINPUT "File name=",A$
0070 LIMITS T#1,A$,A1,A2,A3,A4
0080 IF A4=2THEN 90
   : PRINT "This is not a data file"
   : GOTO 50
0090 B$=A$
0100 GOSUB '98
   : REM /Get surface
   : SELECT #2<D1$(D9)>
   : D2=D9
0110 LINPUT "File name=",B$
0120 LIMITS T#2,B$,B1,B2,B3,B4
0130 IF B4=2THEN 140
   : PRINT "This is not a data file"
   : GOTO 80
0140 IF A3=B3THEN 150
   : PRINT "Unequal file sizes"
   : PRINT A3,B3
   : STOP #
0150 PRINT "File size = ";A3;" Sectors"
0160 DATA LOAD DC OPEN T#1,A$
0170 DATA LOAD DC OPEN T#2,B$
0180 B=0
   : FOR A=1 TO A3
0190 DATA LOAD BA T#1,(A1,A1)A$()
0200 DATA LOAD BA T#2,(B1,B1)B$()
0210 PRINT "Sector ";A;
0220 IF A$()<>B$()THEN 230
   : PRINT " ="
   : GOTO 310
0230 PRINT " differs"
0240 B=B+1
   : D(B)=A
0245 SELECT PRINT 005(79)
   : FOR C=1 TO 16
   : HEXUNPACKA$(C) TO Z$
   : FOR C1=1 TO 16
   : IF STR(A$(C),C1,1)<>STR(B$(C),C1,1)THEN OR (STR(Z$,C1*2-1,2),80)
   : NEXT C1
   : FOR C1=1 TO 32STEP 2
   : PRINT STR(Z$,C1,2);" ";
   : NEXT C1
   : NEXT C
   : PRINT
0250 REM  HEXPRINT A$()
   : PRINT
   : REM   HEX PRINT B$()
0255 FOR C=1 TO 16
   : HEXUNPACKB$(C) TO Z$
   : FOR C1=1 TO 16
   : IF STR(A$(C),C1,1)<>STR(B$(C),C1,1)THEN OR (STR(Z$,C1*2-1,2),80)
   : NEXT C1
   : FOR C1=1 TO 32STEP 2
   : PRINT STR(Z$,C1,2);" ";
   : NEXT C1
   : NEXT C
   : PRINT
   : SELECT PRINT 005(80)
0260 PRINT "Key 1 for hard copy"
0270 KEYIN C$
   : IF C$<>"1"THEN 310
0275 SELECT PRINT 215(130)
   : PRINT "Sector ";A
0280 PRINT "On ";D1$(D1);
   : IF POS(STR(A$(),2,255)<>STR(A$(),1,1))>0THEN 285
   : PRINT "  All ";HEXOF(STR(A$(),1,1))
   : GOTO 290
0285 PRINT
   : FOR C=1 TO 16
   : FOR C1=1 TO 16
   : PRINT HEXOF(STR(A$(C),C1,1));" ";
   : NEXT C1
   : PRINT " ^ ";
   : FOR C1=1 TO 16
   : C1$=STR(A$(C),C1)
   : IF C1$>HEX(1F) AND C1$<HEX(80)THEN PRINT C1$;" ";
   : ELSE PRINT "  ";
   : NEXT C1
   : PRINT
   : NEXT C
   : PRINT
0290 PRINT "On ";D1$(D2);
   : IF POS(STR(B$(),2,255)<>STR(B$(),1,1))>0THEN 295
   : PRINT "  All ";HEXOF(STR(B$(),1,1))
   : GOTO 300
0295 PRINT
   : FOR C=1 TO 16
   : FOR C1=1 TO 16
   : PRINT HEXOF(STR(B$(C),C1,1));" ";
   : NEXT C1
   : PRINT " ^ ";
   : FOR C1=1 TO 16
   : C1$=STR(B$(C),C1)
   : IF C1$>HEX(1F) AND C1$<HEX(80)THEN PRINT C1$;" ";
   : ELSE PRINT "  ";
   : NEXT C1
   : PRINT
   : NEXT C
   : PRINT
0300 SELECT PRINT 005(64)
0310 NEXT A
0320 PRINT "There are ";B;" sectors different"
0330 STOP "Done key continue for detailed differences"
0340 DEFFN'10
0350 PRINT "File ";A$;" on ";D1$(D1);" vs. ";B$;" on ";D1$(D2)
0360 PRINT A3;" sectors ";B;" differences"
0370 FOR A=1 TO B
   : PRINT A;TAB(5);" Sector = ";D(A)
   : NEXT A
0380 PRINT "File ";A$;" vs. ";B$;" with ";A3;" sectors ";B;" differences"
0390 STOP
0440 DEFFN'0
   : LOAD DC T "START   "