Listing of file='TBO.CRF0' on disk='vmedia/toolbox.wvd.zip'
# Sector 190, program filename = 'TBO.CRF0'
0010 REM TBO.CRF0 08/14/89 T.OLSEN 1 of 4 Basic-2 Cross-reference lister
0020 COM D6,E,E9,F9,D0,T9,X9,Q9,D7,D8,A$(16)16,B
0030 COM R$(4)38,M1,X,R1,R,S2,T1,A,D,F,P,P4,P5,P6,P7,L9,T,I,L,H,M,Q1,S,S1,M2,M
3
0040 COM U,E$50,D$64,H$1,S$80,P$8,C$(124)10,V1$1,R$1,L$2,U$(60)2
0050 COM M9,V$1,C,J,V,W,M$(1)2,C$46,T$1,B$(270)1,B$1,N$(4)1,Q$4,Q,G,Y,Z
: Y=20
0060 REM %MAX.CAPACITY VARIABLES
: REM %0E9 # Program files,F9 Max.S.F.,D0 Max.Meanings,T9 Max.Stmt Refs,X9
Max.Var.Oflo,Q9 Max.Variables
0062 REM %0 Y D$().string.size
0065 B$="T"
: K=SPACEK
: E$=$PSTAT(1)
: B$=STR(E$,9)
0068 GOSUB 340
0070 PRINT HEX(03);"TBO xref -- System code = ";C$;" with ";K;"K memory"
0080 GOSUB 100
0090 LOAD DC T"TBO.CRF1"
0100 IF K<20THEN STOP "Insufficient memory"
0110 REM %.20K
: E9=20
: F9=30
: D0=30
: T9=1
: X9=25
: Q9=80
: IF K<24THEN 160
0120 REM %.24K
: E9=40
: F9=40
: D0=60
: T9=2
: X9=35
: Q9=90
: IF K<28THEN 160
0130 REM %.28K
: E9=50
: F9=60
: D0=150
: T9=2
: X9=79
: Q9=95
: IF K<31THEN 160
0140 REM %.31K
: E9=55
: F9=65
: D0=165
: T9=3
: X9=79
: Q9=140
: IF K<33THEN 160
0145 REM %.32K
: E9=60
: F9=75
: D0=175
: T9=3
: X9=79
: Q9=160
: IF K<44THEN 160
0150 REM %.44K
: E9=145
: F9=90
: D0=250
: T9=5
: X9=160
: Q9=170
: Y=45
: IF K<45THEN 160
0155 Q9=250
0160 X=X9+1
: F=F9+1
: Q=Q9+1
: IF Y>38THEN Y=38
: REM E9=300
0180 RETURN
0190 DEFFN'1
: INPUT "K",K
: GOSUB 100
0200 DEFFN'2
: H=0
0210 PRINT HEX(03);"Fiqure new DIMensions for ";K;"K ";C$;" CPU"
: PRINT
: GOSUB '13
: PRINT "KEY S.F. '4 TO GET BACK TO MAIN-LINE"
0220 H=H+1
: ON HGOTO 230,240,250,260,270,280
0230 PRINT "UNIQUE VARIABLES=";Q9;"OR";
: INPUT Q9
: GOTO 210
0240 PRINT "SPECIAL FUNCTIONS=";F9;"OR";
: INPUT F9
: GOTO 210
0250 PRINT "STMT REFS =255*";T9;"OR";
: INPUT T9
: GOTO 210
0260 PRINT "VAR.REFS>10=";X9;"OR";
: INPUT X9
: GOTO 210
0270 PRINT "ANNOTATION=";D0;"OR";
: INPUT D0
: GOTO 210
0280 PRINT "PROGRAM NAMES=";E9;"OR";
: INPUT E9
: H=0
: GOTO 210
0290 DEFFN'13
: PRINT "TABLE CAPACITY"," YOU CHANGE","NUMBER","MEMORY"
: PRINT "UNIQUE VARIABLES Q9 Q$() X$()",Q9,Q9*25+25
: PRINT "SPECIAL FUNCTIONS F9 F$()",F9,F9*3+3
0300 PRINT "STMT REFERENCES T9 T$()",255*T9,T9*8*255,," T1$() T2$()"
: PRINT "VARIABLE REFS.>10 X9 X0$()",X9,X9*21+21
0310 PRINT "ANNOTATION"," D0 D$()",D0,D0*20
: PRINT "PROGRAM FILES"," E9 E$() P$()",E9,E9*51
: GOSUB 350
: RETURN
0320 PRINT "DIMENSIONED THIS WAY YOU NEED A 2200 ";
: G=4886
: REM /MINIMAL TABLES
0330 REM Z=END FOLLOWING TEXT ENTRY IN CROSSRF0
0340 I=1122
: Z=10444+4686
: C$="MVP"
: IF B$="M"THEN RETURN
0345 I=3302
: Z=Z+2180
: C$="VP"
: IF B$="V"THEN RETURN
0346 I=1122
: Z=10444+4686
: C$="CS/386"
: IF B$="W"THEN RETURN
: RETURN
0350 Q=G+Z+(Q9*25)+(F9*3)+((T9-1)*8*255)+(X9*21)+((D0-1)*20)+((E9-1)*51)
0360 PRINT Q;" bytes required ";(K*1024)-I;"available in partition"
0368 IF Q>(K*1024)-ITHEN 380
0370 PRINT
: RETURN
0380 STOP "Insufficient memory reconfigure"
1000 REM %CROSS 3/22/84 Variable definitions
1010 REM % SYSTEM REQUIREMENTS
1020 REM % EQUIPMENT--
1030 REM WANG 2200 vp, mvp
1040 REM MINIMUM MEMORY REQUIRED 16K MAX=32K
1050 REM % PERIPHERALS USED
1060 REM %0 /215 Line Printer, /001 KBD, /005 CRT
1070 REM %0 #0 System.Disk, #2 Program Disk, #9 CRT.or.KBD
1080 REM % OTHER VARIABLE MEANINGS
1090 REM %0A Disk Sector, B Text Bytes, I$( Byte test values
1100 REM %0 A$( Read area, A$(1 Record IDent
1110 REM %0B$ Char, B$( Text, C Line Pos, C$ Prt.data
1120 REM %0C$( Verb tbl,D Device flag,D$ Date,D$( Var.Meanings
1122 REM %0 D1$( Disk table
1130 REM %0R Comment str, R1 Comment ptr, R$( Comment text
1140 REM %0D6 Save comments, D7 D8*Size, D8 # Meanings
1150 REM %0E$ Name+Comment, E$( File Comments, E Even page
1160 REM %0F S.F.Index, F$( S.F.Table, V2$ Verb atom match
1170 REM %0H$ Header byte,I Indent,J Ptr,L Line #,L$ Stmt No., P4 List.mode
1172 REM %0 L4$ $4.byte w/a, M$ $2.byte.w/a, T$ $1.byte.w/a
1180 REM %0L9 Lines/Page, M Margin,M1 Reset,M$( Search find
1190 REM %0 M2 Right column, M3 M1+M2, M9 Right margin
1200 REM %0N$( Next 4 chars, P$ Prog.Name,P$( Prog.Names
1210 REM %0P Page,P5 Print flag,P6 Current file #,P7 # Files
1220 REM %0Q Var.Index,Q1 Annotation flag,Q$ Next 4 Chars
1230 REM %0Q$( Var.Table, S # Lines,S1 # Stmts,S2 Start stmt,S3 End Stmt
1240 REM %0S$ Non-atom list, T Stmt index,T$( Stmt tbl,T1 Array dim.
1250 REM %0T1$ Search for,T1$( SORT tbl,T2$( SORT Tbl
1260 REM %0U Ptr,U$( This line refs,R0$ REM%0 Table
1270 REM %0V Verb ptr,V$ Verb atom,V1$ Prior verb,W flag
1280 REM %0X Oflo Index,X$( Var Refs,X0$( Var.oflo
1290 REM %0R$ R$1,H H,G G,Z Z
1300 REM %SPECIAL FUNCTIONS
1310 REM %0 '0 Surface media, '1 Entry-Disk names
1320 REM %0 '2 Fiqure Dimensions, '3 List changes
1330 REM %0 '10 Summry to PRT/go, '11 Summary only, '12 Description
1340 REM %0 '13 Capacities, '14 List options, '15 S.F.Action